home *** CD-ROM | disk | FTP | other *** search
/ Cream of the Crop 1 / Cream of the Crop 1.iso / COMM / MSKRMSRC.ARJ / MSGIBM.ASM next >
Assembly Source File  |  1991-10-24  |  168KB  |  5,157 lines
  1.      Name msgibm
  2. ; File MSGIBM.ASM
  3.     include mssdef.h
  4. ;       Copyright (C) 1982,1991, Trustees of Columbia University in the
  5. ;       City of New York.  Permission is granted to any individual or
  6. ;       institution to use, copy, or redistribute this software as long as
  7. ;       it is not sold for profit and this copyright notice is retained.
  8. ; Tektronix emulator for use with MS Kermit/IBM.
  9. ; Edit history:
  10. ; 6 Sept 1991 version 3.11
  11. ; 2 March 1991 version 3.10
  12. ; Last edit 5 March 1991
  13. ; 12 Nov 1990 Add text cursor symbol, and on 17 Nov add cursor on/off.
  14. ; 2 Nov 1990 Add Microsoft mouse direct support.
  15. ; 8 June 1989 Added Wyse-700 support from Mikko Laanti.
  16. ; 21 Nov 1988 Version 2.32
  17. ; 1 Nov 1987 Heavy rewrite to integrate code into regular MS Kermit/IBM
  18. ;  material. [jrd]
  19. ;==============================================================================
  20. ; Original version for TI Pro computers by
  21. ; 12-Dec-84  Joe Smith, CSM Computing Center, Golden CO 80401
  22. ; adapted to IBM PC June 1987 by    Brian Holley,
  23. ;                    Faculty of Economics and Politics
  24. ;                    University of Cambridge, England
  25. ;                    Email: BJH6@UK.AC.CAM.PHX
  26. ; Upgraded and integrated into MS Kermit 2.30 by Joe Doupnik, Utah State Univ.
  27. ;
  28. ;           Description of Tektronix commands
  29. ;
  30. ; ESC CONTROL-E (ENQ) requests a status report
  31. ; ESC FORMFEED erases the screen.
  32. ; ESC CONTROL-X turns on bypass mode (ignore incoming characters).
  33. ; ESC CONTROL-Z turns on the crosshairs (not on 4006 or 4025)
  34. ; ESC 2  exit Tek submode for text mode (ignore if doing full Tek)
  35. ; ESC ? is replaced by DEL code, to assist line plots with 7 bit systems.
  36. ; ESC [ Pn ; Pn m  set screen colors. Pn = 30 + sum of colors for foregnd,
  37. ;  40 + sum of colors for background, Pn = 0 sets b/w, Pn = 1 for high
  38. ;  intensity. Colors are red = 1, green = 2, blue = 4.
  39. ; ESC [ ? 3 8 l  exits Tek mode and returns to host text terminal type
  40. ;  (VT102 if none defined yet). This is an extension from DEC VT340's.
  41. ; ESC [ ? 256 n  invokes a screen size report, for Word Perfect. Report is
  42. ;   ESC [ ? 256; height; width; num colors n   where num colors is 0, 1 or
  43. ;   16; report ESC [ ? 24; 80; 0 n  for pure text mono systems.
  44. ; ESC @  through  ESC M  sets default fill pattern as below (1=@...).
  45. ; ESC Z  report terminal type (as VT320)
  46. ; ESC [ 2; 2 $ u  host request color palette report.
  47. ; ESC / xhome;yhome;xwidth;yheight x           draw an empty rectangle
  48. ; ESC / xhome;yhome;xwidth;yheight;pattern y   fill rectangle with pattern
  49. ; ESC / xhome;yhome;xwidth;yheight;pattern z   fill rect with pattern+border
  50. ;  where x/yhome is the lower left Tek corner, xwidth and yheight are the
  51. ;  Tek width and height. All values are decimal numbers.
  52. ;  Patterns 0:use default, 1:solid, 2:grey, 3:left to right slant, 4:right to
  53. ;  left slant, 5:horizontal lines, 6:vertical lines, 7:slanted cross-hatch,
  54. ;  8:vertical cross-hatch, 9:checkerboard; 10:dotted, 11:horiz herringbone,
  55. ;  12:vertical herringbone,13 and above:border without fill. All are tiling
  56. ;  8x8 pixel patterns.
  57. ; ESC / param a, ... ESC / param c  set user definable line drawing pattern
  58. ;  to 16 bit value of param; plot as lsb first.
  59. ; ESC / 2 h or l,  ESC / 9 h or l. h is set, l is reset, 2 is destructive
  60. ;  space and 9 is destructive backspace. Defaults are reset.
  61. ; ESC x  ESC y  ESC z   selects one of these user definable patterns above.
  62. ; ESC P  P1; P2; P3 q string ESC \        a Sixel Graphics command
  63. ;   P1 and P3 ignored, P2 = 0 or 2 means draw 0 bits in background, 1 means
  64. ;    skip them.
  65. ;   string is
  66. ;     sixel chars (3fh..7eh, lower 6 bits+3fh, displayed lsb at the top)
  67. ;     ! Pn sixel char        where Pn is a repeat count
  68. ;     " Pan; Pad; Ph; Pv    raster attributes (all ignored for now)
  69. ;     # Pc; Pu; Px; Py; Pz  coloring as follows
  70. ;    Pc is color palette, 0-255  (note, only 0..15 are predefined)
  71. ;    Pu is color units, 1=HLS, 2=RGB
  72. ;    For Hue Lightness Saturation:
  73. ;        Px = Hue angle, 0-360 degrees. The colors are mapped around
  74. ;        the color wheel in 60 degree segments as Hues:
  75. ;        0-29 deg = blue, 30-89 = magenta (blue + red), 90-149 = red,
  76. ;        150-209 = yellow (red + green), 210-269 = green,
  77. ;        270-329 = cyan (green + blue), 330-359 = blue.
  78. ;        Py = Lightness, 0-100%, Pz = Saturation, 0-100%
  79. ;          Lightness    Sat = 51-100    Sat = 11-50     Sat = 0-10
  80. ;          86-100    bold white    bold white     bold white
  81. ;          71-85        bold hue    bold white     bold white
  82. ;          57-70        bold hue    grey (dim white) grey
  83. ;          43-56        bold hue    dim hue         black
  84. ;          29-42        dim hue        grey         grey
  85. ;          14-28        dim hue        black         black
  86. ;           0-13     black        black         black
  87. ;        Note that Py = Pz = 50 gives the widest spectrum.
  88. ;    For RGB: Px = red, 0-100%, Py = green, 0-100%, Pz = blue, 0-100%
  89. ;        If any color exceeds 50% then the bold bit is turned on for
  90. ;        the ensemble (IBM ega display adapter constraint for RGBi).
  91. ;
  92. ;    Palette registers can be selected by the substring
  93. ;        # Pc    followed by a non-numeric char other than ";"
  94. ;            and Pc is the palette register, 0-255.
  95. ;
  96. ;     $  (dollar sign )     meaning go to left margin
  97. ;     -  (minus)         meaning go to left margin 6 dots down.
  98. ;   This command yields one or more sets of 6 vertically arranged dots. They
  99. ;   are placed starting at the top and left side of the current text cell.
  100. ;   Escape sequences are permitted within string and occur without disruption.
  101. ; CONTROL-] (GS) turns on plot mode, the first move will be with beam off.
  102. ; CONTROL-^ (RS) turns on incremental plot mode. RS space means move pen up
  103. ;  RS P means move pen down, following letters: A, E, D, F, B, J, H, I mean
  104. ;  move right, right and up, up, left and up, left, left and down, down, and
  105. ;  right and down, respectively. Ex: RS <space> J J J  means move three Tek
  106. ;  positions left and down with the pen up (invisibly).
  107. ; CONTROL-UNDERLINE (US) turns off plot mode, as does CR (for all but 4025).
  108. ; CONTROL-X switches from TEKTRONIX sub mode to NORMAL alpha mode but is
  109. ;  ignored if we are emulating a full Tek terminal rather than a sub mode
  110. ;  of DEC or Heath.
  111. ; FF erases screen.
  112. ; ESC letter, where letter is accent grave (`) a..e, sets the line drawing
  113. ;   pattern until reset to solid lines (same as escape accent) by command or
  114. ;   a terminal reset.
  115. ; 
  116. ;    ENQ = Control E
  117. ;    ESC = Control [ (left square bracket)
  118. ;    FF = Control L
  119. ;    FS = Control \ (backslash)
  120. ;    GS = Control ] (right square bracket)
  121. ;    RS = Control ^ (caret)
  122. ;    US = Control _ (underscore)
  123. ;
  124. ; The plot commands are characters which specify the absolute position to move
  125. ; the beam.  All moves except the one immediately after the GS character
  126. ; (Control-]) are with a visible trace.
  127. ;
  128. ; For 4010-like devices - The positions are from 0 to 1023 for both X and Y,
  129. ; although only 0 to 780 are visible for Y due to screen geometry.  The screen
  130. ; is 10.23 by 7.80 inches, and coordinates are sent as 1 to 4 characters.
  131. ;
  132. ; For 4014-like devices - The positions are from 0 to 4096, but each movement
  133. ; is a multiple of 4 positions unless the high-resolution LSBXY are sent.  This
  134. ; makes it compatible with the 4010 in that a full sized plot fills the screen.
  135. ;
  136. ; HIX,HIY = High-order 5 bits of position
  137. ; LOX,LOY = Middle-order 5 bits of position
  138. ; LSBXY      = Low-order 2 bits of X + low-order 2 bits of Y (4014 mode)
  139. ;
  140. ; Hi Y      Lo Y      Hi X      LSBXY      Characters sent (Lo-X always sent)
  141. ; ----      ----      ----      -----      ----------------------------------
  142. ; Same      Same      Same      Same                 Lo-X
  143. ; Same      Same      Same      Diff        LSB, Lo-Y,     Lo-X    4014
  144. ; Same      Same      Diff      Same             Lo-Y, Hi-X, Lo-X
  145. ; Same      Same      Diff      Diff        LSB, Lo-Y, Hi-X, Lo-X    4014
  146. ; Same      Diff      Same      Same             Lo-Y,     Lo-X
  147. ; Same      Diff      Same      Diff        LSB, Lo-Y,     Lo-X    4014
  148. ; Same      Diff      Diff      Same             Lo-Y, Hi-X, Lo-X
  149. ; Same      Diff      Diff      Diff        LSB, Lo-Y, Hi-X, Lo-X    4014
  150. ; Diff      Same      Same      Same      Hi-Y,             Lo-X
  151. ; Diff      Same      Same      Diff      Hi-Y, LSB, Lo-Y,     Lo-X    4014
  152. ; Diff      Same      Diff      Same      Hi-Y,         Lo-Y, Hi-X, Lo-X
  153. ; Diff      Same      Diff      Diff      Hi-Y, LSB, Lo-Y, Hi-X, Lo-X    4014
  154. ; Diff      Diff      Same      Same      Hi-Y,         Lo-Y,     Lo-X
  155. ; Diff      Diff      Same      Diff      Hi-Y, LSB, Lo-Y,     Lo-X    4014
  156. ; Diff      Diff      Diff      Same      Hi-y,         Lo-Y, Hi-X, Lo-X
  157. ; Diff      Diff      Diff      Diff      Hi-y, LSB, Lo-Y, Hi-X, Lo-X    4014
  158. ; Offset for byte:          20h    60h  60h   20h     40h
  159. ;
  160. ; Note that LO-Y must be sent if HI-X has changed so that the TEKTRONIX knows
  161. ; the HI-X byte (in the range of 20h-3fh) is HI-X and not HI-Y.     LO-Y must
  162. ; also be sent if LSBXY has changed, so that the 4010 will ignore LSBXY and
  163. ; accept LO-Y.    The LSBXY byte is 60h + MARGIN*10h + LSBY*4 + LSBX. (MARGIN=0)
  164. ;
  165. ;
  166. ;
  167. ; External variable tekflg and calls to tekini, tekemu, tekesc, tekcls:
  168. ; Byte TEKFLG is non-zero when the Tek emulator is active; it is set by the
  169. ; startup code in tekini and is maintained in this file. Internal variable
  170. ; inited remembers if we have a graphics screen saved, etc.
  171. ; TEKINI must be called when entering the emulator to establish the graphics
  172. ; screen mode and to calculate the screen dimensions.
  173. ; TEKRINT reinitialize complete emulator.
  174. ; TEKESC is called from say mszibm.asm to invoke Tek emulation when the
  175. ; external procedures have detected an Escape Control-L sequence. An implicit
  176. ; initialization is done if necessary.
  177. ; TEKEMU is the normal entry point to pass a received character to the emulator.
  178. ; It too will do an implicit initialization, if required.
  179. ; TEKCLS clears the graphics screen, but only if the emulator is active.
  180. ; The emulator remains active during Connect mode Help, Status, and other
  181. ; interrupts which do not change the terminal type.
  182.  
  183.      
  184.     public    tekemu,tekini,tekrint,tekend,tekgraf ; Terminal emulation
  185.         public    tekflg, tekdmp, tekinq, tekpal, tekrpal    ; used by mszibm file
  186.     public    chcontrol, tekcursor, tekgcptr        ; used by msyibm file
  187.  
  188. ENQ    equ    05h            ; ^E ENQ for TEK enquiries
  189. CAN    equ    18h            ; ^X to return to ANSI mode
  190. ESCZ    equ    1Ah            ; SUB, ESC-^Z triggers crosshairs
  191. VT    equ    0Bh            ; ^K go up one line
  192. FS    equ    1Ch            ; ^\ for point plot mode
  193. GS    equ    1Dh            ; ^] draw line (1st move is invisible)
  194. RS    equ    1Eh                   ; ^^ for incremental line plot mode
  195. US    equ    1Fh            ; ^_ (underscore) returns to text mode
  196. accent    equ    60h            ; accent grave
  197.  
  198. txtmode    equ    4            ; text mode for TEKTRONIX status
  199. maxtekx equ    1024            ; horizontal and
  200. maxteky equ    780            ; vertical resolution of TEK 4010
  201.      
  202. screen    equ    10h            ; IBM Bios screen call
  203.      
  204. uparr    equ    72            ; DOS scan codes for arrow keys
  205. dnarr    equ    80
  206. lftarr    equ    75
  207. rgtarr    equ    77
  208. homscn    equ    71            ; DOS home screen scan code
  209. shuparr    equ    '8'            ; ascii codes for shifted arrows
  210. shdnarr    equ    '2'
  211. shlftarr equ    '4'
  212. shrgtarr equ    '6'
  213. mouse    equ    33h            ; Microsoft mouse interrupt
  214. msread    equ    3            ; mouse, read status and position
  215. mswrite    equ    4            ; mouse, set position
  216. mshoriz    equ    7            ; mouse, set min/max horizontal motion
  217. msvert    equ    8            ; mouse, set min/max vertical motion
  218. msgetbf    equ    21            ; mouse, get state buffer size
  219. msgetst    equ    22            ; mouse, get mouse state to buffer
  220. mssetst    equ    23            ; mouse, set mouse state from buffer
  221. msreset    equ    33            ; mouse, software reset
  222.  
  223.                     ; Graph_mode for different systems:
  224. cga    equ    6            ; highest resolution mode for CGA
  225. mono    equ    7            ; real monochrome display adapter
  226. colorega equ    14            ; Low-res mode, color EGA
  227. monoega equ    15            ; mono ega needs mode 15
  228. ega    equ    16            ; Hi-res mode - EGA
  229. olivetti equ    72            ; Olivetti's Hi-res - 50 lines text
  230. toshiba    equ    74h            ; Toshiba T3100, like Olivetti
  231. vaxmate    equ    0D0h            ; DEC VAXmate II, like Olivetti
  232. wyse700 equ    0D3h            ; Wyse-700 1280 * 400
  233. hercules equ    255            ; pseudo mode for Hercules graphics
  234. ; Note: IBM VGA modes 17 & 18, 640 by 480, can be used by setting "ega" above
  235. ; to 17 or 18 and modifying ybot to be 479 and ymult to be 48 at label tekin5.
  236. ; The code will scale everything appropriately for the new screen size, but
  237. ; there will be insufficient memory to retain the entire graphics image.
  238. ; Manual override SET TERMINAL GRAPHICS VGA accomplishes these two steps.
  239. ;
  240. ; Note: WYSE-700 mode 1024 * 780 and 1280 * 800 can be set only by
  241. ; manual override SET TERMINAL GRAPHICS WYSET or WYSEA, respectively.
  242. ; No automatic sensing for Wyse.
  243.  
  244. segega    equ    0a000h            ; segments of display memory, EGA,VGA
  245. segcga    equ    0b800h            ; CGA, AT&T/Olivetti and relatives
  246. seghga    equ    0b000h            ; HGA
  247. segmono    equ    0b000h            ; Monochrome
  248. segwyse equ    0a000h            ; wyse-700, both banks start from here
  249.                     ; Wyse equates:
  250. wystoff equ    03ddh            ; set bank start offset
  251. wystseg equ    03deh            ; set bank start base
  252. wymode    equ    03dfh            ; register to select mode & bank
  253. wybeven equ    0c8h            ; mask for R/W even bank
  254. wybodd    equ    0cbh            ; mask for R/W odd bank
  255.  
  256.                     ; Hercules equates:
  257. index    equ    03b4h            ; 6845 index register
  258. cntrl    equ    03b8h            ; Display mode control port
  259. hstatus    equ    03bah            ; status port
  260. scrn_on equ    8            ; bit to turn screen on
  261. grph    equ    2            ; graphics mode
  262. text    equ    20h            ; text mode
  263. config    equ    03bfh            ; configuration port
  264. genable equ    1+2            ; enable graphics (1) on two pages (2) 
  265. rgbbold    equ    80            ; nor/bold threshold for RGB intensity
  266. hiy    equ    1            ; codes for Tek graphics components
  267. loy    equ    2
  268. hix    equ    4
  269. lox    equ    3
  270. ; maxparam and maxinter must agree with the prime equ's in file mszibm.asm
  271. maxparam equ    10            ; number of ESC and DCS Parameters
  272. maxinter equ    10            ; number of ESC and DCS Intermediates
  273.  
  274.                     ; Pixel basic operation codes
  275. pixor    equ    1            ; write as foreground OR current dot
  276. pixbak    equ    2            ; write as absolute background color
  277. pixxor    equ    4            ; write as foreground XOR current dot 
  278. pixfor    equ    8            ; write absolute foreground color
  279.  
  280. data    segment
  281.     extrn    flags:byte, portval:word, rxtable:byte, vtemu:byte     
  282.     extrn    tv_mode:byte, yflags:byte, low_rgt:byte
  283.     extrn    param:word, nparam:word, inter:byte, ninter:word, lparam:byte
  284.     extrn    parstate:word, pardone:word, parfail:word
  285.     extrn    dnparam:word, dparam:word, dlparam:byte, dninter:word
  286.     extrn    dinter:byte, dcsstrf:byte, emubufc:word, emubuf:byte
  287.     extrn    emubufl:word, ttyact:byte, vtclear:byte
  288.  
  289. ; required for Hercules screen handling
  290.      
  291. gtable    db    35h,2dh,2eh,7        ; bytes for 6845 controller
  292.     db    5bh,2,57h,57h        ; - graphics mode
  293.     db    2,3,0,0
  294.      
  295. ttable    db    61h,50h,52h,0fh        ; bytes for 6845 controller
  296.     db    19h,6,19h,19h        ; - text mode
  297.     db    2,0dh,0bh,0ch
  298.  
  299. attlogo    db    'OLIVETTI'        ; Olivetti M24/28, AT&T 6300 rom id
  300. attllen    equ    $-attlogo        ; length
  301. toshlogo db    '  TT33110000  TTOOSSHHIIBBAA' ; Toshiba T3100 logo
  302. toshlen    equ    $-toshlogo        ; length
  303. declogo    db    'Copyright Digital Equipment Corp' ; DEC VAXmate
  304. declen    equ    $-declogo
  305. dumpname db    'TEKPLT.TIF',0        ; dump name
  306. dumplen    equ    $-dumpname
  307. tempname db    84 dup (0)        ; temp work area
  308. dhandle    dw    -1            ; dump file handle
  309.  
  310. ttstate    dw    tektxt            ; state machine control pointer
  311. prestate dw    0            ; previous state, across interruptions
  312. visible db    0            ; 0 to move, 1 to draw a line
  313. tek_hiy dw    0            ; Y coordinate in Tektronix mode
  314. tek_loy db    0
  315. tek_hix dw    0            ; X coordinate in Tektronix mode
  316. tek_lox db    0
  317. tek_lsb db    0            ; Low-order 2 bits of X + low Y
  318.                     ;    (4014 mode)
  319. status    db    0
  320. lastc    db    0            ; last x/y coord fragment seen       
  321. bnkchan db    0            ; a flag so we can select which bank
  322.                     ; to write in Wyse 1280*800 mode
  323. colpal    db    0,9,0ch,0ah        ; VT340 color palette table, IRGB
  324.     db    0dh,0bh,0eh,7, 8,1,4,2, 5,3,6,0fh ; 16 bytes, active table
  325.     db    256-($-colpal) dup (0)    ; to make 256 entries overall
  326. coldef    db    0,9,0ch,0ah, 0dh,0bh,0eh,7, 8,1,4,2, 5,3,6,0fh ; color def
  327. mondef    db    0,7 dup (0fh), 8 dup (7) ; monochrome default "colors"
  328. havepal    db    0            ; 1 if have selected palette
  329. masktab db    80h,40h,20h,10h,8,4,2,1 ; quicker than calculations!
  330.                     ; dashed line patterns
  331. linetab    dw    0ffffh            ; ESC accent    11111111 11111111
  332.     dw    0aaaah            ; ESC a        10101010 10101010
  333.     dw    0f0f0h            ; ESC b        11110000 11110000
  334.     dw    0fafah            ; ESC c        11111010 11111010
  335.     dw    0ffcch            ; ESC d        11111111 11001100
  336.     dw    0fc92h            ; ESC e        11111100 10010010
  337.     dw    0ffffh            ; ESC x    user defined
  338.     dw    0ffffh            ; ESC y user defined
  339.     dw    0ffffh            ; ESC z user defined
  340. linepat    dw    0ffffh            ; active line pattern, from above
  341.  
  342. tekid    db    escape,'[?63;1;2;4;8;9;15c',0; VT320, level 3, etc
  343. ;End of init data
  344.  
  345.     even
  346. xmult    dw    1            ; scaling factor for x is
  347. xdiv    dw    1            ;     xmult/xdiv
  348. ymult    dw    1            ; scaling factor for y is
  349. ydiv    dw    1            ;     ymult/ydiv
  350. xmax    dw    1            ;
  351. ybot    dw    1            ;
  352. x_coord dw    0            ; Tek text char X coordinate
  353. y_coord dw    0            ; Tek text char Y coordinate
  354. xcursor    dw    0            ; PC x_coord of text cursor symbol
  355. ycursor    dw    0            ; PC y_coord of text cursor symbol
  356. xcross    dw    0            ; crosshair coordinates
  357. ycross    dw    0
  358. xcenter    dw    0            ; center of screen
  359. ycenter    dw    0            ; center of screen
  360. tekcursor db    1            ; show text cursor (non-zero)
  361. cursorst db    0            ; cursor state (non-zero is displayed)
  362. oldx    dw    0            ; Tek coordinates of last point
  363. oldy    dw    767            ;  initially top left
  364. scalex    dw    0            ; PC coord for scaled x value
  365. scaley    dw    0            ;  for scaled y value
  366. rectx1    dw    0            ; Rectangle PC x lower left corner
  367. recty1    dw    0            ; Rectangle PC y lower left corner
  368. rectx2    dw    0            ; Rectangle PC x width
  369. recty2    dw    0            ; Rectangle PC y height
  370. numlines dw    0            ; number of lines to fill
  371.                     ; area fill material
  372. fill    db    0            ; current fill byte pattern
  373. fillptr    dw    filpat1            ; pointer to current fill pattern
  374. fillist    dw    filpat1,filpat2,filpat3,filpat4,filpat5,filpat6,filpat7
  375.     dw    filpat8,filpat9,filpat10,filpat11,filpat12,filpat13
  376.     dw    filpat14
  377. numfil    equ    ($-fillist)/2        ; number of fill patterns
  378.     ; fill patterns, 8 bits wide, first byte is at top of PC screen
  379.     ; 8 bytes per pattern for 8 scan line repetition
  380. filpat1    db    8 dup (0ffh)        ; solid fill
  381. filpat2    db    4 dup (0aah, 55h)    ; grey (alternating dots)
  382. filpat3    db    80h,01h,02h,04h, 08h,10h,20h,40h ; right to left slant up
  383. filpat4    db    80h,40h,20h,10h, 08h,04h,02h,01h ; left to right slant up
  384. filpat5 db    2 dup (0,0,0aah,0)    ; horizontal lines
  385. filpat6    db    8 dup (44h)        ; vertical lines
  386. filpat7    db    80h,41h,22h,14h, 08h,14h,22h,41h   ; slanted crosshatch
  387. filpat8    db    2 dup (0aah,80h,80h,80h)  ; vertical crosshatch
  388. filpat9    db    4 dup (0f0h), 4 dup (0fh) ; checkerboard
  389. filpat10 db    4 dup (44h, 11h)    ; dots
  390. filpat11 db    2 dup (10h,28h,44h,82h)    ; horizontal herringbone
  391. filpat12 db    80h,40h,20h,10h,08h,10h,20h,40h ; vertical herringbone
  392. filpat13 db    8 dup (0ffh)        ; first user definable fill
  393. filpat14 db    8 dup (0ffh)        ; second user definable fill
  394.                     ; end of area fill material
  395. curmode    db    0            ; screen mode before graphics
  396. tekgraf    db    0        ; Tek graphics board selection (def=auto)
  397.                 ; local variables for LINE plotting routine
  398. graph_mode db    0            ; graphics video mode, default is none
  399. cursor    dw    0            ; saved text cursor
  400. inited    db    0            ; non-zero if inited (retains page)
  401. tekflg    db    0            ; Tek mode active flag
  402.                     ;  1=Tek reads serial port
  403.                     ;  2=VT300 emulator reads serial port
  404. tekident db    0            ; Tek ident request flag
  405. flow    dw    0            ; flow control word
  406. gpage    db    0            ; display adapter graphics page
  407. gfcol    db    15            ; graphics foreground colour
  408. gbcol    db    0            ; graphics background color
  409. tfcol    db    0            ; temp foreground color
  410. tbcol    db    0            ; temp background color
  411. colortb    db    0,4,2,6,1,5,3,7        ; color reversed-bit setting bytes
  412. ccode    db    pixfor            ; temp for holding plot color code
  413. bypass    db    0            ; GIN mode bypass condition (0=off)
  414. esctype    db    0            ; first char after ESCAPE char
  415. bscontrol db    0            ; non-zero for destructive BS
  416. spcontrol db    0            ; non-zero for destructive SPACE
  417. chcontrol db    0            ; char-writing, 1=opaque,0=transparent
  418.     even
  419. mousebuf dw    0            ; segment of mouse save buffer
  420. putc    dw    mputc            ; ptr to plot a character routine
  421. psetup    dw    psetupm            ; ptr to plot setup routine
  422. pincy    dw    pincym            ; ptr to inc y routine
  423. plotptr    dw    pltmon            ; ptr to dot plot routine
  424. gfplot    dw    bpltmon            ; ptr to area-fill plot routine
  425. segscn    dw    0b800h            ; actual screen segment to use
  426. doneptr    dw    offset xpardone,seg xpardone ; far pointer for tpardone use
  427. dumpptr    dw    offset dump,seg dump    ; far pointer for dump use
  428. initptr    dw    offset tekini,seg tekini
  429. rptptr    dw    offset tekrpt,seg tekrpt
  430. endptr    dw    offset tekend,seg tekend
  431. tekpptr dw    offset tekxco4,seg tekxco4
  432. linelen    dw    0            ; offset increment between scan lines
  433. ten    dw    10            ; word 10 for multiplying
  434. temp    dw    0
  435.  
  436. ; 8*8 font for Hercules and such, CGA, and EGA
  437. ; - allows 43 lines, and 80 (90 for Hercules) chars per line.
  438. ; all printing (?) characters from <space> to <del> - two characters per line
  439. ; 8 bits per scan line, top line given first, 8 scan lines.    
  440. font    db    0,0,0,0,0,0,0,0,           18h,18h,18h,18h,18h,0,18h,0
  441.     db    6ch,6ch,6ch,0,0,0,0,0,           36h,36h,7fh,36h,7fh,36h,36h,0
  442.     db    0ch,3fh,68h,3eh,0bh,7eh,18h,0, 60h,66h,0ch,18h,30h,66h,06h,0
  443.     db    38h,6ch,6ch,38h,6dh,66h,3bh,0, 0ch,18h,30h,0,0,0,0,0
  444.     db    0ch,18h,30h,30h,30h,18h,0ch,0, 30h,18h,0ch,0ch,0ch,18h,30h,0
  445.     db    0,18h,7eh,3ch,7eh,18h,0,0,     0,18h,18h,7eh,18h,18h,0,0
  446.     db    0,0,0,0,0,18h,18h,30h,           0,0,0,7eh,0,0,0,0
  447.     db    0,0,0,0,0,18h,18h,0,           0,06h,0ch,18h,30h,60h,0,0
  448.     db    3ch,66h,6eh,7eh,76h,66h,3ch,0, 18h,38h,18h,18h,18h,18h,7eh,0
  449.     db    3ch,66h,06h,0ch,18h,30h,7eh,0, 3ch,66h,06h,1ch,06h,66h,3ch,0
  450.     db    0ch,1ch,3ch,6ch,7eh,0ch,0ch,0, 7eh,60h,7ch,06h,06h,66h,3ch,0
  451.     db    1ch,30h,60h,7ch,66h,66h,3ch,0, 7eh,06h,0ch,18h,30h,30h,30h,0
  452.     db    3ch,66h,66h,3ch,66h,66h,3ch,0, 3ch,66h,66h,3eh,06h,0ch,38h,0
  453.     db    0,0,18h,18h,0,18h,18h,0,       0,0,18h,18h,0,18h,18h,30h
  454.     db    0ch,18h,30h,60h,30h,18h,0ch,   0,0,0,7eh,0,7eh,0,0,0
  455.     db    30h,18h,0ch,06h,0ch,18h,30h,   0,3ch,66h,0ch,18h,18h,0,18h,0
  456.     db    3ch,66h,6eh,6ah,6eh,60h,3ch,   0,3ch,66h,66h,7eh,66h,66h,66h,0
  457.     db    7ch,66h,66h,7ch,66h,66h,7ch,   0,3ch,66h,60h,60h,60h,66h,3ch,0
  458.     db    78h,6ch,66h,66h,66h,6ch,78h,   0,7eh,60h,60h,7ch,60h,60h,7eh,0
  459.     db    7eh,60h,60h,7ch,60h,60h,60h,   0,3ch,66h,60h,6eh,66h,66h,3ch,0
  460.     db    66h,66h,66h,7eh,66h,66h,66h,   0,7eh,18h,18h,18h,18h,18h,7eh,0
  461.     db    3eh,0ch,0ch,0ch,0ch,6ch,38h,   0,66h,6ch,78h,70h,78h,6ch,66h,0
  462.     db    60h,60h,60h,60h,60h,60h,7eh,   0,63h,77h,7fh,6bh,6bh,63h,63h,0
  463.     db    66h,66h,76h,7eh,6eh,66h,66h,   0,3ch,66h,66h,66h,66h,66h,3ch,0
  464.     db    7ch,66h,66h,7ch,60h,60h,60h,   0,3ch,66h,66h,66h,6ah,6ch,36h,0
  465.     db    7ch,66h,66h,7ch,6ch,66h,66h,   0,3ch,66h,60h,3ch,06h,66h,3ch,0
  466.     db    7eh,18h,18h,18h,18h,18h,18h,   0,66h,66h,66h,66h,66h,66h,3ch,0
  467.     db    66h,66h,66h,66h,66h,3ch,18h,   0,63h,63h,6bh,6bh,7fh,77h,63h,0
  468.     db    66h,66h,3ch,18h,3ch,66h,66h,   0,66h,66h,66h,3ch,18h,18h,18h,0
  469.     db    7eh,06h,0ch,18h,30h,60h,7eh,   0,7ch,60h,60h,60h,60h,60h,7ch,0
  470.     db    0,60h,30h,18h,0ch,06h,0,0,     3eh,06h,06h,06h,06h,06h,3eh,0
  471.     db    18h,3ch,66h,42h,0,0,0,0,       0,0,0,0,0,0,0,0ffh
  472.     db    30h,18h,0ch,0,0,0,0,0,           0,0,3ch,06h,3eh,66h,3eh,0
  473.     db    60h,60h,7ch,66h,66h,66h,7ch,0, 0,0,3ch,66h,60h,66h,3ch,0
  474.     db    06h,06h,3eh,66h,66h,66h,3eh,0, 0,0,3ch,66h,7eh,60h,3ch,0
  475.     db    0eh,18h,18h,3ch,18h,18h,18h,0, 0,0,3eh,66h,66h,3eh,06h,3ch
  476.     db    60h,60h,7ch,66h,66h,66h,66h,0, 18h,0,38h,18h,18h,18h,3ch,0
  477.     db    18h,0,38h,18h,18h,18h,18h,70h, 60h,60h,66h,6ch,78h,6ch,66h,0
  478.     db    38h,18h,18h,18h,18h,18h,3ch,0, 0,0,76h,7fh,6bh,6bh,63h,0
  479.     db    0,0,7ch,66h,66h,66h,66h,0,     0,0,3ch,66h,66h,66h,3ch,0
  480.     db    0,0,7ch,66h,66h,7ch,60h,60h,0, 0,3eh,66h,66h,3eh,06h,07h
  481.     db    0,0,6ch,76h,60h,60h,60h,0,     0,0,3eh,60h,3ch,06h,7ch,0
  482.     db    30h,30h,7ch,30h,30h,30h,1ch,0, 0,0,66h,66h,66h,66h,3eh,0
  483.     db    0,0,66h,66h,66h,3ch,18h,0,     0,0,63h,6bh,6bh,7fh,36h,0
  484.     db    0,0,66h,3ch,18h,3ch,66h,0,     0,0,66h,66h,66h,3eh,06h,3ch
  485.     db    0,0,7eh,0ch,18h,30h,7eh,0,     0ch,18h,18h,70h,18h,18h,0ch,0
  486.     db    18h,18h,18h,0,18h,18h,18h,0,   30h,18h,18h,0eh,18h,18h,30h,0
  487.     db    31h,6bh,46h,0,0,0,0,0,           0ffh,6 dup (81h),0ffh
  488.     ; note, the last 8 bytes comprise the text cursor symbol pattern
  489.  
  490. ; TIFF version 5.0 data fields
  491. ; Reference: Aldus/Microsoft Technical Memorandum dated 8/8/88
  492.                     ; TIFF data item size indicators
  493. uchar    equ    1            ; unsigned byte
  494. ascii    equ    2            ; asciiz string byte
  495. integer    equ    3            ; 16 bit unsigned integer
  496. long    equ    4            ; 32 bit unsigned integer
  497. rational equ    5            ; 32 bit numerator, 32 bit denominator
  498.  
  499. entry    struc                ; 12 byte image file directory entries
  500.     dw    ?            ; tag
  501.     dw    integer            ; type, of data item
  502. entcnt    dd    1            ; length, count of data items
  503. entval    dw    0            ; long value or long offset to value
  504.     dw    0
  505. entry    ends
  506.     
  507.     even                ; TIFF 5.0,  8 byte header
  508. header    dw    4949h            ; 'll', low byte stored first
  509.     dw    42            ; TIFF identification, 42 decimal
  510.     dw    nentry-header,0        ; long offset to image file directory
  511.                     ; Image File Directory
  512. nentry    dw    entrycnt        ; number of entries to follow
  513.                     ; 12-byte directory entries
  514. newsub    entry    <0feh,long>        ; new subfield type
  515. iwidth    entry    <100h,integer>        ; image width,  integer for WP 5
  516. ilength entry    <101h,integer>        ; image length, integer for WP 5
  517. bps    entry    <102h,,,4>         ; bits per sample, 4=iRGB, 1=B/W
  518. comp    entry    <103h,,,1>        ; compression, none
  519. photo     entry    <106h,,,3>        ; photometric interpret, palette 
  520. strip     entry    <111h,long,25,stripoff-header> ; offset to long strip offsets
  521. spp    entry    <115h,,,1>        ; samples/pixel, 1
  522. rps    entry    <116h,long,1,25>    ; long rows per strip
  523. sbc    entry    <117h,integer,25,stripbc-header> ; offset to strip byte counts
  524. xres    entry    <11ah,rational,1,xresval-header> ; x axis resolution
  525. yres    entry    <11bh,rational,1,yresval-header> ; y axis resolution
  526. resunit entry    <128h,integer,1,1>    ; resolution unit, no absolute units
  527. soft    entry    <131h,ascii,proglen,prog-header> ; software ident
  528. stamp    entry    <132h,ascii,dtlen,dandt-header>  ; date and time stamp
  529. cmap    entry    <140h,integer,3*16,colmap-header> ; palette color map
  530. entrycnt equ    ($-nentry-2+11)/12    ; compute number of entries for nentry
  531.     dd    0            ; long offset of next directory (none)
  532.                     ; supporting data pointed at above
  533. prog    db    'MS Kermit 300',0    ; originating program, asciiz
  534. proglen equ    $-prog
  535. dandt    db    '1989:12:25 00:00:01',0    ; date and time format
  536. dtlen    equ    $-dandt
  537. xresval dw    0,0,1,0            ; two double words (top / bottom)
  538. yresval dw    0,0,1,0            ; two double words (top / bottom)
  539. stripoff dd    25 dup (0)        ; long file offset for each strip
  540. stripbc dw    25 dup (0)        ; integer byte count for each strip
  541.     ; color map for red, green, blue; index by IRGB bits from ega sample
  542. colmap    dw    4 dup (0), 4 dup (007ffh), 4 dup (0), 4 dup (0ffffh) ; red
  543.     dw    2 dup (0,0,007ffh,007ffh), 2 dup (0,0,0ffffh,0ffffh) ; green
  544.     dw    2 dup (0,007ffh,0,007ffh), 2 dup (0,0ffffh,0,0ffffh) ; blue
  545. tifflen equ    $-header         ; length of header + directory + info
  546. pixdata equ    $              ; pixel data start here on disk
  547.                     ; end of TIFF information
  548.  
  549. esctab    db    34            ; table of ESC <char> dispatches
  550.     dw    escjmp            ; address of table for action routines
  551.     db    ENQ,FF,CAN,CTLZ,'/'            ; ^E,^L,^X,^Z,/
  552.     db    '2','@ABCD','EFGHI','JKLM'
  553.     db    3fh,'PZ[\'                ; '?PZ[\'
  554.     db    60h,'abcde','xyz'            ; accent, a..e,x,y,z
  555.  
  556. ; Dispatch for esctab table
  557.     even
  558. escjmp    dw    tekenq, tekcls,tekcan, tekgin,tekeseq    ; ^E,^L,^X,^Z,/
  559.     dw    tektwo,14 dup (tekfill)            ; '2@ABCDEFGHIJKLM'
  560.     dw    tekqury,tekeseq,sendid,tekeseq,tekgotst ; '?PZ[\'
  561.     dw    9 dup (teklpat)                ; accent, a..e,x,y,z
  562.  
  563. ; Final char table for ANSI escape sequences
  564. anstab    db    21            ; number of entries
  565.     dw    ansjmp            ; address of action routines
  566.     db    '@ABCD','EFGHJ','KXade','fhlmn','u'
  567.  
  568. ; Dispatch for anstab table
  569.     even
  570. ansjmp    dw    ansich, atcuu,   atcud,   atcuf,  atcub        ; '@ABCD'
  571.     dw    atcnl,  atcpl,   atcha,   atcup,  ated        ; 'EFGHJ'
  572.     dw    atel,   atech,   atcuf,   atcva,  atcud        ; 'KXade'
  573.     dw    atcup,  escexit, escexit, tekcol, tekrid    ; 'fhlmn'
  574.     dw    tekprpt                        ; 'u'
  575. data    ends
  576.  
  577. code    segment                    ; main body code segment
  578.     extrn    outchr:near, beep:near, scrseg:near, cmblnk:near
  579.     extrn    savescr:near, restscr:near, cptchr:near, clrbuf:near
  580.     extrn    iseof:near, atparse:near, unique:near
  581.     extrn    chgdsp:near, pcwait:near, vtrmac:near, vtsmac:near
  582.  
  583.     assume    cs:code, ds:data, es:nothing
  584.  
  585. ; These far routines are called by the Tek emulator; they are here to provide
  586. ; a bridge to the main code segment near procedures.
  587.      
  588. ; Procedures for calling to the main body of MS Kermit. Most are FAR and
  589. ; must be in in code segment named code, not in code2.
  590.  
  591. outmodem proc    far            ; send Tek char out serial port
  592.     push    ax
  593.     mov    ah,al
  594.     call    outchr            ; outchr reads from ah
  595.     pop    ax
  596.     ret
  597. outmodem ENDP
  598.  
  599. tekbeep    proc    far            ; sound a beep from Tek mode
  600.     call    beep
  601.     ret
  602. tekbeep    endp
  603.  
  604. tcmblnk    proc    far            ; blank the screen from Tek mode
  605.     call    cmblnk
  606.     ret
  607. tcmblnk    endp
  608.  
  609. tsavescr proc    far            ; save text screen while in Tek mode
  610.     call    savescr
  611.     ret
  612. tsavescr endp
  613.  
  614. trestscr proc    far            ;restore text screen while in Tek mode
  615.     cmp    low_rgt,80        ; were we in 80 column mode?
  616.     jbe    trestsc1        ; be = yes
  617.     mov    al,1            ; set to 132 columns
  618.     call    chgdsp            ; msyibm routine to change screen
  619. trestsc1:
  620.     call    restscr
  621.     ret
  622. trestscr endp
  623.  
  624. tscrseg    proc    far            ; get video segment while in Tek mode
  625.     call    scrseg
  626.     ret
  627. tscrseg    endp
  628.  
  629. tcptchr    proc    far            ; call session logger while in Tek
  630.     call    cptchr            ;  mode
  631.     ret
  632. tcptchr    endp
  633.  
  634. tiseof    proc    far            ; call iseof while in Tek mode
  635.     call    iseof
  636.     ret
  637. tiseof    endp
  638.  
  639. tparstart proc    far            ; start escape sequence parser
  640.     mov    parstate,0        ; set to initialize automatically
  641.     mov    pardone,offset tpardone    ; jmp to this when completed
  642.     mov    parfail,0        ; no failure case jump
  643.     ret
  644. tparstart endp
  645.  
  646. tparser    proc    far
  647.     call    atparse            ; reach to real parser
  648.     ret
  649. tparser    endp
  650.  
  651. tpardone proc    near            ; called by real parser
  652.     call    dword ptr doneptr    ; far call xpardone, old MASM way
  653.     ret
  654. tpardone endp
  655.  
  656. tunique    proc    far            ; reach to real unique name procedure
  657.     call    unique            ;  while in Tek mode
  658.     ret
  659. tunique    endp
  660.  
  661. tekwait    proc    far            ; call pcwait while in Tek mode
  662.     call    pcwait
  663.     ret
  664. tekwait    endp
  665.  
  666.  
  667. ; Return screen info for Tek screen report: ax=screen height, bx=width,
  668. ; cx=number of colors (0=none for pure text, 1=b/w, 16=ega)
  669. tekinq    proc    near
  670.     mov    tekident,1        ; say this is an ident request
  671.     call    dword ptr initptr    ; do init steps to get screen sizes
  672.     mov    ax,ybot            ; lowest screen line
  673.     inc    ax            ; screen height, in lines
  674.     mov    bx,xmax
  675.     add    bx,8            ; screen width, in dots
  676.     cmp    graph_mode,mono        ; pure text mono (no graphics at all)?
  677.     jne    tekinq1            ; ne = no
  678.     mov    ax,24            ; bottom screen line
  679.     mov    bx,80            ; screen width
  680.     xor    cx,cx            ; pure mono, say 0 colors
  681.     jmp    short tekinq2
  682. tekinq1:mov    cx,1            ; say b/w screen
  683.     cmp    plotptr,offset pltcga    ; using CGA style graphics?
  684.     je    tekinq2            ; e = yes
  685.     cmp    graph_mode,monoega    ; monochrome monitor on ega?
  686.     je    tekinq2            ; e = yes
  687.     mov    cx,16            ; say 16 colors
  688. tekinq2:mov    tekident,0
  689.     ret
  690. tekinq    endp
  691.  
  692. ; Return in BX the offset of the master color palette table. Used by SET TERM
  693. ; GRAPHICS COLOR <color value> to obtain foreground and background colors
  694. ; in palette slots 7 and 0, resp.
  695. tekgcptr proc    near
  696.     mov    tekident,1        ; say this is an ident request
  697.     call    dword ptr initptr    ; do init steps to get screen sizes
  698.     mov    bx,offset mondef    ; default monochrome colors
  699.     cmp    plotptr,offset pltcga    ; using CGA style graphics?
  700.     je    tekgcpt1        ; e = yes
  701.     cmp    graph_mode,mono        ; pure mono text system?
  702.     je    tekgcpt1        ; e = yes
  703.     cmp    graph_mode,monoega    ; ega, but monochrome?
  704.     je    tekgcpt1        ; e = no
  705.     mov    bx,offset coldef    ; return offset of color palette
  706. tekgcpt1:mov    havepal,0        ; say don't have a palette setup
  707.     mov    tekident,0
  708.     mov    inited,0
  709.     ret
  710. tekgcptr endp
  711.  
  712. ; These routines can be called by either the main body or from within Tek
  713. ; mode.
  714. tekdmp    proc    near            ; Tek screen dump routine
  715.     call    dword ptr dumpptr    ; callable from main body
  716.     clc
  717.     ret
  718. tekdmp    endp
  719.  
  720. tekmac    proc    far            ; invoke vtrmac or vtsmac
  721.     or    ax,ax            ; which macro?
  722.     jz    tekmacr            ; z = the R flavor
  723.     call    vtsmac            ; do TerminalS, in msyibm
  724.     ret
  725. tekmacr:call    vtrmac            ; do TerminalR, in msyibm
  726.     ret                ; only if they fail
  727. tekmac    endp
  728.  
  729. tekpal    proc    near            ; do palette report tekrpt
  730.     call    dword ptr rptptr    ; callable from main body
  731.     ret
  732. tekpal    endp
  733.  
  734. tekrpal    proc    near            ; restore color palette
  735.     call    dword ptr tekpptr    ; callable from main body
  736.     ret
  737. tekrpal endp
  738. code    ends                ; main body code segment
  739.  
  740. ; Code segment code2 is allocated to Tektronix emulation
  741. code2    segment                ; supplementary code segment
  742.  
  743.     assume    cs:code2, ds:data, es:nothing
  744.  
  745. cs2pb    db    256    dup (0)        ; code2 segment patch buffer
  746.  
  747. tekxco4    proc    FAR            ; call local tekgco4, return far
  748.     call    tekgco4
  749.     ret
  750. tekxco4    endp
  751.  
  752. ; Initialise TEK mode by setting high resolution screen, etc
  753. tekini    proc    far
  754.     push    ax            ; do presence tests
  755.     push    bx
  756.     push    cx
  757.     push    dx
  758.     push    si
  759.     push    di
  760.     push    es
  761.     cmp    tekident,0        ; just identifying?
  762.     jne    tekin0            ; ne = yes
  763.     mov    bx,portval        ; get port flow control chars:
  764.     mov    bx,[bx].flowc        ; bh=xon, bl=xoff or both are nulls
  765.     mov    flow,bx            ; save here
  766.     mov    ax,bx            ; get flow control word
  767.     or    al,al            ; able to do xoff?
  768.     jz    tekin0            ; z = no
  769.     call    outmodem        ; tell host xoff while we change modes
  770. tekin0:    cmp    inited,0        ; inited yet?
  771.     jne    tekin0a            ; ne = yes, use existing coloring
  772.     mov    ax,linetab        ; get default line pattern
  773.     mov    linepat,ax        ; init active line pattern
  774.     mov    fillptr,offset filpat1    ; init active fill pointer
  775.     cmp    havepal,0        ; have a color palette yet?
  776.     jne    tekin0a            ; ne = yes
  777.     mov    bx,vtemu.att_ptr    ; emulator screen color ptr
  778.     mov    al,[bx]
  779.     mov    gfcol,al        ; save foreground color
  780.     and    gfcol,0fh        ; save just foreground bits
  781.     and    al,70h            ; select background color, no bold
  782.     mov    cl,4
  783.     shr    al,cl            ; get background colors
  784.     mov    gbcol,al        ; set graphics background color
  785. tekin0a:mov    ah,15            ; get current screen mode
  786.     int    screen
  787.     and    al,not 80h        ; strip "preserve regen" bit 80h
  788.     cmp    al,mono            ; mono text mode (7)?
  789.     je    tekin1            ; e = yes
  790.     cmp    tekident,0        ; doing an ident request?
  791.     jne    tekin2            ; ne = yes, don't mess with screen
  792.     test    tekflg,1        ; are we active as Tek device now?
  793.     jz    tekin1            ; z = no
  794.     jmp    tekin13            ; yes, don't redo graphics setup
  795. tekin1:    mov    curmode,al        ; save mode here
  796.     mov    ah,3            ; get cursor position
  797.     xor    bh,bh            ; page 0
  798.     int    screen
  799.     mov    cursor,dx        ; save position
  800.     call    tsavescr        ; save text screen
  801.                     ; Presence tests.
  802. tekin2:    mov    graph_mode,cga        ; Color. Assume CGA
  803.     mov    segscn,segcga        ; assume cga screen segment
  804.     mov    gpage,0            ; graphics page 0 but no page 1
  805.     mov    putc,offset gputc    ; CGA character display routine
  806.     mov    gfplot,offset bpltcga    ; CGA area fill routine
  807.     mov    psetup,offset psetupc    ; CGA plot setup routine
  808.     mov    plotptr,offset pltcga    ; CGA dot plot routine
  809.     mov    pincy,offset pincyc    ; CGA inc y routine
  810.     mov    xmult,5            ; CGA. Scale TEK to PC by 640/1024
  811.     mov    xdiv,8            ;  so that 0-1023 converts to 0-639
  812.     mov    xmax,640-8        ; x-coord of rightmost character
  813.     mov    ymult,10        ; vertical scale for IBM is 200/780
  814.     mov    ydiv,39            ;
  815.     mov    ybot,199        ; Bottom of screen is Y=199
  816.     mov    al,tekgraf        ; user video board specification
  817.     or    al,al            ; auto-sensing?
  818.     jnz    tekin2d            ; nz = no
  819.     jmp    tekin2c            ; yes (default)
  820. tekin2d:cmp    al,1            ; user wants CGA?
  821.     jne    tekin2a            ; ne = no
  822.     jmp    tekin13            ; do CGA
  823. tekin2a:cmp    al,4            ; user wants Hercules?
  824.     jne    tekin2b            ; ne = no
  825.     jmp    tekin8            ; do Hercules
  826. tekin2b:cmp    al,5            ; user wants AT&T style?
  827.     jne    tekinwy            ; ne = no
  828.     jmp    tekin7            ; do AT&T kind
  829.                     ; Wyse-700
  830. tekinwy:cmp    al,8            ; user wants Wyse-700 1024*780 ?
  831.     jne    tekinw0            ; ne = no
  832.     call    chkwyse            ; presence test
  833.     jc    tekinwf            ; c = failed
  834.     mov    xmax,1024-8        ; x-coord of rightmost character
  835.     mov    ybot,779        ; Bottom of screen is Y=780
  836.     mov    xmult,1            ; Wyse. Scale TEK to PC by 1024/1024
  837.     mov    xdiv,1            ;  so that 0-1023 converts to 0-1023
  838.     mov    ymult,1            ; vertical scale is 780/780
  839.     mov    ydiv,1            ;
  840.     jmp    short tekinw2        ;
  841. tekinw0:cmp    al,7            ; user wants Wyse-700 1280*780 ?
  842.     jne    tekinw1            ; ne = no
  843.     call    chkwyse            ; presence test
  844.     jc    tekinwf            ; c = failed
  845.     mov    xmax,1280-8        ; x-coord of rightmost character
  846.     mov    ybot,779        ; Bottom of screen is Y=800
  847.     mov    xmult,10        ; Wyse. Scale TEK to PC by 1280/1024
  848.     mov    xdiv,8            ;  so that 0-1023 converts to 0-1279
  849.     mov    ymult,1            ; vertical scale is 780/780
  850.     mov    ydiv,1            ;
  851.     jmp    short tekinw2        ;
  852. tekinwf:jmp    tekin2c            ; failure jump point
  853. tekinw1:cmp    al,6            ; user wants Wyse-700 1280*800 ?
  854.     jne    tekin2c            ; no = no
  855.     call    chkwyse            ; presence test
  856.     jc    tekinwf            ; c = failed
  857.     mov    xmax,1280-8        ; x-coord of rightmost character
  858.     mov    ybot,799        ; Bottom of screen is Y=800
  859.     mov    xmult,10        ; Wyse. Scale TEK to PC by 1280/1024
  860.     mov    xdiv,8            ;  so that 0-1023 converts to 0-1279
  861.     mov    ymult,40        ; vertical scale for IBM is 800/780
  862.     mov    ydiv,39            ;  so scale those 20 pixels more
  863. tekinw2:mov    graph_mode,wyse700    ; Assume Wyse Graphics
  864.     mov    segscn,segwyse        ; assume wyse screen segment
  865.     mov    gpage,0            ; only one graphics page 0
  866.     mov    putc,offset gputc    ; CGA character display routine
  867.     mov    psetup,offset psetupw    ; Wyse plot setup routine
  868.     mov    plotptr,offset pltcga    ; CGA dot plot routine
  869.     mov    pincy,offset pincyw    ; Wyse inc y routine
  870.     jmp    tekin13            ; do Wyse
  871.                     ; do auto-sensing of display board
  872.                     ; test for EGA
  873. tekin2c:mov    ax,1200H        ; EGA: Bios alternate select
  874.     mov    bl,10H                  ; Ask for EGA info
  875.     mov    bh,0ffH            ; Bad info, for testing
  876.     mov    cl,0fH            ; Reserved switch settings
  877.     int    screen            ; EGA, are you there?
  878.     and    cl,0fh            ; four lower switches
  879.     cmp    cl,0cH            ; Test reserved switch settings
  880.     jb    tekin3            ; b = ega present
  881.     jmp    tekin7            ; else no EGA, check other adapters
  882.  
  883. tekin3:    mov    ax,40h            ; check Bios 40:87h for ega being
  884.     mov    es,ax            ;  the active display adapter
  885.     test    byte ptr es:[87h],8    ; is ega active?
  886.     jz    tekin3a            ; z = yes
  887.     jmp    tekin7            ; ega is inactive, check others
  888. tekin3a:cmp    bl,1            ; is there 128KB on ega board?
  889.     jb    tekin4            ; b = less, so no screen saves
  890.     mov    gpage,1            ; >=128 KB, use two graphics pages
  891. tekin4:    mov    graph_mode,ega        ; assume high resolution color
  892.     cmp    cl,3            ; high resolution color?
  893.     je    tekin5            ; e = yes
  894.     cmp    cl,9            ; high resolution color?
  895.     je    tekin5            ; e = yes
  896.     mov    graph_mode,monoega    ; assume mono monitor on ega board
  897.     test    bh,1            ; ega mono mode in effect?
  898.      jnz    tekin5            ; nz = yes
  899.     mov    graph_mode,colorega    ; say ordinary cga on ega board, 64KB
  900.     mov    gpage,1            ; is enough memory with 200 scan lines
  901.     jmp    short tekin5a        ; use current cga parameters
  902. tekin5:    mov    ybot,349        ; text screen bottom is 349 on EGA
  903.     mov    ymult,35        ;
  904.     mov    ydiv,78            ; scale y by 350/780
  905. tekin5a:mov    segscn,segega        ; use ega screen segment
  906.     mov    psetup,offset psetupe    ; plot setup routine
  907.     mov    plotptr,offset pltega    ; ega dot plot routine
  908.     mov    gfplot,offset bpltega    ; ega area fill routine
  909.     mov    pincy,offset pincye    ; inc y routine
  910.     mov    putc,offset gputc    ; character display routine
  911.     jmp    tekin13            ; end of EGA part, do VGA tests below
  912.  
  913. tekin7:    mov    ax,0fc00h        ; Olivetti/AT&T 6300, check rom id
  914.     mov    es,ax
  915.     xor    di,di            ; start here
  916.     mov    graph_mode,olivetti    ; Olivetti
  917.     mov    cx,attllen        ; length of logo
  918.     mov    si,offset ATTLOGO    ; master string
  919.     repe    cmpsb            ; do a match
  920.     je    tekin7c            ; e = a match
  921.     mov    di,0050h        ; look here too
  922.     mov    si,offset ATTLOGO
  923.     mov    cx,attllen
  924.     repe    cmpsb
  925.     je    tekin7c            ; e = a match
  926.     mov    di,2014h        ; and look here
  927.     mov    si,offset ATTLOGO
  928.     mov    cx,attllen
  929.     repe    cmpsb            ; do a match
  930.     je    tekin7c            ; e = a match, else try other types
  931. tekin7a:mov    graph_mode,toshiba
  932.     mov    ax,0f000h        ; Check for Toshiba T3100, rom scan
  933.     mov    es,ax
  934.     mov    di,0014h        ; start here
  935.     mov    si,offset TOSHLOGO    ; master string
  936.     mov    cx,toshlen        ; length
  937.     repe    cmpsb            ; do a match
  938.     je    tekin7c            ; e = a match, else try other types
  939. tekin7b:mov    graph_mode,vaxmate    ; DEC VAXmate II
  940.     mov    ax,0f000h        ; Check for VAXmate II rom signature
  941.     mov    es,ax
  942.     mov    di,0e000h        ; start here
  943.     mov    si,offset DECLOGO    ; master string
  944.     mov    cx,declen        ; length
  945.     repe    cmpsb            ; do a match
  946.     jne    tekin7d            ; ne = mismatch, try other types
  947.  
  948.                     ; Olivetti/AT&T, Toshiba, VAXmate
  949. tekin7c:mov    gpage,0            ; only page 0 with 640 by 400 mode
  950.     mov    segscn,segcga        ; use cga screen segment (0b800h)
  951.     mov    psetup,offset psetupo    ; plot setup routine
  952.     mov    plotptr,offset pltcga    ; cga dot plot routine
  953.     mov    gfplot,offset bpltcga    ; area fill plot routine
  954.     mov    pincy,offset pincyh    ; inc y routine (Herc style addresses)
  955.     mov    putc,offset gputc    ; character display routine
  956.     mov    ybot,399        ; bottom of screen is y = 399
  957.     mov    ymult,20        ; vertical scale = 400/780
  958.     mov    ydiv,39            ; same as cga setup
  959.     jmp    tekin13
  960.  
  961. tekin7d:cmp    curmode,mono        ; mono text mode?
  962.     je    tekin8            ; e = yes
  963.     jmp    tekin11            ; ne = no, try cga
  964.                     ; test for Hercules
  965. tekin8:    call    tscrseg            ; get screen segment, test Environment
  966.     cmp    tv_mode,1        ; Environment active?
  967.     jne    tekin8a            ; ne = no, ok to test for Hercules
  968.     jmp    tekin10            ; don't do Herc mode, do Mono
  969. tekin8a:mov    dx,hstatus        ; Herc status port
  970.     in    al,dx            ; read it
  971.     mov    bl,al            ; save here
  972.     and    bl,80h            ; remember retrace bit
  973.     mov    cx,0ffffh        ; do many times (for fast machines)
  974. tekin8b:mov    dx,hstatus        ; check status port
  975.     in    al,dx
  976.     and    al,80h            ; select bit
  977.     jmp    $+2            ; use a little time
  978.     cmp    bl,al            ; did it change?
  979.     loope    tekin8b            ; test again if not
  980.     je    tekin10            ; e = no change in bit, not Herc
  981.     mov    graph_mode,hercules    ; say have Herc board
  982.     mov    segscn,seghga        ; assume hga screen segment
  983.     mov    putc,offset gputc    ; character display routine
  984.     mov    gfplot,offset bpltcga    ; area fill plot routine
  985.     mov    psetup,offset psetuph    ; plot setup routine to use
  986.     mov    plotptr,offset pltcga    ; use cga dot plot routine for Herc
  987.     mov    pincy,offset pincyh    ; inc y routine
  988.     mov    xmult,45        ; Scale TEK to Hercules by 720/1024
  989.     mov    xdiv,64            ;  so that 0-1023 converts to 0-719
  990.     mov    xmax,720-8        ; x-coord of rightmost character
  991.     mov    ymult,87        ; vertical scale for Hercules is
  992.     mov    ydiv,195        ;  348/780
  993.     mov    ybot,347        ; bottom of screen is y = 347
  994.     mov    ax,seghga        ; segment of Herc video display
  995.     mov    es,ax
  996.     mov    al,es:[8000h]        ; read original contents, page 1
  997.     not    byte ptr es:[8000h]    ; write new pattern
  998.     mov    ah,es:[8000h]        ; read back
  999.     not    byte ptr es:[8000h]    ; restore original contents
  1000.     not    ah            ; invert this too
  1001.     cmp    ah,al            ; same (memory present?)
  1002.     jne    tekin9            ; ne = not same, no memory there
  1003.     mov    gpage,1            ; say two pages of display memory
  1004. tekin9:    call    crossini        ; preset crosshairs
  1005.     jmp    tekin13
  1006.                     ; set to MONO
  1007. tekin10:mov    graph_mode,mono        ; force monochrome adapter text
  1008.     mov    segscn,segmono        ; assume mono screen segment
  1009.     call    tscrseg            ; Environments: get virtual screen
  1010.     mov    segscn,ax        ;  seg returned in ax and es:di
  1011.     mov    gpage,0
  1012.     mov    putc,offset mputc    ; character display routine
  1013.     mov    psetup,offset psetupm    ; plot setup routine to use
  1014.     mov    gfplot,offset bpltmon    ; area fill plot routine
  1015.     mov    plotptr,offset pltmon    ; use hga dot plot routine
  1016.     mov    pincy,offset pincym    ; inc y routine
  1017.     mov    xmult,5            ; Scale TEK to mono by 640/1024
  1018.     mov    xdiv,8            ;  so that 0-1023 converts to 0-639
  1019.     mov    xmax,640-8        ; x-coord of rightmost character
  1020.     mov    ymult,10        ; vertical scale for mono is 200/780
  1021.     mov    ydiv,39
  1022.     mov    ybot,200        ; bottom of screen is y = 200 for Bios
  1023.     jmp    tekin13            ; Uses TEXT mode, for safety
  1024.  
  1025.                     ; test for CGA
  1026. tekin11:mov    graph_mode,cga        ; set CGA high resolution graphics
  1027.     mov    segscn,segcga        ; CGA screen segment
  1028.     jmp    tekin13
  1029.  
  1030.                     ; Set Graphics mode
  1031. tekin13:cmp    tekident,0        ; just identifying?
  1032.     je    tekin13b        ; e = no
  1033.     jmp    tekin16            ; ne = yes
  1034. tekin13b:cmp    graph_mode,wyse700    ; Wyse ?
  1035.     jne    tekin13a        ; ne = no
  1036.     call    wygraf            ; set Wyse graphics mode, clear regen
  1037.     jmp     tekin16        ; restore screen
  1038. tekin13a:cmp    graph_mode,hercules    ; Hercules?
  1039.     jne    tekin14            ; ne = no
  1040.     call    hgraf            ; set Herc graphics mode, clear regen
  1041.     or    tekflg,1        ; say doing Tekmode
  1042.     jmp     tekin16        ; restore screen
  1043. tekin14:xor    ah,ah            ; set screen mode
  1044.     mov    al,graph_mode        ;  to this screen mode
  1045.     cmp    tekgraf,3        ; user wants "VGA" modes (640x480)?
  1046.     jne    tekin14a        ; ne = no
  1047.     push    ax
  1048.     mov    ax,1a00h        ; VGA, read display config code
  1049.     int    screen
  1050.     pop    ax
  1051.     cmp    bl,0bh            ; MCGA mono?
  1052.     jne    tekin14b        ; ne = no
  1053.     mov    al,monoega
  1054.     mov    graph_mode,al
  1055.     jmp    short tekin14c
  1056. tekin14b:cmp    bl,0ch            ; MCGA color?
  1057.     jne    tekin14d        ; ne = no
  1058.     mov    al,ega
  1059.     mov    graph_mode,al
  1060. tekin14c:mov    ydiv,78            ; scale y by 350/780
  1061.     mov    segscn,segega        ; use ega screen segment
  1062.     mov    psetup,offset psetupe    ; plot setup routine
  1063.     mov    plotptr,offset pltcga    ; ega dot plot routine
  1064.     mov    gfplot,offset bpltcga    ; ega area fill routine
  1065.     mov    pincy,offset pincye    ; inc y routine
  1066.     mov    putc,offset gputc    ; character display routine
  1067. tekin14d:
  1068.     cmp    al,monoega        ; yes, allow high resolution stuff?
  1069.     jb    tekin14a        ; b = no
  1070.     cmp    al,ega            ; ditto
  1071.     ja    tekin14a        ; a = no
  1072.     add    al,2            ; use modes 17(b/w) and 18(10)(color)
  1073.     mov    ybot,479        ; text screen bottom is 479 on VGA
  1074.     mov    ymult,48
  1075. tekin14a:cmp    tekident,0        ; just identifying screen size etc?
  1076.     jne    tekin16            ; ne = yes, do not invoke graphics
  1077.     cmp    gpage,0            ; only page 0 available?
  1078.     je    tekin15            ; e = yes, and watch for Bios errors
  1079.     cmp    inited,0        ; first time through?
  1080.     je    tekin15            ; e = yes, clear the page of old junk
  1081.     or    al,80h            ; save regen buffer (save area too)
  1082. tekin15:int    screen            ; Bios Set Mode.
  1083.     mov    ax,40h            ; DOS 4 GRAPHICS.COM may see high bit
  1084.     mov    es,ax            ;  and be confused. Clear it from Bios
  1085.     and    byte ptr es:[49h],7fh    ;  word area for some clones
  1086.     or    tekflg,1        ; say doing Tekmode
  1087.  
  1088. tekin16:cmp    tekident,0        ; just identifying?
  1089.     jne    tekin16a        ; ne = yes
  1090.     cmp    inited,0        ; inited yet?
  1091.     jne    tekin19            ; ne = yes, restore screen
  1092.     mov    ttstate,offset tektxt    ; do displayable text
  1093.     mov    prestate,offset tektxt    ; set a previous state of text
  1094.     mov    inited,1        ; say we have initialized
  1095.     jmp    short tekin16b        ; and init the color palette
  1096. tekin16a:mov    si,offset colpal    ; active color palette
  1097.     cmp    havepal,0        ; have a color palette yet?
  1098.     jne    tekin17            ; yes, use active palette
  1099. tekin16b:mov    si,offset mondef    ; default monochrome colors
  1100.     cmp    plotptr,offset pltcga    ; using CGA style graphics?
  1101.     je    tekin17            ; e = yes
  1102.     cmp    graph_mode,mono        ; pure mono text system?
  1103.     je    tekin17            ; e = yes
  1104.     cmp    graph_mode,monoega    ; ega, but monochrome?
  1105.     je    tekin17            ; e = no
  1106.     mov    si,offset coldef    ; use color palette
  1107. tekin17:mov    havepal,1        ; say have a color palette
  1108.     mov    al,[si+7]        ; foreground color = palette 7
  1109.     mov    gfcol,al
  1110.     mov    al,[si]            ; background color = palette 0
  1111.     mov    gbcol,al
  1112.     mov    cx,16
  1113.     mov    di,offset colpal    ; VT340 active color palette
  1114.     push    es
  1115.     push    ds
  1116.     pop    es
  1117.     cld
  1118.     rep    movsb            ; reinit palette entries
  1119.     pop    es
  1120.     call    fixcolor        ; correct color mapping for some bds
  1121.     mov    al,gfcol
  1122.     mov    tfcol,al        ; remember current coloring
  1123.     mov    al,gbcol
  1124.     mov    tbcol,al
  1125.     cmp    tekident,0        ; just identifying?
  1126.     jne    tekin21            ; ne = yes
  1127.     call    tekcls            ; clear screen, for ega coloring
  1128.     jmp    short tekin20
  1129.  
  1130. tekin19:cmp    vtclear,0        ; clear screen?
  1131.     je    tekin19a        ; e = no
  1132.     call    tekcls            ; clear screen, use existing colors
  1133.     jmp    short tekin20
  1134. tekin19a:call    tekrest            ; restore old graphics screen
  1135.     mov    al,tfcol        ; and coloring
  1136.     mov    gfcol,al
  1137.     mov    al,tbcol
  1138.     mov    gbcol,al
  1139. tekin20:call    setcursor        ; set text cursor, if any
  1140.     mov    ax,250
  1141.     call    tekwait            ; 250 ms wait for display adapter
  1142.     mov    ax,flow            ; get flow control word
  1143.     xchg    ah,al            ; get xon into al
  1144.     or    al,al            ; able to send xon?
  1145.     jz    tekin21            ; z = no
  1146.     call    outmodem        ; tell host xon
  1147. tekin21:mov    al,chcontrol        ; opaque/transparent char writing
  1148.     mov    bscontrol,al        ; set destructive BS control
  1149.     mov    spcontrol,al        ; set destructive SPACE control
  1150.     mov    tekident,0
  1151.     mov    bypass,0        ; clear Bypass flag
  1152.     clc                ; clear carry for success
  1153.     pop    es
  1154.     pop    di
  1155.     pop    si
  1156.     pop    dx
  1157.     pop    cx
  1158.     pop    bx
  1159.     pop    ax
  1160.     ret
  1161. tekini    endp
  1162.  
  1163. TEKRINT proc    far            ; Tek reinitialization entry point
  1164.     call    dword ptr endptr    ; exit cleanly if alread in Tek mode
  1165.     xor    ax,ax            ; get a null
  1166.     mov    inited,al        ; do complete reinitialization
  1167.     mov    tekflg,al
  1168.     mov    xcenter,ax        ; forget center of screen
  1169.     mov    ycenter,ax
  1170.     call    tekini
  1171.     ret
  1172. TEKRINT    endp
  1173.  
  1174. ; End TEK emulation, recover previous screen
  1175. TEKEND    proc    far
  1176.     mov    ttstate,offset tektxt    ; set an initial state
  1177.     mov    prestate,offset tektxt    ; and a previous state
  1178.     test    tekflg,1        ; running as a Tek terminal now?
  1179.     jnz    teknd1            ; nz = yes
  1180.     mov    tekflg,0        ; returning to text emulator
  1181.     ret                ; else return as is
  1182. teknd1:    call    remcursor        ; remove text cursor, if any
  1183.     call    teksave            ; save graphics screen to page 1
  1184.     cmp    graph_mode,hercules    ; Hercules?
  1185.     jne    teknd2            ; ne = no
  1186.     call    htext            ; yes then set up Hercules text mode
  1187. teknd2:    call    mousexit        ; restore mouse state, if any
  1188.     xor    ah,ah            ; set video mode
  1189.     mov    al,curmode        ; restore previous screen mode
  1190.     int    screen            ; revert to text screen
  1191.     call    trestscr        ; restore text screen
  1192.     mov    dx,cursor        ; saved cursor position
  1193.     xor    bh,bh            ; page 0
  1194.     mov    ah,2            ; set cursor
  1195.     int    screen
  1196.     mov    tekflg,0        ; returning to text emulator
  1197.     mov    lastc,0
  1198.     mov    bypass,0        ; reset bypass condition
  1199.     mov    visible,0        ; next move is invisible
  1200.     clc
  1201.     ret
  1202. TEKEND    ENDP
  1203.  
  1204.  
  1205. ;Terminal emulation. Enter with received character in AL.
  1206. TEKEMU    proc    far            ; main emulator
  1207.     call    tektt            ; local emulator routine
  1208.     ret
  1209. TEKEMU    endp
  1210.  
  1211. tektt    proc    near
  1212.     test    tekflg,1        ; running as a Tek device?
  1213.     jnz    tektt1            ; nz = yes
  1214.     push    ax
  1215.     call    tekini            ; init now
  1216.     pop    ax
  1217.     mov    ttstate,offset tektxt    ; initial state
  1218.     mov    prestate,offset tektxt    ; set a previous state of text
  1219.     jnc    tektt1            ; nc = succeeded
  1220.     ret                ; else failed to init, just return
  1221. tektt1:    test    al,80h            ; high bit set?
  1222.     jz    tektt1a            ; z = no
  1223.     cmp    al,9fh            ; in range for C1 controls?
  1224.     ja    tektt1a            ; a = no
  1225.     push    ax            ; save the char
  1226.     mov    al,escape        ; make 7-bit control version
  1227.     call    tektt2            ; act on escape
  1228.     pop    ax
  1229.     sub    al,40h            ; get second char of 7-bit control
  1230.  
  1231. tektt1a:and    al,7fh            ; force Tek chars to be 7 bits
  1232.     or    al,al            ; NUL char?
  1233.     jnz    tektt2            ; nz = no
  1234.     ret                ; yes, ignore it (before logging)
  1235. tektt2:    test    yflags,capt        ; capturing output?
  1236.     jz    tektt4            ; z = no, forget this part
  1237.     push    ax            ; save char
  1238.     call    tcptchr            ; give it captured character
  1239.     pop    ax            ; restore character and keep going
  1240. tektt4:    test    yflags,trnctl        ; debug? if so use tty mode
  1241.     jz    tektt5            ; z = no
  1242.     cmp    al,DEL            ; DEL char?
  1243.     jne    tektt4a            ; ne = no
  1244.     mov    al,5eh            ; make DEL a caret query mark
  1245.     call    outscrn
  1246.     mov    al,3fh            ; the query mark
  1247.     call    outscrn
  1248.     ret
  1249. tektt4a:cmp    al,' '            ; control char?
  1250.     jae    tektt4b            ; ne = no
  1251.     push    ax
  1252.     mov    al,5eh            ; caret
  1253.     call    outscrn
  1254.     pop    ax
  1255.     add    al,'A'-1        ; make char printable
  1256. tektt4b:call    outscrn
  1257.     ret
  1258.  
  1259. tektt5:    cmp    bypass,0        ; Bypass mode off?
  1260.     jne    tektt5a            ; ne = no, on, ignore all incoming
  1261.     call    ttstate            ; do current state
  1262.     ret
  1263. tektt5a:cmp    al,' '            ; incoming control code?
  1264.     jae    tektt5b            ; ae = no
  1265.     mov    bypass,0        ; turn off bypass
  1266.     call    ttstate            ; act on it
  1267. tektt5b:ret
  1268. tektt    endp
  1269.      
  1270. TEKTXT    proc    near            ; Dispatch on text characters
  1271.     mov    ttstate,offset tektxt    ; this is our state
  1272.     push    ax
  1273.     call    setcursor        ; show text cursor
  1274.     pop    ax
  1275.     cmp    al,DEL            ; RUBOUT?
  1276.     jne    tektx1            ; ne = no
  1277.     mov    al,bs            ; make BS
  1278.     jmp    short tektx7
  1279. tektx1:    cmp    al,CR            ; carriage return (^M)?
  1280.     je    tektx7            ; e = yes
  1281.     cmp    al,LF            ; line feed (^J)?
  1282.     je    tektx7            ; e = yes
  1283.     cmp    al,FF            ; form feed (^L)?
  1284.     jne    tektx4            ; ne = no
  1285.     call    tekcls            ; clear the screen
  1286.     ret
  1287. tektx4:    cmp    al,VT            ; vertical tab (^K)?
  1288.     je    tektx7
  1289.     cmp    al,bell            ; bell (^G)?
  1290.     jne    tektx5            ; ne = no
  1291.     call    tekbeep
  1292.     ret
  1293. tektx5:    cmp    al,tab            ; horizontal tab (^I)?
  1294.     je    tektx7            ; e = yes
  1295.     cmp    al,BS            ; backspace (^H)?
  1296.     je    tektx7            ; e = yes
  1297.     cmp    al,' '            ; control char?
  1298.     jae    tektx7            ; ae = no
  1299.     jmp    tekctl            ; process control char
  1300. tektx7:    call    outscrn            ; output character to the screen
  1301. tektx8:    ret
  1302. TEKTXT    endp
  1303.  
  1304.  
  1305. tekctl    proc    near            ; Control characters:
  1306.     cmp    al,GS            ; Line plot command?
  1307.     jne    tekctl1            ; ne = no
  1308.     mov    visible,0        ; next move is invisible
  1309.     and    status,not txtmode    ; set status report byte
  1310.     mov    ttstate,offset tekline    ; expect coordinates next
  1311.     call    remcursor        ; remove text cursor
  1312.     ret
  1313. tekctl1:cmp    al,RS            ; Incremental dot command?
  1314.     jne    tekctl2            ; ne = no
  1315.     and    status,not txtmode    ; set status report
  1316.     mov    ttstate,offset tekrlin    ; expect pen command next
  1317.     call    remcursor        ; remove text cursor
  1318.     ret
  1319. tekctl2:cmp    al,FS            ; Point plot command?
  1320.     jne    tekctl3            ; ne = no
  1321.     mov    visible,0        ; next move is invisible
  1322.     and    status,not txtmode    ; set status report byte
  1323.     mov    ttstate,offset tekpnt
  1324.     call    remcursor        ; remove text cursor
  1325.     ret
  1326. tekctl3:cmp    al,US            ; assert text mode? [bjh]
  1327.     jne    tekctl4            ; ne = no
  1328.     or    status,txtmode        ; set status report byte
  1329.     mov    ttstate,offset tektxt    ; go to TEKTXT next time
  1330.     mov    visible,0        ; next move is invisible
  1331.     call    setcursor        ; restore text cursor
  1332.     ret
  1333. tekctl4:cmp    al,ESCAPE        ; Escape?
  1334.     jne    tekctl5            ; ne = no
  1335.     call    remcursor        ; remove text cursor
  1336.     or    status,txtmode        ; set status report byte
  1337.     cmp    ttstate,offset tekesc    ; already in escape state?
  1338.     je    tekctl7            ; e = yes, nest no further
  1339.     push    ttstate            ; current state
  1340.     pop    prestate        ; save here as previous state
  1341.     mov    ttstate,offset tekesc    ; next state parses escapes
  1342.     ret
  1343.  
  1344. tekctl5:cmp    al,CAN            ; Control X? (exits Tek sub mode)
  1345.     jne    tekctl7            ; ne = no, stay in current state
  1346.     mov    ttstate,offset tektxt    ; back to text mode
  1347.     mov    bypass,1        ; turn on bypass mode
  1348.     cmp    flags.vtflg,tttek    ; main Tek emulator?
  1349.     je    tekctl6            ; e = yes, ignore the ^X
  1350.     call    tekend            ; else exit sub mode
  1351.     mov    visible,0        ; next move is invisible
  1352. tekctl6:mov    prestate,offset tektxt    ; make previous state text
  1353. tekctl7:ret
  1354. tekctl    endp
  1355.  
  1356. TEKESC    proc    near            ; Process ESC <following text>
  1357.     mov    ninter,0        ; initialize parsing
  1358.     mov    ttstate,offset tekesc    ; in case get here from msz file
  1359.     cmp    inited,0        ; inited yet? (msz call)
  1360.     jne    tekesc1            ; ne = yes
  1361.     call    tekini            ; init now
  1362.     mov    prestate,offset tektxt    ; set a previous state of text
  1363.     jnc    tekesc1            ; nc = succeeded
  1364.     ret                ; else failed to init, just return
  1365.     
  1366. tekesc1:cmp    al,20h            ; in intermediates, column 2?
  1367.     jb    tekesc3            ; b = no
  1368.     cmp    al,2fh
  1369.     ja    tekesc3            ; a = no
  1370.     mov    ttstate,offset tekesc1    ; stay in this state while intermeds
  1371.     mov    bx,ninter        ; number of intermediates
  1372.     cmp    bx,maxinter        ; done enough already?
  1373.     jae    tekesc2            ; ae = yes, ignore the excess
  1374.     mov    inter[bx],al        ; store this one
  1375.     inc    ninter            ; one more
  1376.     cmp    inter,'/'        ; HDS2000/3000 Final char?
  1377.     je    tekesc3            ; e = yes, process specially like '['
  1378. tekesc2:ret                ; get more input
  1379.     
  1380.                     ; Final char is in AL, dispatch on it
  1381. tekesc3:mov    ttstate,offset tektxt    ; set new state
  1382.     mov    esctype,al        ; save kind of escape sequence
  1383.     mov    bx,offset esctab    ; ESC dispatch table
  1384.     call    atdispat        ; dispatch on AL
  1385.     ret
  1386. TEKESC    endp    
  1387.  
  1388. tekeseq    proc    near            ; process Escape and Device Contrl seq
  1389.     call    tparstart        ; init escape sequence parser
  1390.     mov    ttstate,offset escparse    ; do parsing next
  1391.     ret
  1392. tekeseq    endp
  1393.  
  1394. ; State for gathering text to feed escape sequence parser
  1395. escparse proc    near
  1396.     cmp    al,' '            ; embedded control code?
  1397.     jb    escpar2            ; b = yes, process now
  1398.     call    tparser            ; far call, to call real parser
  1399.     jnc    escpar1            ; nc = success
  1400.     push    prestate        ; recover previous state
  1401.     pop    ttstate
  1402.     stc
  1403. escpar1:ret
  1404. escpar2:call    tekctl            ; process embedded control code
  1405.     push    prestate        ; get previous state
  1406.     pop    ttstate            ; restore it
  1407.     ret
  1408. escparse endp
  1409.  
  1410. ; Escape sequence parser completion routine
  1411. ; AL has Final character of escape sequence
  1412. XPARDONE PROC    FAR            ; called by tpardone when done
  1413.     cmp    esctype,'['        ; ansi escape sequence (ESC [)?
  1414.     jne    xpardo3            ; ne = no
  1415.     mov    bx,offset anstab    ; ANSI ESC [ table
  1416.     call    atdispat        ; dispatch on Final char in AL
  1417.     jmp    short xpardo5
  1418.  
  1419. xpardo3:cmp    esctype,'/'        ; HDS escape sequence (ESC /)?
  1420.     jne    xpardo4            ; ne = no
  1421.     call    hdsesc            ; analyze
  1422.     jmp    short xpardo5
  1423.  
  1424. xpardo4:cmp    esctype,'P'        ; DCS introducer?
  1425.     jne    xpardo5            ; ne = no
  1426.     call    tekdcs            ; grab parameters etc, prep strings
  1427.     ret
  1428.  
  1429. xpardo5:push    prestate        ; recover previous state
  1430.     pop    ttstate
  1431.     ret
  1432. XPARDONE ENDP
  1433.                 ; ESC <char> action routines
  1434.                 ; exit each by putting prestate into ttstate
  1435.  
  1436. tekenq    proc    near            ; ESC-^E Enquiry for cursor position
  1437.     mov    bypass,1        ; set bypass mode
  1438.     call    sendstat        ; send status
  1439.     push    prestate        ; get previous state
  1440.     pop    ttstate            ; restore it
  1441.     ret
  1442. tekenq    endp
  1443.  
  1444. tekcan    proc    near            ; ESC ^X
  1445.     push    prestate        ; get previous state
  1446.     pop    ttstate            ; restore it
  1447.     jmp    tekctl            ; process in controls section
  1448. tekcan    endp
  1449.  
  1450. tekgin    proc    near            ; ESC-^Z Enter GIN mode
  1451.     cmp    graph_mode,mono        ; Monochrome text mode?
  1452.     je    tekgin1            ; e = yes, no crosshairs in text mode
  1453.     mov    bypass,1        ; turn on GIN mode bypass conditon
  1454.     call    crossini        ; preset crosshairs
  1455.     call    croshair        ; activate the cross-hairs
  1456.     jmp    short tekgin2
  1457. tekgin1:call    tekbeep            ; tell the user we are unhappy
  1458. tekgin2:push    prestate        ; get previous state
  1459.     pop    ttstate            ; restore it
  1460.     ret
  1461. tekgin    endp
  1462.  
  1463. tektwo    proc    near            ; ESC 2 (Exit Tek mode)
  1464.     mov    al,CAN            ; force Control-X
  1465.     jmp    tekcan            ; process there as ESC ^X
  1466. tektwo    endp
  1467.  
  1468. tekqury    proc    near            ; query mark (ESC ? means DEL)
  1469.     mov    al,DEL            ; replace with DEL code
  1470.     push    prestate        ; get previous state
  1471.     pop    ttstate            ; restore it
  1472.     ret
  1473. tekqury    endp
  1474.  
  1475. tekfill    proc    near            ; Fill series ESC @ .. ESC M
  1476.     sub    al,'@'            ; remove bias
  1477.     mov    bl,al
  1478.     xor    bh,bh
  1479.     shl    bx,1            ; make a word index
  1480.     mov    bx,fillist[bx]        ; get pointer to the pattern from list
  1481.     mov    fillptr,bx        ; assign this pattern pointer
  1482.     push    prestate        ; get previous state
  1483.     pop    ttstate            ; restore it
  1484.     ret
  1485. tekfill    endp
  1486.  
  1487. teklpat    proc    near            ; ESC accent grave line pattern series
  1488.     cmp    al,'g'            ; accent ... lowercase g?
  1489.     jbe    teklpa2            ; be = yes
  1490.     cmp    al,'o'            ; bold patterns ESC h..ESC o?
  1491.     ja    teklpa1            ; a = no
  1492.     sub    al,'h'-accent        ; map bold to normal
  1493.     jmp    short teklpa2
  1494. teklpa1:sub    al,'x'-'f'        ; user sets,map x to f, y to g, z to h
  1495. teklpa2:push    bx
  1496.     mov    bl,al
  1497.     sub    bl,accent        ; remove bias
  1498.     cmp    bl,8            ; nine patterns, ignore others
  1499.     jbe    teklpa3            ; be = ok, make others accent, solid
  1500.     xor    bl,bl            ; solid pattern
  1501. teklpa3:xor    bh,bh
  1502.     shl    bx,1            ; make this a word index
  1503.     mov    bx,linetab[bx]        ; get line pattern word
  1504.     mov    linepat,bx        ; save in active word
  1505.     pop    bx            ; return to previous mode
  1506.     push    prestate        ; get previous state
  1507.     pop    ttstate            ; restore it
  1508.     ret
  1509. teklpat    endp
  1510.  
  1511. ; Detect exit Tek submode command ESC [ ? 38 l  from VT340's
  1512. escexit    proc    near
  1513.     cmp    lparam,'?'        ; possible "ESC [ ? 38 l"?
  1514.     jne    escex2            ; ne = no
  1515.     cmp    nparam,1        ; just one numeric parameter?
  1516.     jne    escex2            ; ne = no
  1517.     cmp    al,'l'            ; ESC [ ? Pn l?
  1518.     jne    escex4            ; ne = no, try 'h'
  1519.     cmp    param,38        ; correct value?
  1520.     jne    escex3            ; ne = no
  1521.     cmp    flags.vtflg,tttek    ; are we a full Tek terminal now?
  1522.     je    escex1            ; e = yes, stay that way
  1523.     call    dword ptr endptr    ; call far tekend
  1524.     ret
  1525. escex1:    mov    ttstate,offset tektxt
  1526.     mov    al,CAN            ; simulate arrival of Control-X
  1527.     jmp    tektxt            ; process char as text
  1528. escex2:    ret
  1529. escex3:    cmp    param,34        ; ESC [ ? 34 l?
  1530.     jne    escex2            ; ne = no
  1531.     call    tekend            ; play safe and restore text mode
  1532.     xor    ax,ax            ; tell tekmac it's a Reset flavor
  1533.     call    tekmac            ; returns only if successful
  1534.     ret
  1535. escex4:    cmp    al,'h'            ; ESC ... h?
  1536.     jne    escex3            ; ne = no
  1537.     cmp    param,34        ; ESC [ ? 34 h?
  1538.     jne    escex2            ; ne = no
  1539.     call    tekend            ; play safe and restore text mode
  1540.     mov    ax,1            ; tell tekmac it's a Set flavor
  1541.     call    tekmac            ; returns only if successful
  1542.     ret
  1543. escexit    endp
  1544.  
  1545. ; Human Data Systems 2000/3000 style escape sequences (ESC / params Final)
  1546. ; Final character is in AL
  1547. hdsesc    proc    near
  1548.     cmp    al,'x'            ; draw an empty rectangle?
  1549.     jne    hdsesc0            ; ne = no
  1550.     call    rectdraw
  1551.     jmp    short hdsesc2a
  1552. hdsesc0:cmp    al,'y'            ; draw a filled rectangle?
  1553.     jne    hdsesc1            ; ne = no
  1554.     call    rectfil            ;do xhome,yhome,xwidth,yheight,pattern
  1555.     jmp    short hdsesc2a
  1556. hdsesc1:cmp    al,'z'            ; draw and fill rectangle?
  1557.     jne    hdsesc2            ; ne = no
  1558.     call    rectfil            ; do fill before border
  1559.     call    rectdraw        ; do border
  1560.     jmp    short hdsesc2a
  1561. hdsesc2:cmp    ninter,0        ; any intermediates?
  1562.     jne    hdsesc2a        ; ne = yes, failure
  1563.     cmp    lparam,0        ; letter parameter?
  1564.     jne    hdsesc2a        ; ne = yes, failure
  1565.     cmp    nparam,1        ; just zero or one numeric parameter?
  1566.     ja    hdsesc9            ; a = no
  1567.     cmp    al,'a'            ; user defined pattern?
  1568.     jb    hdsesc3            ; b = no
  1569.     cmp    al,'c'
  1570.     ja    hdsesc3            ; a = no
  1571.     sub    al,'a'            ; 'a' is first of three user patterns
  1572.     xor    ah,ah            ;  store as 'f,g,h' in the series
  1573.     mov    bx,ax
  1574.     shl    bx,1            ; make a word index
  1575.     mov    ax,param[0]        ; get the 16-bit pattern
  1576.     mov    linetab[bx+12],ax    ; store in user defined pattern
  1577. hdsesc2a:push    prestate        ; get previous state
  1578.     pop    ttstate            ; restore it
  1579.     ret
  1580.  
  1581. hdsesc3:cmp    al,'d'            ; "Data Level" (pixel ops)?
  1582.     jne    hdsesc4            ; ne = no
  1583.     mov    cx,param        ; get the parameter value
  1584.     mov    al,pixfor        ; assume foreground only ESC / 0 d
  1585.     cmp    cl,1            ; something else?
  1586.     jb    hdsesc3a        ; b = no
  1587.     mov    al,pixbak        ; assume background only ESC / 1 d
  1588.     cmp    cl,2            ; something else?
  1589.     jb    hdsesc3a        ; b = no
  1590.     mov    al,pixxor        ; assume XOR  ESC / 2 d
  1591.     cmp    cl,3            ; something else?
  1592.     jb    hdsesc3a        ; b = no
  1593.     ja    hdsesc3b        ; a = unknown, ignore
  1594.     mov    al,pixfor+pixbak    ; write both absolute  ESC / 3 d
  1595. hdsesc3a:mov    ccode,al        ; use as pixel op coding
  1596. hdsesc3b:push    prestate        ; get previous state
  1597.     pop    ttstate            ; restore it
  1598.     ret
  1599.  
  1600. hdsesc4:cmp    al,'h'            ; set space, backspace control?
  1601.     je    hdsesc4a        ; e = yes
  1602.     cmp    al,'l'            ; reset space, backspace control?
  1603.     jne    hdsesc9            ; ne = no
  1604.     xor    ah,ah            ; say resetting
  1605.     jmp    short hdsesc5
  1606. hdsesc4a:mov    ah,1            ; say setting
  1607. hdsesc5:cmp    param,2            ; space control?
  1608.     jne    hdsesc5a        ; ne = no
  1609.     mov    spcontrol,ah        ; reset (0) or set destructive SPACE
  1610.     push    prestate        ; get previous state
  1611.     pop    ttstate            ; restore it
  1612.     ret
  1613. hdsesc5a:cmp    param,9            ; destructive backspace?
  1614.     jne    hdsesc13        ; ne = no
  1615.     mov    bscontrol,ah        ; reset (0) or set destructive BS
  1616.  
  1617. hdsesc9:cmp    al,'C'            ; user defined fill pattern #1?
  1618.     jne    hdsesc10        ; ne = no
  1619.     mov    di,offset filpat13    ; storage area for user pattern #1
  1620.     jmp    short hdsesc11
  1621. hdsesc10:cmp    al,'D'            ; user defined fill pattern #2?
  1622.     jne    hdsesc11        ; ne = no
  1623.     mov    di,offset filpat14    ; storage area for user pattern #2
  1624. hdsesc11:mov    cx,8            ; do 8 paramters
  1625.     xor    bx,bx
  1626. hdsesc12:mov    ax,param[bx]        ; copy 8 bit fill pattern
  1627.     mov    [di],al            ; to array
  1628.     add    bx,2
  1629.     inc    di
  1630.     loop    hdsesc12
  1631. hdsesc13:push    prestate        ; get previous state
  1632.     pop    ttstate            ; restore it
  1633.     ret
  1634. hdsesc    endp
  1635.  
  1636. ; Analyze ESC [ Pn ; Pn m  color command    
  1637. ; where Pn = 30-37 foreground color, 40-47 background color, ANSI standard
  1638. ; Enter with escape sequence already parsed.
  1639. TEKCOL    proc    near
  1640.     push    si
  1641.     cld
  1642.     mov    al,gfcol        ; update these in case error
  1643.     mov    tfcol,al
  1644.     mov    al,gbcol
  1645.     mov    tbcol,al
  1646.     mov    si,offset param        ; parameters from parser
  1647.     mov    cx,nparam        ; number of parameters
  1648. tekco1:    jcxz    tekco5            ; z = none left
  1649.     lodsw                ; parameter to ax
  1650.     dec    cx
  1651.     or    ax,ax            ; 0, remove intensity, set b/w?
  1652.     jnz    tekco2            ; nz = no
  1653.     mov    tfcol,7            ; regular white
  1654.     mov    tbcol,0            ;  on black
  1655.     jmp    short tekco1
  1656.  
  1657. tekco2:    cmp    ax,1            ; intensity bit?
  1658.     jne    tekco3            ; ne = no
  1659.     or    tfcol,8            ; set foreground intensity
  1660.     jmp    short tekco1
  1661.     
  1662. tekco3:    cmp    ax,30            ; foreground series?
  1663.     jb    tekco1            ; b = no
  1664.     cmp    ax,37
  1665.     ja    tekco4            ; a = no
  1666.     sub    ax,30            ; remove bias
  1667.     push    bx
  1668.     mov    bl,al
  1669.     xor    bh,bh
  1670.     mov    al,byte ptr colortb[bx]    ; reverse coloring
  1671.     pop    bx
  1672.     and    tfcol,not (7)        ; retain intensity bit
  1673.     or    tfcol,al        ; remember foreground color
  1674.     jmp    short tekco1
  1675.  
  1676. tekco4:    cmp    ax,40
  1677.     jb    tekco1
  1678.     cmp    ax,47            ; legal value?
  1679.     ja    tekco1            ; a = no
  1680.     sub    al,40
  1681.     push    bx
  1682.     mov    bl,al
  1683.     xor    bh,bh
  1684.     mov    al,byte ptr colortb[bx]    ; reverse coloring
  1685.     pop    bx
  1686.     mov    tbcol,al        ; remember background color
  1687.     jmp    short tekco1
  1688.  
  1689. tekco5:    cmp    ninter,0        ; intermediates?
  1690.     jne    tekco7            ; ne = yes, no go
  1691.     cmp    lparam,0        ; letter parameter?
  1692.     jne    tekco7            ; ne = yes, no go
  1693.     cmp    nparam,0        ; number of ansi arguments, zero?
  1694.     ja    tekco6            ; a = no, got some
  1695.     mov    tbcol,0            ; none is same as 0, set b/w
  1696.     mov    tfcol,7
  1697. tekco6:    mov    al,tbcol        ; success, store coloring
  1698.     mov    gbcol,al        ; set background color
  1699.     mov    al,tfcol
  1700.     mov    gfcol,al        ; set foreground color
  1701.     call    fixcolor        ; do special ega corrections
  1702.     mov    al,gfcol        ; update these in case error
  1703.     mov    tfcol,al
  1704.     mov    colpal[7],al        ; foreground goes here
  1705.     mov    al,gbcol
  1706.     mov    tbcol,al
  1707.     mov    colpal[0],al        ; background goes here
  1708. tekco7:    pop    si
  1709.     clc
  1710.     ret
  1711. TEKCOL    endp
  1712.  
  1713. ; Revise screen color codes for ega boards with mono displays and limited
  1714. ; memory.
  1715. fixcolor proc    near
  1716.     cmp    graph_mode,ega        ; one of these ega modes?
  1717.     je    fixcol6            ; e = yes
  1718.     cmp    graph_mode,colorega
  1719.     je    fixcol6
  1720.     cmp    graph_mode,monoega
  1721.     je    fixcol6
  1722.     cmp    plotptr,offset pltcga    ; using CGA style graphics?
  1723.     jne    fixcol5            ; ne = no
  1724.     and    gfcol,7            ; strip intensity
  1725.     jmp    short fixcol6        ; keep colors different
  1726. fixcol5:ret                ; else ignore color corrections
  1727. fixcol6:mov    ah,gfcol
  1728.     mov    al,gbcol
  1729.     cmp    graph_mode,monoega    ; monochrome ega display?
  1730.     jne    fixcol3            ; ne = no
  1731.     test    al,7            ; bright backgound?
  1732.     jnz    fixcol1            ; nz = yes
  1733.     mov    ah,1            ; normal foreground
  1734.     test    gfcol,8            ; intensity on?
  1735.     jz    fixcol1            ; z = no
  1736.     mov    ah,5            ; say bright foreground
  1737. fixcol1:test    al,7            ; black backgound?
  1738.     jz    fixcol2            ; z = yes
  1739.     mov    al,1            ; regular video
  1740. fixcol2:cmp    ah,al            ; same color in both?
  1741.     jne    fixcol3            ; ne = no
  1742.     mov    ah,1            ; make foreground regular
  1743.     xor    al,al            ;  and background black
  1744. fixcol3:mov    gfcol,ah
  1745.     mov    gbcol,al
  1746.     cmp    gpage,0            ; minimal memory (64KB mono and ega)?
  1747.     ja    fixcol4            ; a = no, enough, else strange mapping
  1748.     mov    al,gfcol        ; fix coloring to map planes C0 to C1
  1749.     and    al,5            ; and C2 to C3 (as 0, 3, 0Ch, or 0Fh)
  1750.     mov    ah,al            ; make a copy
  1751.     shl    ah,1            ; duplicate planes C0, C2 in C1, C3
  1752.     or    al,ah            ; merge the bits
  1753.     mov    gfcol,al        ; store proper foreground color
  1754.     mov    al,gbcol        ; repeat for background color
  1755.     and    al,5
  1756.     mov    ah,al
  1757.     shl    ah,1
  1758.     or    al,ah
  1759.     mov    gbcol,al
  1760. fixcol4:ret
  1761. fixcolor endp
  1762.  
  1763. tekrid    proc    near            ; report Tek screen parameters
  1764.     cmp    lparam,'?'        ; possible "ESC [ ? 38 l"?
  1765.     jne    tekridx            ; ne = no
  1766.     cmp    nparam,1        ; just one numeric parameter?
  1767.     jne    tekridx            ; ne = no
  1768.     cmp    param,256        ; correct value?
  1769.     je    tekrid1            ; e = yes
  1770. tekridx:ret
  1771. tekrid1:push    es            ; as ESC [ ? 256; height; len; #col n
  1772.     push    ds
  1773.     pop    es
  1774.     cld
  1775.     mov    di,offset tempname    ; a temp buffer
  1776.     mov    al,escape        ; report
  1777.     stosb
  1778.     mov    al,'['
  1779.     stosb
  1780.     mov    al,'?'
  1781.     stosb
  1782.     mov    ax,256
  1783.     call    dec2di            ; write ascii digits
  1784.     mov    al,';'
  1785.     stosb
  1786.     mov    ax,ybot            ; do height
  1787.     inc    ax
  1788.     cmp    graph_mode,mono        ; pure mono text system?
  1789.     jne    tekrid7a        ; ne = no
  1790.     mov    ax,24
  1791. tekrid7a:call    dec2di
  1792.     mov    al,';'            ; separator
  1793.     stosb
  1794.     mov    ax,xmax            ; width
  1795.     add    ax,8            ; in dots
  1796.     cmp    graph_mode,mono        ; pure mono text system?
  1797.     jne    tekrid7b        ; ne = no
  1798.     mov    ax,80
  1799. tekrid7b:call    dec2di
  1800.     mov    al,';'            ; separator
  1801.     stosb
  1802.     mov    al,'1'            ; screen colors, assume 1
  1803.     stosb
  1804.     cmp    plotptr,offset pltcga    ; using CGA style graphics?
  1805.     je    tekrid4            ; e = yes
  1806.     cmp    graph_mode,monoega    ; monochrome monitor on ega?
  1807.     je    tekrid4            ; e = yes
  1808.     cmp    graph_mode,mono        ; pure mono text system?
  1809.     jne    tekrid3
  1810.     mov    byte ptr [di-1],'0'    ; say zero colors
  1811.     jmp    short tekrid4
  1812. tekrid3:mov    al,'6'
  1813.     stosb                ; say 16
  1814. tekrid4:mov    al,'n'            ; end of string
  1815.     stosb
  1816.     call    outstrng        ; send the string
  1817.     pop    es
  1818.     ret
  1819. tekrid    endp
  1820.  
  1821. tekprpt    proc    near
  1822.     cmp    nparam,1        ; one or more numeric parameters?
  1823.     jb    tekrprx            ; b = no
  1824.     cmp    param,2            ; "CSI 2 $ u"?
  1825.     jne    tekrprx            ; ne = no
  1826.     cmp    inter,'$'        ; correct Intermediate?
  1827.     jne    tekrprx            ; ne = no
  1828.     call    dword ptr rptptr    ; invoke the palette report generator
  1829. tekrprx:ret
  1830. tekprpt    endp
  1831.  
  1832. tekrpt    proc    FAR            ; report VT340 color palette
  1833.     push    es            ; DECRQTSR(request), DECCTR(response)
  1834.     push    ds
  1835.     pop    es
  1836.     push    di
  1837.     push    bx
  1838.     cld
  1839.     mov    di,offset tempname    ; a temp buffer
  1840.     mov    al,escape        ; report
  1841.     stosb
  1842.     cmp    plotptr,offset pltcga    ; using CGA style graphics?
  1843.     je    tekrpt9            ; e = yes
  1844.     cmp    graph_mode,mono        ; pure mono text system?
  1845.     je    tekrpt9            ; e = yes
  1846.     cmp    graph_mode,monoega    ; monochrome monitor on ega?
  1847.     jne    tekrpt10        ; ne = no
  1848. tekrpt9:mov    ax,'0P'            ; b/w systems report DCS 0 $ s ST
  1849.     stosw
  1850.     mov    ax,'s$'
  1851.     stosw
  1852.     call    outstrng
  1853.     jmp    tekrpt8
  1854.  
  1855. tekrpt10:mov    ax,'2P'            ; color systems report DCS 2 $ s...ST
  1856.     stosw
  1857.     mov    ax,'s$'
  1858.     stosw                ; "ESC [ 2 $ s"
  1859.     call    outstrng        ; output this string
  1860.     mov    cx,16            ; number of palette registers to do
  1861.     xor    bx,bx            ; begin with color palette 0
  1862. tekrpt1:push    bx            ; save palette index
  1863.     push    cx            ; save loop counter
  1864.     mov    di,offset tempname    ; buffer
  1865.     mov    ax,bx            ; palette number
  1866.     call    dec2di            ; palette register, to buffer
  1867.     mov    ax,'2;'            ; ";2;" means sending RGB values
  1868.     stosw
  1869.     mov    al,';'
  1870.     stosb
  1871.     mov    ah,colpal[bx]        ; get palette iRGB
  1872.     mov    al,rgbbold/4        ; assume dark red for bold black
  1873.     cmp    ah,8            ; bold black?
  1874.     je    tekrpt2            ; e = yes
  1875.     xor    al,al
  1876.     test    ah,4            ; red?
  1877.     jz    tekrpt2            ; z = no
  1878.     mov    al,rgbbold/2        ; say red, 40%
  1879.     test    ah,8            ; bold?
  1880.     jz    tekrpt2            ; z = no
  1881.     mov    al,rgbbold        ; more if bold
  1882. tekrpt2:push    ax
  1883.     xor    ah,ah            ; clear high byte
  1884.     call    dec2di            ; store red
  1885.     pop    ax
  1886.     mov    al,';'            ; separator
  1887.     stosb
  1888.     mov    al,rgbbold/4        ; assume dark green for bold black
  1889.     cmp    ah,8            ; bold black?
  1890.     je    tekrpt4            ; e = yes
  1891.     xor    al,al
  1892.     test    ah,2            ; green?
  1893.     jz    tekrpt4            ; z = no
  1894.     mov    al,rgbbold/2        ; say green, 40%
  1895.     test    ah,8            ; bold?
  1896.     jz    tekrpt4            ; z = no
  1897.     mov    al,rgbbold        ; more if bold
  1898. tekrpt4:push    ax
  1899.     xor    ah,ah            ; clear high byte
  1900.     call    dec2di            ; store green
  1901.     pop    ax
  1902.     mov    al,';'            ; separator
  1903.     stosb
  1904.     mov    al,rgbbold/4        ; assume dark blue for bold black
  1905.     cmp    ah,8            ; bold black?
  1906.     je    tekrpt6            ; e = yes
  1907.     xor    al,al
  1908.     test    ah,1            ; blue?
  1909.     jz    tekrpt6            ; z = no
  1910.     mov    al,rgbbold/2        ; say blue, 40%
  1911.     test    ah,8            ; bold?
  1912.     jz    tekrpt6            ; z = no
  1913.     mov    al,rgbbold        ; more if bold
  1914. tekrpt6:xor    ah,ah            ; clear high byte
  1915.     call    dec2di            ; store blue
  1916.     pop    cx            ; recover loop counter
  1917.     cmp    cx,1            ; doing last item?
  1918.     je    tekrpt7            ; e = yes, do not send another "/"
  1919.     mov    al,'/'            ; separator
  1920.     stosb
  1921. tekrpt7:push    cx
  1922.     call    outstrng        ; output this string
  1923.     pop    cx
  1924.     pop    bx            ; recover palette index
  1925.     inc    bx            ; ready for next palette
  1926.     dec    cx
  1927.     jz    tekrpt8            ; z = done
  1928.     jmp    tekrpt1            ; do all palettes
  1929. tekrpt8:mov    al,escape        ; DCS terminator ST
  1930.     call    outmodem
  1931.     mov    al,'\'
  1932.     call    outmodem
  1933.     pop    bx
  1934.     pop    di
  1935.     pop    es
  1936.     ret
  1937. tekrpt    endp
  1938.  
  1939. ; Output string in tempname. Enter with di pointing at last byte+1. Return
  1940. ; with di at the same place.
  1941. outstrng proc    near
  1942.     mov    ttyact,0        ; group output for network
  1943.     push    cx
  1944.     mov    cx,di            ; compute length
  1945.     mov    di,offset tempname    ; start of buffer
  1946.     sub    cx,di            ; start of buffer
  1947.     jle    outstn3            ; le = nothing to do
  1948. outstn1:mov    al,[di]
  1949.     inc    di
  1950.     cmp    cx,1            ; last character?
  1951.     ja    outstn2            ; a = no
  1952.     mov    ttyact,1        ; end group output for network
  1953. outstn2:call    outmodem        ; send the byte
  1954.     loop    outstn1            ; do the string
  1955. outstn3:pop    cx
  1956.     ret
  1957. outstrng endp
  1958.  
  1959. ; Process Device Control Strings (DCS or ESC P lead-in chars, parameters,
  1960. ; and Final character already read). Prepare to gather strings.
  1961. tekdcs    proc    near
  1962.     mov    dcsstrf,al        ; record Final char
  1963.     mov    emubufc,0        ; clear string count
  1964.     mov    cx,maxparam        ; number of DCS parameters
  1965.     push    si            ; copy these to the DCS area so that
  1966.     push    di            ;  they are not lost when an ST is
  1967.     push    es            ;  parsed (parser clears ESC items)
  1968.     push    ds
  1969.     pop    es
  1970.     mov    si,offset param        ; ESC paramater storage area, numeric
  1971.     mov    di,offset dparam    ; DCS parameter storage area, numeric
  1972.     cld
  1973.     rep    movsw            ; copy set to DCS storage area
  1974.     mov    cl,lparam         ; copy letter Paramter
  1975.     mov    dlparam,cl
  1976.     mov    cx,maxinter        ; number of intermediate characters
  1977.     mov    si,offset inter        ; source
  1978.     mov    di,offset dinter    ; destination
  1979.     rep    movsb
  1980.     mov    si,nparam        ; number of parameters
  1981.     mov    dnparam,si
  1982.     mov    si,ninter
  1983.     mov    dninter,si        ; number of intermediates
  1984.     pop    es
  1985.     pop    di
  1986.     pop    si
  1987.     cmp    dcsstrf,'q'        ; Sixel Graphics?
  1988.     jne    tekdcs3            ; ne = no
  1989.     mov    ttstate,offset tekgets    ; get string as next state
  1990.     mov    al,chcontrol        ; opaque/transparent char writing
  1991.     or    al,al            ; is it being set?
  1992.     jz    tekdcs2            ; z = no, do not force condition
  1993.     mov    bscontrol,al        ; set destructive BS control
  1994.     mov    spcontrol,al        ; set destructive SPACE control
  1995. tekdcs2:ret
  1996. tekdcs3:cmp    dcsstrf,'p'        ; restore color palette (DCS 2 $ p)?
  1997.     jne    tekdcs1            ; ne = no
  1998.     cmp    nparam,1        ; just one parameter?
  1999.     jne    tekdcs1            ; ne = no
  2000.     cmp    param,2            ; correct parameter?
  2001.     jne    tekdcs1            ; ne = no
  2002.     cmp    dinter,'$'        ; correct intermediate?
  2003.     jne    tekdcs1            ; ne = no
  2004.     mov    ttstate,offset tekrcol    ; get color report as next state
  2005.     ret
  2006. tekdcs1:mov    ttstate,offset tekdcsnul ; consume unknown DCS
  2007.     ret
  2008. tekdcs    endp
  2009.  
  2010. ; Read and discard OSC (ESC ]), PM (ESC ^), APC (ESC _) control sequences
  2011. ; through final ST (ESC \) terminator.
  2012. tekdcsnul proc    near
  2013.     mov    dcsstrf,0        ; simulate a null (dummy) Final char
  2014.     cmp    al,20h            ; control char?
  2015.     jae    tekdcsnu1        ; ae = no, skip
  2016.     jmp    tekctl            ; do control char
  2017. tekdcsnu1:ret
  2018. tekdcsnul endp
  2019.  
  2020. ; State machine to process DCS strings of type "p" (restore color palette)
  2021. ; Enter with "p" char in AL. Callable from outside this file via tekrpal.
  2022. tekrcol    proc    near
  2023.     mov    ttstate,offset tekrco1    ; next state is get parameter
  2024.     push    ax            ; save character
  2025.     push    es
  2026.     push    ds
  2027.     pop    es
  2028.     push    di
  2029.     mov    cx,5            ; five words
  2030.     xor    ax,ax
  2031.     mov    di,offset param        ; clear parameters Pc,Pu,Px,Py,Pz
  2032.     cld
  2033.     rep    stosw
  2034.     pop    di
  2035.     pop    es
  2036.     mov    nparam,0        ; work on initial parameter first
  2037.     pop    ax
  2038. tekrco1:cmp    al,escape        ; escape, as in ESC \?
  2039.     je    tekrcost        ; e = yes, finish command
  2040.     cmp    al,' '            ; control code?
  2041.     jb    tekrco5            ; b = yes, ignore it
  2042.     push    bx
  2043.     mov    bx,nparam        ; parameter number
  2044.     shl    bx,1            ; make it a word index
  2045.     mov    cx,param[bx]        ; accumulated parameter
  2046.     call    getdec            ; accumulate decimal value
  2047.     mov    param[bx],cx        ; remember accumulation
  2048.     pop    bx
  2049.     jnc    tekrco5            ; nc = got a digit char
  2050.     inc    nparam            ; say have another complete parameter
  2051.     cmp    al,'/'            ; this kind of separator?
  2052.     je    tekrco3            ; e = yes, finish
  2053.     cmp    al,';'            ; break char is separator?
  2054.     jne    tekrco4            ; ne = no, decode current sequence
  2055. tekrco3:cmp    nparam,5        ; have 5 params already?
  2056.     jb    tekrco5            ; n = no, continue reading
  2057. tekrco4:call    tekgco4            ; process parameters in msgibm file
  2058.     mov    ttstate,offset tekrcol    ; next state is get parameter
  2059. tekrco5:ret                ; start over on next field
  2060.  
  2061. tekrcost:                ; get here on ST
  2062.     cmp    nparam,5        ; enough parameters to finish cmd?
  2063.     jb    tekrcos1        ; b = no, abandon it
  2064.     call    tekgco4            ; update from last data item
  2065.     mov    al,escape
  2066. tekrcos1:jmp    tekctl
  2067. tekrcol    endp
  2068.  
  2069. ; State machine to process DCS strings of type "q" (Sixel Command and Data)
  2070. ; Enter with new char in AL.
  2071. tekgets    proc    near
  2072.     mov    ttstate,offset tekgets    ; set state to ourselves
  2073.     mov    nparam,0        ; say no pending control sequences
  2074.     cmp    al,20h            ; control character?
  2075.     jae    tekgsch            ; ae = no, analyze
  2076.     jmp    tekctl            ; do control char
  2077.                     ; single sixel char state
  2078. tekgsch:cmp    al,3fh            ; legal sixel data char?
  2079.     jb    tekgrpt            ; b = no, try repeated char
  2080.     mov    cx,1            ; repeat count of 1
  2081.     jmp    sixplt            ; plot the six dots
  2082.  
  2083. tekgrpt:cmp    al,'!'            ; repeated char?
  2084.     jne    tekgera            ; ne = no
  2085.     mov    ttstate,offset tekgrpt0    ; next state is get repeat parameter
  2086.     mov    param,0
  2087.     mov    nparam,0
  2088.     ret
  2089.  
  2090. tekgrpt0:cmp    al,' '            ; control char?
  2091.     jae    tekgrpt1        ; ae = no
  2092.     jmp    tekctl            ; process control char
  2093. tekgrpt1:mov    cx,param        ; first param is used here
  2094.     call    getdec            ; accumulate repeat count to cx
  2095.     mov    param,cx        ; retain current count
  2096.     jc    tekgrpt2        ; c = ended on non-numeric
  2097.     ret                ; get more characters
  2098. tekgrpt2:cmp    al,3fh            ; break char, is it a sixel datum?
  2099.     jb    tekgrpt3        ; b = no, it is illegal, quit
  2100.     call    sixplt            ; plot cx versions of the six bits
  2101.     mov    ttstate,offset tekgets    ; return to sixel idle state
  2102.     ret
  2103. tekgrpt3:jmp    short tekgets        ; reprocess break character
  2104.  
  2105. tekgera:cmp    al,22h            ; double quote raster attribute?
  2106.     jne    tekgco            ; ne = no, try color
  2107.     mov    param,0            ; clear parameters, Pan
  2108.     mov    param[2],0        ; Pad
  2109.     mov    param[4],0        ; Ph
  2110.     mov    param[6],0        ; Pv
  2111.     mov    nparam,0        ; work on initial parameter first
  2112.     mov    ttstate,offset tekgra1    ; next state is get parameter
  2113.     ret
  2114. tekgra1:cmp    al,' '            ; control char?
  2115.     jb    tekgra2            ; b = yes, finish this work first
  2116.     push    bx
  2117.     mov    bx,nparam        ; parameter number
  2118.     shl    bx,1            ; make it a word index
  2119.     mov    cx,param[bx]        ; accumulated parameter
  2120.     call    getdec            ; accumulate decimal value into cx
  2121.     mov    param[bx],cx        ; remember accumulation
  2122.     pop    bx
  2123.     jc    tekgra2            ; c = failure to get a digit char
  2124.     ret
  2125. tekgra2:inc    nparam            ; say have another complete parameter
  2126.     cmp    nparam,4        ; got all four params Pan,Pad,Ph,Pv?
  2127.     je    tekgra4            ; e = yes
  2128.     cmp    al,';'            ; break char is separator?
  2129.     jne    tekgra3            ; ne = no, quit now
  2130.     ret                ; get more characters
  2131. tekgra3:jmp    tekgets            ; restart with the break char
  2132.  
  2133. tekgra4:;;; perform raster attributes work here
  2134.     mov    ttstate,offset tekgets
  2135.     ret
  2136.  
  2137. tekgco:    cmp    al,'#'            ; color introducer?
  2138.     je    tekgco0            ; e = yes
  2139.     jmp    tekgcr            ; ne = no
  2140. tekgco0:mov    ttstate,offset tekgco1    ; next state is get parameter
  2141.     push    ds
  2142.     pop    es
  2143.     push    di
  2144.     mov    cx,5            ; five words
  2145.     xor    ax,ax
  2146.     mov    di,offset param        ; clear parameters Pc,Pu,Px,Py,Pz
  2147.     cld
  2148.     rep    stosw
  2149.     pop    di
  2150.     pop    es
  2151.     mov    nparam,0        ; work on initial parameter first
  2152.     ret
  2153. tekgco1:cmp    al,' '            ; control char?
  2154.     jb    tekgco2            ; b = yes, finish this work first
  2155.     push    bx
  2156.     mov    bx,nparam        ; parameter number
  2157.     shl    bx,1            ; make it a word index
  2158.     mov    cx,param[bx]        ; accumulated parameter
  2159.     call    getdec            ; accumulate decimal value
  2160.     mov    param[bx],cx        ; remember accumulation
  2161.     pop    bx
  2162.     jc    tekgco2            ; c = failure to get a digit char
  2163.     ret
  2164. tekgco2:inc    nparam            ; say have another complete parameter
  2165.     cmp    al,';'            ; break char is separator?
  2166.     jne    tekgco3            ; ne = no, decode current sequence
  2167.     cmp    nparam,5        ; have 5 params already?
  2168.     jae    tekgco3            ; ae = yes, process them now
  2169.     ret                ;  else get more parameters
  2170. tekgco3:cmp    nparam,1        ; just one parameter?
  2171.     je    tekgco3a        ; e = yes, select from palette
  2172.     jb    tekgco3b        ; b = none, reprocess as sixel
  2173.     call    tekgco4            ; process parameters
  2174.     mov    nparam,0        ; clear parameters
  2175.     jmp    tekgets            ; reprocess char as sixel
  2176.  
  2177. tekgco3a:push    bx            ; select color from palette
  2178.     mov    bx,param[0]        ; get color number
  2179.     xor    bh,bh            ; make 0-255
  2180.     mov    bl,colpal[bx]        ; get color from palette
  2181.     mov    gfcol,bl        ; set active foreground color
  2182.     pop    bx
  2183.     push    ax            ; save char in al
  2184.     call    fixcolor        ; fix color too, if req'd
  2185.     pop    ax
  2186. tekgco3b:mov    nparam,0        ; clear parameters
  2187.     jmp    tekgets            ; reprocess char as sixel
  2188.  
  2189.                     ; set IRGB/HLS color to color palette
  2190. tekgco4:cmp    param[2],2        ; Pu (1-2), wanted RBG?
  2191.     je    tekgco4b        ; e = yes
  2192.     cmp    param[2],1        ; Pu, wanted HLS?
  2193.     jne    tekgco4a        ; ne = no
  2194.     jmp    tekgco9            ; do HLS scheme
  2195. tekgco4a:mov    nparam,0        ; clear parameters
  2196.     ret                ; return without doing work
  2197. tekgco4b:push    ax            ; iRGB, save break char in al
  2198.     mov    ax,param[4]        ; red
  2199.     mov    bx,param[6]        ; green
  2200.     mov    dx,param[8]        ; blue
  2201.     xor    cx,cx            ; cl has final color index, 0-15
  2202.     or    ch,al
  2203.     or    ch,bl
  2204.     or    ch,dl            ; any color?
  2205.     jcxz    tekgco7            ; z = no, use cl = 0 black
  2206.     cmp    ax,rgbbold        ; setting red bold?
  2207.     jae    tekgco4c        ; ae = yes
  2208.     cmp    bx,rgbbold        ; setting green bold?
  2209.     jae    tekgco4c        ; ae = yes
  2210.     cmp    dx,rgbbold        ; setting blue bold?
  2211.     jb    tekgco4d        ; b = no
  2212. tekgco4c:mov    cl,8            ; set the bold bit
  2213.     jmp    tekgco4e        ; do hues
  2214. tekgco4d:cmp    ax,rgbbold/2        ; all in dim intensities?
  2215.     jae    tekgco4e        ; ae = no
  2216.     cmp    bx,rgbbold/2        ; green?
  2217.     jae    tekgco4e        ; ae = no
  2218.     cmp    dx,rgbbold/2        ; blue
  2219.     jae    tekgco4e        ; ae = no
  2220.     mov    cl,8            ; use bold black (dark grey)
  2221.     jmp    tekgco7
  2222. tekgco4e:or    ax,ax            ; Hues, any red?
  2223.     jz    tekgco5            ; z = no
  2224.     or    cl,4            ; set red bit
  2225.     cmp    ax,rgbbold/2        ; dim?
  2226.     jae    tekgco5            ; ae = no
  2227.     test    cl,8            ; doing bold?
  2228.     jz    tekgco5            ; z = no
  2229.     xor    cl,4            ; clear dim red
  2230. tekgco5:or    bx,bx            ; any green?
  2231.     jz    tekgco6            ; z = no
  2232.     or    cl,2            ; set green bit
  2233.     cmp    bx,rgbbold/2        ; dim?
  2234.     jae    tekgco6            ; ae = no
  2235.     test    cl,8            ; doing bold?
  2236.     jz    tekgco6            ; z = no
  2237.     xor    cl,2            ; clear dim green
  2238. tekgco6:or    dx,dx            ; any blue?
  2239.     jz    tekgco7            ; z = no
  2240.     or    cl,1            ; set blue bit
  2241.     cmp    dx,rgbbold/2        ; dim?
  2242.     jae    tekgco7            ; ae = no
  2243.     test    cl,8            ; doing bold?
  2244.     jz    tekgco7            ; z = no
  2245.     xor    cl,1            ; clear dim blue
  2246. tekgco7:push    bx
  2247.     mov    bx,param[0]        ; Pc, color palette being defined
  2248.     xor    bh,bh            ; make 0-255
  2249.     mov    colpal[bx],cl        ; store color code in palette
  2250.     pop    bx
  2251.     mov    nparam,0        ; say done with this sequence
  2252.     pop    ax            ; recover break char in al
  2253.     ret
  2254.  
  2255.                     ; Hue, Lightness, Saturation
  2256. tekgco9:push    ax            ; save break char
  2257.     xor    cl,cl            ; assummed color of black
  2258.     mov    ax,param[4]        ; Px, Hue, 60 degree slices
  2259.     push    cx
  2260.     mov    cx,360            ; do modulo 360
  2261.     xor    dx,dx            ; clear high order numerator
  2262.     div    cx            ; dx has remainder
  2263.     pop    cx
  2264.     mov    ax,dx            ; put remainder in ax
  2265.     cmp    ax,30            ; blue?
  2266.     jae    tekgco10        ; ae = no
  2267.     or    cl,1            ; blue
  2268.     jmp    short tekgco15
  2269. tekgco10:cmp    ax,90            ; magenta?
  2270.     jae    tekgco11        ; ae = no
  2271.     or    cl,1+4            ; magenta = blue + red
  2272.     jmp    short tekgco15
  2273. tekgco11:cmp    ax,150            ; red?
  2274.     jae    tekgco12        ; ae = no
  2275.     or    cl,4            ; red
  2276.     jmp    short tekgco15
  2277. tekgco12:cmp    ax,210            ; yellow?
  2278.     jae    tekgco13        ; ae = no
  2279.     or    cl,4+2            ; yellow = reg + green
  2280.     jmp    short tekgco15
  2281. tekgco13:cmp    ax,270            ; cyan?
  2282.     jae    tekgco14        ; ae = no
  2283.     or    cl,2+1            ; cyan = green+blue
  2284.     jmp    short tekgco15
  2285. tekgco14:or    cl,1            ; blue
  2286.  
  2287. tekgco15:mov    ax,param[6]        ; Py, Lightness
  2288.     mov    dx,param[8]        ; Pz, Saturation
  2289.     cmp    ax,86            ; lightness is max?
  2290.     jb    tekgco16        ; b = no
  2291.     mov    cl,0fh            ; greater than 85% means bold white
  2292.     jmp    short tekgco22
  2293. tekgco16:cmp    ax,71            ; high lightness?
  2294.     jb    tekgco17        ; b = not that light
  2295.     or    cl,8            ; turn on bold bit
  2296.     cmp    dx,51            ; saturated?
  2297.     jae    tekgco22        ; ae = yes
  2298.     mov    cl,0fh            ; low saturation yields bold white
  2299.     jmp    short tekgco22
  2300. tekgco17:cmp    ax,57            ; central coloring, upper?
  2301.     jb    tekgco18        ; b = no
  2302.     or    cl,8            ; turn on bold bit
  2303.     cmp    dx,51            ; saturated?
  2304.     jae    tekgco22        ; ae = yes, use bold colors
  2305.     mov    cl,7            ; s < 50 is dim white
  2306.     cmp    dx,11            ; saturated less than 11%
  2307.     jae    tekgco22        ; ae = no
  2308.     xor    cl,cl            ; s < 11 is black here
  2309.     jmp    short tekgco22
  2310. tekgco18:cmp    ax,43            ; dim colors, upper?
  2311.     jb    tekgco19        ; b = no
  2312.     or    cl,8            ; turn on bold bit
  2313.     cmp    dx,51            ; saturated?
  2314.     jae    tekgco22        ; ae = yes, use bold colors
  2315.     and    cl,not 8        ; use dim colors
  2316.     jmp    short tekgco22
  2317. tekgco19:cmp    ax,29            ; dim colors, lower?
  2318.     jb    tekgco20        ; b = no
  2319.     cmp    dx,51            ; saturated?
  2320.     jae    tekgco22        ; ae = yes
  2321.     mov    cl,7            ; use dim white
  2322.     jmp    short tekgco22
  2323. tekgco20:cmp    ax,14            ; dark colors?
  2324.     jb    tekgco21        ; b = no
  2325.     cmp    dx,51            ; saturated?
  2326.     jae    tekgco22        ; ae = yes
  2327. tekgco21:xor    cl,cl            ; use black
  2328. tekgco22:push    bx
  2329.     mov    bx,param[0]        ; Pc, color palette being defined
  2330.     xor    bh,bh            ; get palette 0-255
  2331.     mov    colpal[bx],cl        ; store color code in palette
  2332.     pop    bx
  2333.     mov    nparam,0        ; say done with this sequence
  2334.     pop    ax            ; recover break char
  2335.     ret
  2336.  
  2337. tekgcr:    cmp    al,'$'            ; graphics carriage return?
  2338.     jne    tekgnl            ; ne = no
  2339.     mov    x_coord,0        ; go to left margin, no line feed
  2340.     ret
  2341. tekgnl:    cmp    al,'-'            ; graphics new line?
  2342.     jne    tekgunk            ; ne = no
  2343.     mov    x_coord,0        ; go to left margin, no line feed
  2344.     mov    ax,y_coord        ; bottom of char cell
  2345.     add    ax,6            ; go down 6 dots
  2346.     cmp    ax,ybot            ; wrapping below bottom?
  2347.     jbe    tekgnl1            ; be = no
  2348.     mov    ax,ybot            ; stop at bottom (leaves 2 dots free!)
  2349. tekgnl1:mov    y_coord,ax
  2350.     ret
  2351. tekgunk:mov    ttstate,offset tekgets    ; unknown char
  2352.     cmp    al,' '            ; control char?
  2353.     jae    tekgun1            ; ae = no
  2354.     jmp    tektxt            ; process control char
  2355. tekgun1:ret                ; ignore the unknown char
  2356. tekgets    endp
  2357.  
  2358. ; Accumulate decimal value in CX using ascii char in al.
  2359. ; Return with value in CX. Return carry clear if ended on a digit,
  2360. ; return carry set and ascii char in al if ended on a non-digit.
  2361. getdec    proc    near
  2362.     cmp    al,'0'            ; a number?
  2363.     jb    getdecx            ; b = no, quit
  2364.     cmp    al,'9'
  2365.     ja    getdecx            ; a = not a number, quit
  2366.     sub    al,'0'            ; remove ascii bias
  2367.     xchg    cx,ax            ; put char in cx, decimal value in ax
  2368.     push    dx            ; save reg
  2369.     mul    ten            ; times ten for a new digit
  2370.     pop    dx            ; recover reg, ignore overflow
  2371.     add    al,cl            ; add current digit
  2372.     adc    ah,0            ; 16 bits worth
  2373.     xchg    ax,cx            ; rpt cnt back to cx
  2374.     clc                ; say found a digit
  2375.     ret
  2376. getdecx:stc                ; say non-digit (in al)
  2377.     ret
  2378. getdec    endp
  2379.  
  2380. ; Display lower six bits of AL in a column, a sixel datum. Do CX times.
  2381. ; Location is PC text cursor, x_coord, y_coord, with least significant bit
  2382. ; at the top (at y_coord-8). Increments x_coord by one for each interation
  2383. ; but stops at right margin and does not change y_coord. If dparam[2], P2,
  2384. ; is 1 then color pattern 0 bits in current background, else skip them.
  2385. sixplt    proc    near
  2386.     or    cx,cx            ; repeat count present?
  2387.     jnz    sixplt1            ; nz = yes
  2388.     ret
  2389. sixplt1:push    ax
  2390.     push    bx
  2391.     push    linepat            ; save line pattern
  2392.     sub    al,3fh            ; remove ascii bias from sixel char
  2393.     xor    ah,ah
  2394.     mov    linepat,ax        ; our dot pattern in lower 6 bits
  2395.     mov    di,y_coord        ; text bottom cell line
  2396.     sub    di,8            ; go to top of 8 high char cell
  2397.     jnc    sixplt2            ; nc = no wrap over top
  2398.     xor    di,di            ; limit to screen top
  2399. sixplt2:mov    bx,di            ; bx = ending y
  2400.     add    bx,5            ; plus our six dots (goes down screen)
  2401.     cmp    bx,ybot            ; wrapping below bottom?
  2402.     jbe    sixplt3            ; be = no
  2403.     mov    bx,ybot            ; stop at bottom
  2404. sixplt3:mov    ax,x_coord        ; left edge of text cell
  2405.     mov    si,ax            ; si=starting, ax=ending PC x coord
  2406.     add    xmax,7            ; refer to right edge, not right char
  2407.     push    es            ; set up for dot plotting, save regs
  2408.     push    si
  2409.     push    di
  2410.     push    dx
  2411.     push    bp
  2412.     mov    dl,ccode        ; existing pixel op code
  2413.     push    dx            ; save ccode around line drawing
  2414.     mov    ccode,pixor        ; set OR pixel op for use by plot()
  2415.     cmp    gfcol,0            ; all black dots?
  2416.     jne    sixplt3a        ; ne = no
  2417.     mov    ccode,pixfor        ; yes, force overwriting to nulls
  2418. sixplt3a:push    cx
  2419.     call    psetup            ; setup display and es:di and es:si
  2420.     pop    cx
  2421.                     ; start sixel repeat loop
  2422. sixplt4:push    cx            ; save sixel repeat count
  2423.     push    di            ; save y starting screen address
  2424.     mov    bp,linepat        ; store active line pattern word in BP
  2425.     mov    cx,6            ; six dots per sixel
  2426.                     ; start six dot loop
  2427. sixplt5:push    cx            ; save dot count
  2428.     mov    cl,pixFor        ; assume foreground coloring
  2429.     test    bp,1            ; bit to be plotted, is it a 1?
  2430.     jnz    sixplt6            ; nz = yes, plot in foreground color
  2431.     cmp    dparam[2],1        ; P2 = 1, skip over 0's?
  2432.     je    sixplt6            ; e = yes
  2433.     mov    cl,pixbak        ; use background write pixel op
  2434.     or    bp,1            ; set pattern bit so we see a pixel
  2435. sixplt6:mov    ccode,cl        ; desired pixel op
  2436.     call    plotptr            ; plot a dot if it is a 1
  2437.     call    pincy            ; next dot down the screen (di)
  2438.     pop    cx            ; recover dot counter
  2439.     loop    sixplt5            ; do each of 6 dots
  2440.                     ;
  2441.     pop    di            ; recover starting y screen coord
  2442.     pop    cx            ; recover repeat count
  2443.     cmp    ax,xmax            ; off right edge?
  2444.     jae    sixplt8            ; ae = yes
  2445.     inc    ax            ; move right one pixel
  2446.     inc    si            ; start and stop x's
  2447. sixplt8:loop    sixplt4            ; repeat sixel cx times
  2448.     pop    dx
  2449.     mov    ccode,dl        ; recover main color code
  2450.     pop    bp
  2451.     pop    dx
  2452.     pop    di
  2453.     pop    si
  2454.     pop    es
  2455.     mov    x_coord,ax        ; new text starting x coord
  2456.     sub    xmax,7            ; restore to right most char cell
  2457.     pop    linepat            ; restore normal line pattern
  2458.     pop    bx
  2459.     pop    ax
  2460.     ret
  2461. sixplt    endp
  2462.  
  2463. ; Process ST or ESC \  String Terminator.
  2464. tekgotst proc    near
  2465.     mov    dcsstrf,0        ; clear DCS Final char
  2466.     mov    nparam,0
  2467.     mov    ninter,0
  2468.     mov    al,colpal[7]        ; reset foreground to palette 7
  2469.     mov    gfcol,al
  2470.     mov    al,colpal[0]        ; and background to palette 0
  2471.     mov    gbcol,al
  2472.     call    fixcolor        ; and fix up coloring, if req'd
  2473.     mov    prestate,offset tektxt    ; reset state of emulator to normal
  2474.     mov    ttstate,offset tektxt
  2475.     call    setcursor        ; restore text cursor
  2476.     ret
  2477. tekgotst endp
  2478.  
  2479. TEKLINE    proc    near            ; GS line drawing
  2480.     cmp    al,' '            ; control char?
  2481.     jae    teklin3            ; ae = no
  2482.     cmp    al,CR            ; exit drawing on CR,LF,RS,US,FS,CAN
  2483.     je    teklin2            ; e = yes, a cr
  2484.     cmp    al,LF            ; these terminate line drawing cmds
  2485.     je    teklin2
  2486.     cmp    al,FS            ; <FS>
  2487.     je    teklin2
  2488.     cmp    al,GS            ; <GS>
  2489.     je    teklin2
  2490.     cmp    al,RS            ; <RS>
  2491.     je    teklin2
  2492.     cmp    al,US            ; <US>
  2493.     je    teklin2
  2494.     cmp    al,CAN            ; and <CAN>
  2495.     je    teklin2            ; BUT ignore other control chars
  2496.     cmp    al,escape        ; escape?
  2497.     je    teklin1            ; e = yes, come back to this state
  2498.     ret                ; ignore stray control char
  2499. teklin1:jmp    tekctl            ; process control char
  2500. teklin2:mov    lastc,0            ; clear last drawing coordinate flag
  2501.     mov    visible,0        ; invisible again
  2502.     jmp    tektxt            ; process char under text mode
  2503.  
  2504. teklin3:call    tekxyc            ; parse coordinates from input bytes
  2505.     jc    teklin4            ; c = done, do the plotting
  2506.     ret                ; nc = not done yet
  2507. teklin4:mov    cl,visible        ; get moveto or drawto variable
  2508.     call    tekdraw            ; move that point
  2509.     mov    visible,1        ; say next time we draw
  2510.     ret
  2511. TEKLINE    endp
  2512.     
  2513. TEKPNT    proc    near            ; FS plot single point
  2514.     cmp    al,' '            ; control char?
  2515.     jae    tekpnt3            ; ae = no
  2516.     cmp    al,CR            ; exit drawing on CR,LF,RS,US,FS,CAN
  2517.     je    tekpnt2            ; e = yes, a cr
  2518.     cmp    al,LF             ; these terminate line drawing cmds
  2519.     je    tekpnt2
  2520.     cmp    al,FS            ; <FS>
  2521.     je    tekpnt2
  2522.     cmp    al,GS            ; <GS>
  2523.     je    tekpnt2
  2524.     cmp    al,RS            ; <RS>
  2525.     je    tekpnt2
  2526.     cmp    al,US            ; <US>
  2527.     je    tekpnt2
  2528.     cmp    al,CAN            ; and <CAN>
  2529.     je    tekpnt2            ; BUT ignore other control chars
  2530.     cmp    al,escape        ; escape?
  2531.     je    tekpnt1            ; e = yes
  2532.     clc
  2533.     ret                ; ignore stray control char
  2534. tekpnt1:jmp    tekctl            ; process control char
  2535. tekpnt2:mov    lastc,0            ; clear last drawing coordinate flag
  2536.     mov    visible,0        ; invisible again
  2537.     jmp    tektxt            ; process char under text mode
  2538.  
  2539. tekpnt3:call    tekxyc            ; parse coordinates
  2540.     jc    tekpnt4            ; c = done, do the plotting
  2541.     ret                ; nc = not done yet
  2542. tekpnt4:xor    cl,cl            ; do not draw
  2543.     call    tekdraw            ; move to the point
  2544.     mov    ax,si            ; copy starting point to end point
  2545.     mov    bx,di            ; ax,bx,si,di are in PC coordinates
  2546.     mov    cl,1            ; make plot visible
  2547.     call    line            ; draw the dot
  2548.     mov    visible,0        ; return to invisibility
  2549.     clc
  2550.     ret
  2551. TEKPNT    endp
  2552.  
  2553. ; Decode graphics x,y components. Returns carry set to say have all
  2554. ; components for a line, else carry clear. Understands 4014 lsb extensions.
  2555. ; Permits embedded escape sequences.
  2556. TEKXYC    proc    near
  2557.     cmp    al,40h
  2558.     jb    tekgh2            ; 20-3F are HIX or HIY
  2559.     cmp    al,60h            ; 40-5F are LOX (causes beam movement)
  2560.     jb    tekgh4            ; 60-7F are LOY
  2561.                     ; extract low-order 5 bits of Y coord
  2562.     mov    ah,tek_loy        ; copy previous LOY to MSB (4014)
  2563.     mov    tek_lsb,ah
  2564.     and    al,1Fh            ; LOY is 5 bits
  2565.     mov    tek_loy,al
  2566.     cmp    lastc,loy        ; 2nd LOY in a row?
  2567.     je    tekgh1            ; e = yes, then LSB is valid
  2568.     mov    tek_lsb,0        ; 1st one, clear LSB
  2569. tekgh1:    mov    lastc,loy        ; LOY seen, expect HIX (instead of HIY)
  2570. tekgh0:    clc                ; c clear = not completed yet
  2571.     ret
  2572. tekghx:    mov    ttstate,offset tektxt    ; go to TEKTXT next time
  2573.     mov    lastc,0            ; clear last drawing coordinate flag
  2574.     or    status,txtmode        ; set text mode in status byte
  2575.     clc                ; carry clear means done
  2576.     ret
  2577.  
  2578.         ; Extract high-order 5 bits (X or Y, depending on lastc)
  2579. tekgh2: and    ax,1Fh            ; just 5 bits
  2580.     mov    cl,5
  2581.     shl    ax,cl            ; shift over 5 bits
  2582.     cmp    lastc,loy        ; was last coordinate a low-y?
  2583.     je    tekgh3            ; e = yes, parse hix
  2584.     mov    tek_hiy,ax        ; this byte has HIY
  2585.     mov    lastc,hiy
  2586.     clc
  2587.     ret
  2588. tekgh3: mov    tek_hix,ax        ; this byte has HIX
  2589.     mov    lastc,hix
  2590.     clc
  2591.     ret
  2592. tekgh4: and    al,1Fh            ; just 5 bits
  2593.     mov    tek_lox,al
  2594.     mov    lastc,lox
  2595.     mov    ax,tek_hix        ; combine HIX*32
  2596.     or    al,tek_lox        ;  with LOX
  2597.     mov    bx,tek_hiy        ; same for Y
  2598.     or    bl,tek_loy
  2599.     stc                ; set c to say completed operation
  2600.     ret
  2601. TEKXYC    endp
  2602.  
  2603. TEKRLIN    proc    near            ; RS relative line drawing
  2604.     cmp    al,' '            ; control char?
  2605.     jae    tekrli1            ; ae = no
  2606.     jmp    tektxt            ; process control char
  2607. tekrli1:cmp    al,' '            ; pen up command?
  2608.     jne    tekrli2            ; ne = no, try pen down
  2609.     mov    visible,0        ; do invisible movements
  2610.     jmp    short tekrli3        ; do the command
  2611. tekrli2:cmp    al,'P'            ; pen down command?
  2612.     jne    tekrli4            ; ne = no, return to text mode
  2613.     mov    visible,1        ; set visible moves
  2614.  
  2615. tekrli3:mov    ax,x_coord        ; PC x coordinate of pen
  2616.     mov    bx,y_coord        ;    y coordinate
  2617.     call    pctotek            ; get current pen position in Tek coor
  2618.     xor    cl,cl            ; invisible, moveto
  2619.     call    tekdraw            ; move that point, set oldx and oldy
  2620.     mov    ttstate,offset tekinc    ; next get incremental movement cmds
  2621.     ret
  2622.  
  2623. tekrli4:mov    visible,0        ; bad char, reset visibility
  2624.     mov    ttstate,offset tektxt    ; assume text
  2625. tekrli5:jmp    ttstate            ; deal with bad char
  2626. TEKRLIN    endp
  2627.                     ; interpret RS inc plot command byte
  2628. TEKINC    proc    near            ; get movement character and do cmd
  2629.     cmp    al,' '            ; control char?
  2630.     jae    tekinc1            ; ae = no
  2631.     jmp    tektxt            ; process control char
  2632. tekinc1:mov    bx,oldx
  2633.     mov    cx,oldy
  2634.     test    al,1            ; 'A', 'E', 'I'?  Do by bit fields
  2635.     jz    tekinc2            ; z = no
  2636.     inc    bx            ; adjust beam position
  2637. tekinc2:test    al,2            ; 'B', 'F', 'J'?
  2638.     jz    tekinc4
  2639.     dec    bx
  2640. tekinc4:test    al,4            ; 'D', 'E', 'F'?
  2641.     jz    tekinc8            ; z = no
  2642.     inc    cx
  2643. tekinc8:test    al,8            ; 'H', 'I', 'J'?
  2644.     jz    tekinc9
  2645.     dec    cx
  2646. tekinc9:cmp    bx,0            ; too far left?
  2647.     jge    tekinc10        ; ge = no
  2648.     xor    bx,bx            ; else stop at the left margin
  2649. tekinc10:cmp    bx,maxtekx-1        ; too far left?
  2650.     jle    tekinc11        ; le = no
  2651.     mov    bx,maxtekx-1        ; else stop that the left margin
  2652. tekinc11:cmp    cx,maxteky-1        ; above the top?
  2653.     jle    tekinc12        ; le = not above the top
  2654.     mov    cx,maxteky-1        ; else stop at the top
  2655. tekinc12:cmp    cx,0            ; below bottom?
  2656.     jge    tekinc13        ; ge = not below bottom
  2657.     xor    cx,cx            ; else stop at the bottom
  2658. tekinc13:mov    ax,bx            ; ax is vector x end point
  2659.     mov    oldx,bx
  2660.     mov    bx,cx            ; bx is vector y end point
  2661.     mov    oldy,cx
  2662.     mov    cl,visible
  2663.     jmp    tekdraw            ; move/draw to that point
  2664. tekincb:mov    visible,0
  2665.     jmp    tektxt            ; reparse the bad char
  2666. TEKINC    endp
  2667.     
  2668.  
  2669. crossini proc    near            ; set crosshairs for initial screen
  2670.     mov    ax,xmax            ; right margin minus 7 dots
  2671.     add    ax,7            ; right most dot
  2672.     shr    ax,1            ; central position
  2673.     mov    bx,ybot            ; last scan line
  2674.     shr    bx,1
  2675.     cmp    ax,xcenter        ; same as previous call?
  2676.     jne    crossin2        ; ne = no, recenter
  2677.     cmp    bx,ycenter        ; same as previous call?
  2678.     je    crossin3        ; e = yes, don't recenter crosshairs
  2679. crossin2:mov    xcross,ax        ; save PC coord for crosshair
  2680.     mov    xcenter,ax        ; remember center coord
  2681.     mov    ycross,bx        ; this is the center of the screen
  2682.     mov    ycenter,bx        ; remember center coord
  2683. crossin3:                ; Mouse setup
  2684.     mov    mousebuf,0        ; assume no active mouse driver
  2685.     mov    al,mouse        ; mouse interrupt 33h
  2686.     mov    ah,35h            ; get vector for mouse driver
  2687.     int    dos
  2688.     mov    ax,es
  2689.     cmp    ax,0f000h        ; in ROM Bios?
  2690.     jae    crosin1            ; ae = yes
  2691.     or    ax,bx            ; check for no vector at all
  2692.     jz    crosin1            ; z = none
  2693.     cmp    byte ptr es:[bx],0cfh    ; is this an IRET instruction?
  2694.     je    crosin1            ; e = yes, not our driver
  2695.     mov    ax,msgetbf        ; get state buffer size (bytes) to BX
  2696.     int    mouse
  2697.     add    bx,15            ; round up to next paragraph
  2698.     shr    bx,1
  2699.     shr    bx,1
  2700.     shr    bx,1
  2701.     shr    bx,1            ; bytes to paragraphs
  2702.     mov    ah,alloc        ; allocate memory
  2703.     int    dos
  2704.     jc    crosin1            ; c = failed
  2705.     mov    mousebuf,ax        ; save seg of the mouse status buffer
  2706.     mov    es,ax
  2707.     xor    dx,dx            ; buffer address to es:dx
  2708.     mov    ax,msgetst        ; get mouse state info
  2709.     int    mouse
  2710.     jnc    crosin2            ; nc = presumed success
  2711.     call    mousefree        ; return mouse save buffer
  2712. crosin1:ret
  2713. crosin2:xor    cx,cx            ; minimum horizontal/vertical motion
  2714.     mov    dx,xmax            ; right most char
  2715.     add    dx,7            ; right most dot (counted from 0)
  2716.     mov    ax,mshoriz        ; set min/max horizontal motion
  2717.     int    mouse
  2718.     mov    dx,ybot            ; max y (counted from 0)
  2719.     mov    ax,msvert        ; set min/max vertical motion
  2720.     int    mouse
  2721.     ret
  2722. crossini endp
  2723.  
  2724. ; Routine to trigger the crosshairs, wait for a key to be struck, and send
  2725. ; the typed char (if printable ascii) plus four Tek encoded x,y position
  2726. ; coordinates and then a carriage return.
  2727. ; ax, cx, xcross, ycross operate in PC coordinates.
  2728.      
  2729. CROSHAIR PROC NEAR
  2730.     push    linepat            ; save line drawing pattern
  2731.     mov    linepat,0ffffh        ; reset line type to solid
  2732.     mov    ax,xmax            ; right margin minus 7 dots
  2733.     add    ax,7
  2734.     mov    temp,ax            ; right margin dot
  2735.     call    crosdrawh        ; draw initial crosshairs
  2736.     call    crosdrawv
  2737.     call    setmouse        ; set mouse there too
  2738. crosha1:call    tiseof            ; is stdin at EOF?
  2739.     jc    crosha2            ; c = yes, exit this mode now
  2740.     mov    dl,0ffh
  2741.     mov    ah,dconio        ; read console
  2742.     int    dos
  2743.     jnz    crosha4            ; nz = have char in AL
  2744.     cmp    mousebuf,0        ; is mouse driver active?
  2745.     je    crosha1            ; e = no
  2746.     mov    ax,msread        ; mouse, read status and position
  2747.     int    mouse
  2748.     push    bx            ; save button press information
  2749.     cmp    cx,xcross        ; moved in x direction?
  2750.     je    crosm1            ; e = no
  2751.     push    dx            ; save mouse y
  2752.     call    crosdrawv        ; erase vertical line
  2753.     mov    xcross,cx        ; new position
  2754.     call    crosdrawv        ; draw new vertical line
  2755.     pop    dx
  2756. crosm1:    cmp    dx,ycross        ; moved in y direction?
  2757.     je    crosm2            ; e = no
  2758.     call    crosdrawh        ; erase horizontal line
  2759.     mov    ycross,dx
  2760.     call    crosdrawh        ; draw new horizontal line
  2761. crosm2:    pop    bx
  2762.     test    bx,7            ; mouse, was a button pressed?
  2763.     jz    crosha1            ; z = no
  2764.     mov    al,CR            ; simulate a CR
  2765.  
  2766. crosha4:or    al,al            ; ascii or scan code returned
  2767.     jnz    arrow5            ; nz = ascii char returned
  2768.     call    tiseof            ; is stdin at EOF?
  2769.     jc    crosha2            ; c = yes, exit this mode now
  2770.     mov    ah,coninq        ; read scan code
  2771.     int    dos
  2772.     or    al,al            ; Control-Break?
  2773.     jnz    crosha3            ; nz = no, something else
  2774. crosha2:call    crosdrawh        ; erase crosshairs
  2775.     call    crosdrawv
  2776.     pop    linepat            ; restore line pattern
  2777.     ret                ; exit crosshairs mode
  2778.  
  2779. crosha3:cmp    al,homscn        ; is it 'home'?
  2780.     jne    arrow1            ; ne = no, try other keys
  2781.     call    crosdrawh        ; erase crosshairs
  2782.     call    crosdrawv
  2783.     mov    ax,temp            ; right margin
  2784.     shr    ax,1            ; central position
  2785.     mov    xcross,ax        ; save PC coord for crosshair
  2786.     mov    ax,ybot            ; last scan line
  2787.     shr    ax,1
  2788.     mov    ycross,ax        ; this is the center of the screen
  2789.     call    crosdrawh        ; draw home'd crosshairs
  2790.     call    crosdrawv
  2791.     call    setmouse        ; set mouse there too
  2792.     jmp    crosha1
  2793.  
  2794. arrow1:    cmp    al,lftarr        ; left arrow?
  2795.     jne    arrow2            ; ne = no
  2796.     mov    cx,-1            ; left shift
  2797.     jmp    short xkeys
  2798. arrow2:    cmp    al,rgtarr        ; right arrow?
  2799.     jne    arrow3            ; ne = no
  2800.     mov    cx,1            ; right shift
  2801.     jmp    short xkeys
  2802. arrow3:    cmp    al,uparr        ; up arrow?
  2803.     jne    arrow4            ; ne = no
  2804.     mov    cx,-1            ; up shift
  2805.     jmp    short vertkey
  2806. arrow4:    cmp    al,dnarr        ; down arrow?
  2807.     jne    badkey            ; ne = no, ignore it
  2808.     mov    cx,1                  ; down shift
  2809.     jmp    short vertkey
  2810.  
  2811. badkey:    call    tekbeep            ; tell user we don't understand
  2812.     jmp    crosha1            ; keep going
  2813.  
  2814.                     ; Shifted keys yield ascii keycodes
  2815. arrow5:    cmp    al,'C' and 1fh        ; Control-C?
  2816.     je    crosha2            ; e = yes, exit crosshairs mode now
  2817.     cmp    al,shlftarr        ; shifted left arrow?
  2818.     jne    arrow6            ; ne = no
  2819.     mov    cx,-10            ; big left shift
  2820.     jmp    short xkeys
  2821. arrow6:    cmp    al,shrgtarr        ; shifted right arrow?
  2822.     jne    arrow7            ; ne = no
  2823.     mov    cx,10            ; big right shift
  2824.     jmp    short xkeys
  2825. arrow7:    cmp    al,shuparr        ; shifted up arrow?
  2826.     jne    arrow8            ; ne = no
  2827.     mov    cx,-10            ; big up shift
  2828.     jmp    short vertkey
  2829. arrow8:    cmp    al,shdnarr        ; shifted down arrow?
  2830.     jne    charkey            ; ne = no, send this key as is
  2831.     mov    cx,10            ; big down shift
  2832.     jmp    short vertkey
  2833.  
  2834. xkeys:    call    crosdrawv        ; erase vertical line
  2835.     add    cx,xcross        ; add increment
  2836.     jns    noxc            ; gone too far negative?
  2837.     xor    cx,cx            ; s = yes, make it 0
  2838. noxc:    cmp    cx,temp            ; too far right?
  2839.     jb    xdraw9            ; b = no
  2840.     mov    cx,temp            ; yes, make it the right
  2841. xdraw9: mov    xcross,cx        ; new x value for cross hairs
  2842.     call    crosdrawv        ; draw new vertical line
  2843.     call    setmouse        ; set mouse there too
  2844.     jmp    crosha1
  2845.      
  2846. vertkey:call    crosdrawh        ; erase horizontal line
  2847.     add    cx,ycross        ; adjust cx
  2848.     jns    noyc            ; gone negative?
  2849.     xor    cx,cx            ; s = yes then make 0
  2850. noyc:    cmp    cx,ybot            ; too high?
  2851.     jb    yok            ; b = no
  2852.     mov    cx,ybot            ; make it maximum
  2853. yok:    mov    ycross,cx        ; save new y crosshair
  2854.     call    crosdrawh        ; draw new vertical line
  2855.     call    setmouse        ; set mouse there too
  2856.     jmp    crosha1
  2857.      
  2858. charkey:push    ax            ; preserve char in al
  2859.     call    crosdrawh        ; erase crosshairs
  2860.     call    crosdrawv
  2861.     pop    ax
  2862.     call    outmodem        ; send the break character
  2863.     mov    ax,xcross        ; set beam to xcross,ycross
  2864.     mov    bx,ycross        ; must convert to Tek coordinates
  2865.     call    pctotek            ; scale from PC screen coord to Tek
  2866.     push    ax            ; save around drawing
  2867.     push    bx
  2868.     xor    cx,cx            ; just a move
  2869.     call    tekdraw            ; moveto ax,bx in Tek coord
  2870.     pop    bx            ; recover Tek y
  2871.     pop    ax            ; recover Tek x
  2872.     call    sendpos            ; send position report to host
  2873.     pop    linepat            ; recover current line drawing pattern
  2874.     mov    ttstate,offset tektxt    ; go to TEKTXT next time
  2875.     mov    lastc,0            ; clear last drawing coordinate flag
  2876.     or    status,txtmode        ; set text mode in status byte
  2877.     ret
  2878. CROSHAIR ENDP
  2879.      
  2880. ; draw vertical crosshair line at x = xcross, xor with picture
  2881. crosdrawv proc near
  2882.     mov    al,ccode        ; save current pixel op
  2883.     push    ax
  2884.     push    cx
  2885.     mov    si,xcross        ; move to x= xcross
  2886.     mov    ax,si            ; ending x coord
  2887.     xor    di,di            ; starting y coord
  2888.     mov    bx,ybot            ; bottom y coord
  2889.     mov    cl,pixxor        ; xor pixels
  2890.     call    line            ; draw vertical
  2891.     pop    cx
  2892.     pop    ax            ; recover current pixel op
  2893.     mov    ccode,al        ; restore it
  2894.     ret
  2895. crosdrawv endp
  2896.  
  2897. ; draw horizontal crosshair line at y = ycross, xor with picture
  2898. crosdrawh proc near
  2899.     mov    al,ccode        ; save current pixel op
  2900.     push    ax
  2901.     push    cx
  2902.     mov    di,ycross        ; set y = ycross
  2903.     mov    bx,di            ; ending y
  2904.     xor    si,si            ; starting x
  2905.     mov    ax,temp            ; max x value
  2906.     mov    cl,pixxor        ; set XOR code
  2907.     call    line            ; draw to (xcross+12, ycross)
  2908.     pop    cx
  2909.     pop    ax            ; recover current pixel op
  2910.     mov    ccode,al        ; restore it
  2911.     ret
  2912. crosdrawh endp
  2913.  
  2914. ; Set mouse cursor position to xcross,ycross. Ignored if no active mouse.
  2915. setmouse proc    near
  2916.     cmp    mousebuf,0        ; is mouse driver is active?
  2917.     je    setmou1            ; e = no
  2918.     mov    cx,xcross
  2919.     mov    dx,ycross
  2920.     mov    ax,mswrite        ; set mouse position
  2921.     int    mouse
  2922. setmou1:ret
  2923. setmouse endp
  2924.  
  2925. ; Return DOS memory allocated as mouse status buffer
  2926. mousefree proc    near
  2927.     push    es
  2928.     mov    ax,mousebuf        ; seg of mouse save buffer
  2929.     mov    es,ax            ; allocated segment
  2930.     mov    ah,freemem        ; free it
  2931.     int    dos
  2932.     mov    mousebuf,0        ; clear mouse presence too
  2933.     pop    es
  2934.     ret
  2935. mousefree endp
  2936.  
  2937. ; Return mouse state and free state save buffer
  2938. mousexit proc    near
  2939.     mov    ax,mousebuf        ; segment of state save buffer
  2940.     or    ax,ax            ; is mouse driver active?
  2941.     jz    mousex1            ; z = no
  2942.     push    es
  2943.     mov    es,ax
  2944.     xor    dx,dx            ; address is in es:dx
  2945.     mov    ax,mssetst        ; set mouse driver state from buffer
  2946.     int    mouse
  2947.     pop    es
  2948.     call    mousefree        ; return memory to DOS
  2949. mousex1:ret
  2950. mousexit endp
  2951.  
  2952. ; SENDPOS sends position of cross-hairs to the host.
  2953. ; ax has Tek X and bx has Tek Y coord of center of crosshair     
  2954. SENDPOS PROC NEAR
  2955.     push    bx            ; preserve register
  2956.     call    sendxy            ; send x coord
  2957.     pop    ax
  2958.     call    sendxy            ; send y coord
  2959.     mov    al,cr            ; follow up with cr
  2960.     call    outmodem
  2961.     ret
  2962. SENDPOS ENDP
  2963.  
  2964. ; Write binary number in AX as decimal asciiz to buffer pointer DI.
  2965. dec2di    proc    near        ; output number in ax using base in cx
  2966.                 ; corrupts ax, cx, and dx
  2967.     mov    cx,10
  2968. dec2di1:xor    dx,dx        ; clear high word of numerator
  2969.     div    cx        ; (ax / cx), remainder = dx, quotient = ax
  2970.     push    dx        ; save remainder for outputting later
  2971.     or    ax,ax        ; any quotient left?
  2972.     jz    dec2di2        ; z = no
  2973.     call    dec2di1        ; yes, recurse
  2974. dec2di2:pop    dx        ; get remainder
  2975.     add    dl,'0'        ; make digit printable
  2976.     mov    [di],dl        ; store char in buffer
  2977.     inc    di
  2978.     mov    byte ptr[di],0    ; add terminator
  2979.     ret
  2980. dec2di    endp
  2981.      
  2982. ; SENDXY sends value of ax as Tek encoded bytes
  2983. ; ax is in Tek coordinates     
  2984. SENDXY    PROC    NEAR
  2985.     shl    ax,1
  2986.     shl    ax,1            ; move all but lower 5 bits to ah
  2987.     shl    ax,1
  2988.     shr    al,1
  2989.     shr    al,1            ; move low five bits to low 5 bits
  2990.     shr    al,1
  2991.     or    ah,20h            ; make it a printing char as per TEK
  2992.     xchg    al,ah            ; send high 5 bits first
  2993.     call    outmodem
  2994.     xchg    al,ah            ; then low five bits
  2995.     or    al,20h
  2996.     call    outmodem
  2997.     xchg    ah,al            ; al is first sent byte
  2998.     ret
  2999. SENDXY    ENDP
  3000.      
  3001.      
  3002. SENDID    PROC NEAR            ; pretend VT340
  3003.     mov    bx,offset tekid        ; VT320 identification string
  3004. sndid1: mov    al,[bx]            ; get char from sequence
  3005.     or    al,al            ; end of sequence?
  3006.     jz    sndid0            ; z = yes, return
  3007.     call    outmodem        ; send it out the port
  3008.     inc    bx
  3009.     jmp    sndid1
  3010. sndid0:    ret
  3011. SENDID    ENDP
  3012.      
  3013. ; SENDSTAT - send status and cursor position to host
  3014.      
  3015. SENDSTAT PROC NEAR
  3016.     mov    al,STATUS        ; get tek status
  3017.     or    al,20h            ; make it printable
  3018.     call    OUTMODEM        ; and send it
  3019.     mov    ax,oldx            ; now send x coordinate (oldx is Tek)
  3020.     call    SENDXY
  3021.     mov    ax,oldy            ; and y coordinate (oldy is Tek coord)
  3022.     call    SENDXY
  3023.     mov    al,cr            ; end with a cr
  3024.     call    OUTMODEM
  3025.     ret
  3026. SENDSTAT ENDP
  3027.      
  3028.  
  3029. ; Convert X and Y from PC coordinates to Tek coordinates. AX = X, BX = Y
  3030. ; for both input and output.
  3031. pctotek    proc    near
  3032.     mul    xdiv            ; scale from PC screen coord to Tek
  3033.     div    xmult
  3034.     xchg    bx,ax            ; save Tek x coord in bx
  3035.     neg    ax            ; y axis. Turn upside down for Tek
  3036.     add    ax,ybot
  3037.     mul    ydiv            ; scale y from PC screen coord to Tek
  3038.     div    ymult
  3039.     xchg    ax,bx            ; ax has X, bx has Y in Tek coords
  3040.     ret
  3041. pctotek    endp
  3042.  
  3043. ; Routine to output character in AL to the screen.
  3044.  
  3045. OUTSCRN PROC NEAR            ; put one character to the screen
  3046.     cmp    rxtable+256,0        ; translation turned off?
  3047.     je    outscr2            ; e = yes, no translation
  3048.     push    bx
  3049.     mov    bx,offset rxtable    ; address of translate table
  3050.     xlatb                ; new char is in al
  3051.     and    al,7fh            ; retain only lower seven bits
  3052.     pop    bx
  3053.  
  3054. outscr2:
  3055.     mov    ah,ccode        ; assume transparent chars
  3056.     push    ax            ; save ccode
  3057.     mov    ccode,pixfor        ; write in foreground
  3058.     cmp    chcontrol,0        ; transparent char writing?
  3059.     je    outscr3            ; e = yes
  3060.     or    ccode,pixbak        ; write background dots too
  3061. outscr3:cmp    al,lf            ; this moves down the screen
  3062.     je    outscr4            ; e = yes, a lf
  3063.     cmp    al,' '            ; printable?
  3064.     jb    outscr5            ; b = no
  3065. outscr4:call    testfull        ; check for full screen
  3066. outscr5:call    remcursor        ; remove text cursor symbol
  3067.     call    putc            ; routine to draw characters
  3068.     call    setcursor        ; draw text cursor symbol
  3069.     pop    ax            ; recover ccode
  3070.     mov    ccode,ah
  3071.     ret
  3072. OUTSCRN ENDP
  3073.      
  3074. ; Test if screen is full. If full sound beep, wait for any keyboard input
  3075. ; (skip kbd reading if stdin is redirected).
  3076. testfull proc    near
  3077.     push    ax
  3078.     mov    ax,x_coord
  3079.     cmp    ax,xmax            ; at end of the line?
  3080.     jbe    testfu1            ; be = no
  3081.     mov    x_coord,0        ; wrap to next line
  3082.     add    y_coord,8        ; next row
  3083. testfu1:mov    ax,ybot            ; get last scan line
  3084.     inc    ax            ; number of scan lines
  3085.     cmp    ax,y_coord        ; minus where char bottom needs to go
  3086.     jae    testfu3            ; ae = enough space for char
  3087.     call    tekbeep            ; tell the user we are waiting
  3088.     call    tiseof            ; EOF on redirected stdin?
  3089.     jc    testfu2            ; c = yes, proceed anyway
  3090.     mov    ah,coninq        ; read keyboad via DOS
  3091.     int    dos            ; wait for keystroke
  3092.     or    al,al            ; scan code being returned?
  3093.     jne    testfu2            ; ne = no
  3094.     mov    ah,coninq        ; clear away scan code too
  3095.     int    dos
  3096. testfu2:call    tekcls            ; clear the screen
  3097.     mov    x_coord,0
  3098.     mov    y_coord,0
  3099. testfu3:pop    ax            ; recover current character
  3100.     ret
  3101. testfull endp
  3102.  
  3103. ; Draw text cursor symbol by xor-ing. Sets xcursor,ycursor to symbol position.
  3104. setcursor proc    near
  3105.     cmp    tekcursor,0        ; suppress cursor?
  3106.     je    setcurs0        ; e = yes
  3107.     cmp    cursorst,0        ; is cursor off now?
  3108.     jne    setcurs0        ; ne = no
  3109.     cmp    putc,offset mputc    ; pure mono character display routine?
  3110.     jne    setcurs1        ; ne = no
  3111. setcurs0:ret                ; no cursor for pure mono
  3112. setcurs1:mov    bh,ccode        ; current drawing code, save it
  3113.     mov    bl,chcontrol        ; and transparent writing state
  3114.     push    bx            ; save ccode
  3115.     push    ax
  3116.     mov    ccode,pixxor        ; xor with foreground coloring
  3117.     mov    chcontrol,0        ; transparent characters
  3118.     push    x_coord            ; save current operating point (PC)
  3119.     push    y_coord
  3120.     mov    ax,x_coord        ; where cursor symbol starts, X axis
  3121.     cmp    ax,xmax            ; beyond last character position?
  3122.     jbe    setcurs2        ; be = no
  3123.     mov    ax,xmax            ; yes, stop at last, for wrapping
  3124. setcurs2:mov    xcursor,ax        ; remember where we drew symbol
  3125.     mov    x_coord,ax        ; set this for drawing the symbol
  3126.     mov    ax,y_coord
  3127.     mov    ycursor,ax
  3128.     mov    al,7fh            ; symbol code to draw
  3129.     call    putc            ; routine to draw characters
  3130.     pop    y_coord
  3131.     pop    x_coord
  3132.     pop    ax
  3133.     pop    bx            ; recover ccode
  3134.     mov    ccode,bh
  3135.     mov    chcontrol,bl
  3136.     mov    cursorst,1        ; say cursor is on
  3137.     ret
  3138. setcursor endp
  3139.  
  3140. ; Remove text cursor symbol by xor-ing with itself. Xcursor, ycursor is the
  3141. ; PC coord of the cursor symbol.
  3142. remcursor proc    near
  3143.     cmp    tekcursor,0        ; suppress cursor?
  3144.     je    remcurs0        ; e = yes
  3145.     cmp    cursorst,0        ; is cursor off now?
  3146.     je    remcurs0        ; e = yes
  3147.     cmp    putc,offset mputc    ; pure mono character display routine?
  3148.     jne    remcurs1        ; ne = no
  3149. remcurs0:ret                ; no cursor for pure mono
  3150. remcurs1:mov    bh,ccode        ; current drawing code, save it
  3151.     mov    bl,chcontrol        ; and transparent writing state
  3152.     push    bx            ; save ccode
  3153.     push    ax
  3154.     mov    ccode,pixxor        ; xor with foreground coloring
  3155.     mov    chcontrol,0        ; transparent characters
  3156.     push    x_coord            ; save current operating point (PC)
  3157.     push    y_coord
  3158.     mov    ax,xcursor        ; where last cursor was written
  3159.     mov    x_coord,ax        ; setup for xor writing to remove it
  3160.     mov    ax,ycursor
  3161.     mov    y_coord,ax
  3162.     mov    al,7fh            ; cursor symbol
  3163.     call    putc            ; routine to draw characters
  3164.     pop    y_coord
  3165.     pop    x_coord
  3166.     pop    ax
  3167.     pop    bx            ; recover ccode
  3168.     mov    ccode,bh
  3169.     mov    chcontrol,bl
  3170.     mov    cursorst,0        ; say cursor is off
  3171.     ret
  3172. remcursor endp
  3173.       
  3174. ; TEKCLS routine to clear the screen.
  3175. ; Entry point tekcls1 clears screen without resetting current point.     
  3176. TEKCLS    PROC    NEAR
  3177.     cmp    flags.vtflg,tttek    ; regular Tek terminal?
  3178.     je    tekcls0            ; e = yes
  3179.     test    tekflg,1        ; Tek mode active yet?
  3180.     jnz    tekcls0            ; nz = yes
  3181.     ret                ; else ignore this call
  3182. tekcls0:mov    x_coord,0        ; starting text coordinates
  3183.     mov    y_coord,0
  3184.     mov    oldx,0            ; assumed cursor starting location
  3185.     mov    oldy,maxteky        ;  top right corner (Tek coord)
  3186.     mov    scalex,0        ; clear last plotted point (PC coord)
  3187.     mov    scaley,0
  3188.     mov    lastc,0            ; last parsed x,y coordinate
  3189.     mov    visible,0        ; make lines invisible
  3190.     mov    bypass,0        ; clear bypass condition
  3191.     mov    ttstate,offset tektxt    ; do displayable text
  3192.     mov    prestate,offset tektxt
  3193. tekcls1:push    ax            ; save registers
  3194.     push    cx
  3195.     mov    bl,ccode        ; save pixel op code
  3196.     push    bx
  3197.     cmp    graph_mode,hercules    ; Hercules?
  3198.     jne    tekclsw            ; ne = no
  3199.     call    hgraf            ; set Hercules board to Graphics mode
  3200.     jmp    tekcls7
  3201.  
  3202. tekclsw:cmp    graph_mode,wyse700    ; Wyse 700?
  3203.     jne    tekcls2            ; ne = no
  3204.     call    wygraf            ; set board to Graphics mode & cls
  3205.     jmp    tekcls7
  3206.  
  3207. tekcls2:xor    di,di            ; point to start of screen, di=row
  3208.     mov    ccode,pixbak        ; write in background
  3209.     call    psetup            ; setup graphics routine and es:di
  3210.     mov    cx,4000h        ; CGA, 200 lines times 80 bytes worth
  3211.     cmp    graph_mode,cga        ; cga?
  3212.     je    tekcls3            ; e = yes
  3213.     mov    cx,8000h        ; Olivetti, 400 lines times 80 bytes
  3214.     cmp    graph_mode,olivetti    ; AT&T-Olivetti?
  3215.     je    tekcls3            ; e = yes
  3216.     cmp    graph_mode,toshiba    ; Toshiba?
  3217.     je    tekcls3            ; e = yes
  3218.     cmp    graph_mode,vaxmate    ; VAXmate?
  3219.     jne    tekcls4            ; ne = no
  3220. tekcls3:cld                ; clear screen directly of text stuff
  3221.     xor    ax,ax
  3222.     test    gbcol,7            ; background is dark?
  3223.     jz    tekcls3a        ; z = yes
  3224.     mov    ax,0ffffh        ; light, set all pixels
  3225. tekcls3a:shr    cx,1            ; do words
  3226.     rep    stosw            ; clear the words
  3227.     jmp    short tekcls7
  3228.  
  3229. tekcls4:cmp    graph_mode,ega        ; EGA?
  3230.     je    tekcls5            ; e = yes
  3231.     cmp    graph_mode,monoega    ; EGA with mono display?
  3232.     je    tekcls5            ; e = yes
  3233.     cmp    graph_mode,colorega    ; EGA with medium resolution monitor?
  3234.     je    tekcls5            ; e = yes
  3235.     jmp    short tekcls6        ; else use Bios
  3236.  
  3237. tekcls5:                ; EGA clear screen quickly
  3238.     mov    ax,0ff08h        ; set all 8 bits to be changed
  3239.     call    ega_gc            ; set bit mask register accordingly
  3240.     mov    ax,0003h        ; data rotate reg, write unmodified
  3241.     call    ega_gc            ; 
  3242.     mov    cx,ybot            ; last scan line
  3243.     inc    cx            ; number of scan lines
  3244.     mov    ax,80/2            ; words (2*bytes) per scan line
  3245.     mul    cx
  3246.     mov    cx,ax            ; cx = number of bytes to clear
  3247.     call    fixcolor        ; fix colors first, if req'd
  3248.     mov    al,gbcol        ; select background colour
  3249.     mov    ah,al            ; copy for word stores
  3250.     cld
  3251.     rep    stosw            ; write backgound color
  3252.     jmp    short tekcls7
  3253.  
  3254. tekcls6:push    es            ; clear screen by scrolling up
  3255.     call    tcmblnk            ; clear screen, for Environments
  3256.     pop    es
  3257.  
  3258. tekcls7:xor    si,si            ; starting x  (in case screen is
  3259.     xor    di,di            ; starting y    cleared by user)
  3260.     pop    bx
  3261.     mov    ccode,bl        ; restore pixel op code
  3262.     mov    xcursor,0        ; position of text cursor symbol
  3263.     mov    ycursor,0
  3264.     mov    cursorst,0        ; say text cursor is off (new screen)
  3265.     call    setcursor        ; draw text cursor symbol
  3266.     pop    cx
  3267.     pop    ax
  3268.     ret
  3269. TEKCLS    ENDP
  3270.      
  3271. ; Routine to draw a line on the screen, using TEKTRONIX coordinates.
  3272. ; X coordinate in AX, 0=left edge of screen, 1023=right edge of screen.
  3273. ; Y coordinate in BX, 0=bottom of screen, 779=top of screen.
  3274. ; CL=0 - invisible move, else draw in foreground colors
  3275.      
  3276. TEKDRAW PROC NEAR
  3277.     mov    si,scalex        ; get old x already scaled
  3278.     mov    di,scaley        ; get old y already scaled
  3279.     call    scale             ; scale new end point to PC coords
  3280.     or    cl,cl            ; invisible drawing?
  3281.     jz    moveto            ; z = just move, skip draw part
  3282.     mov    cl,pixfor        ; draw in foreground color
  3283.     call    LINE            ; draw the line
  3284. moveto:    mov    x_coord,ax        ; update text coordinates to match
  3285.     mov    y_coord,bx        ;  last drawn point
  3286.     ret
  3287. TEKDRAW ENDP
  3288.      
  3289. ; Scale TEKTRONIX coordinates to the currently defined screen coordinates
  3290. ; AX holds X axis, BX holds Y axis. Both are changed from Tektronix coord
  3291. ; to PC coordinates by this procedure.
  3292. SCALE    PROC    NEAR
  3293.     push    dx
  3294.     push    si
  3295.     cmp    ax,1023            ; limit x axis
  3296.     jbe    scale1            ; be = not out of bounds
  3297.     mov    ax,1023
  3298. scale1:    cmp    bx,779            ; limit y axix
  3299.     jbe    scale2            ; be = not out of bounds
  3300.     mov    bx,779
  3301. scale2:    mov    oldx,ax            ; save current Tek x for next draw
  3302.     mov    oldy,bx            ; save current Tek y for next draw
  3303.     mul    xmult            ; scale x-coord
  3304.     mov    si,xdiv            ; get the divisor
  3305.     shr    si,1            ; halve it
  3306.     add    ax,si            ; add in - to round to nearest integer
  3307.     adc    dx,0
  3308.     div    xdiv
  3309.     push    ax
  3310.     mov    ax,bx
  3311.     mul    ymult            ; scale y-coord
  3312.     mov    si,ydiv            ; get divisor
  3313.     shr    si,1            ; halve it
  3314.     add    ax,si            ; add in - to round to nearest integer
  3315.     adc    dx,0
  3316.     div    ydiv
  3317.     mov    bx,ybot
  3318.     sub    bx,ax            ; put new Y in right reg
  3319.     jns    scale3            ; ns = not too far
  3320.     xor    bx,bx
  3321. scale3:    pop    ax            ; put new X in right reg
  3322.     mov    scalex,ax        ; save scaled values
  3323.     mov    scaley,bx
  3324.     pop    si
  3325.     pop    dx
  3326.     ret
  3327. SCALE    ENDP
  3328.       
  3329. ; LINE    Subroutine to plot a line with endpoints in AX,BX and SI,DI.
  3330. ;    fast line drawing routine for the IBM PC
  3331. ;
  3332. ; Registers at CALL
  3333. ; -----------------
  3334. ; SI=Start X coord, all in PC coordinates
  3335. ; DI=Start Y coord
  3336. ; AX=End X coord
  3337. ; BX=End Y coord
  3338. ; CCODE=pixel operation code
  3339. ; BP= line drawing pattern (is changed here by rotation)
  3340. ; registers are all unchanged
  3341.      
  3342. LINE    PROC    NEAR
  3343.     push    ax
  3344.     push    bx
  3345.     push    cx
  3346.     push    dx
  3347.     push    si
  3348.     push    di
  3349.     push    es
  3350.     mov    bp,linepat        ; store active line pattern word in BP
  3351.     mov    dl,ccode        ; existing pixel op code
  3352.     push    dx            ; save around line drawing
  3353.     mov    ccode,cl    ; save color code in ccode for use by plot()
  3354.             ; first get coord to achieve increasing x; deltax >= 0
  3355.     sub    ax,si            ; deltax = x2 - x1
  3356.     jge    line1            ; ge = going to the right, as desired
  3357.     neg    ax            ; make deltax non-negative
  3358.     sub    si,ax            ; swap the x coordinates
  3359.     xchg    bx,di            ; swap the y coordinates too
  3360.                 ; second, compute deltay. ax = deltax, si = x1
  3361. line1:    sub    bx,di            ; deltay = y2 - y1
  3362.     call    psetup            ; setup display adapter for plotting
  3363.                     ;  and setup es:di to screen memory
  3364.   ; Choose algorithm based on |deltay| < |deltax| (use shallow) else steep.
  3365.   ; We arrange matters such that both deltas are non-negative.
  3366.     cmp    bx,0            ; deltay
  3367.     jge    line2            ; ge = non-negative
  3368.     neg    linelen
  3369.     neg    bx            ; make non-negative
  3370. line2:    cmp    bx,ax            ; |deltay| versus |deltax|
  3371.     jbe    shallow            ; be = do shallow algorithm
  3372.     jmp    steep            ; else do steep algorithm
  3373.  
  3374.     ; shallow algorithm, move along x, di=y1, bx=deltay, si=x1, ax=deltax
  3375. shallow:add    bx,bx            ; bx = 2*deltay
  3376.     mov    cx,ax            ; cx = number of steps (deltax here)
  3377.     inc    cx            ; loop dec's cx before testing
  3378.     mov    dx,bx            ; dx holds error
  3379.     sub    dx,ax            ; error = 2*deltay - deltax
  3380.     add    ax,ax            ; ax = 2*|deltax|
  3381. shal1:    call    plotptr            ; Plot(x,y)
  3382.     cmp    dx,0
  3383.     jle    shal2            ; le =     error <= 0
  3384.     call    pincy            ; increment y by one scan line
  3385.     sub    dx,ax            ; error = error - 2*deltax
  3386. shal2:    add    dx,bx            ; error = error + 2*deltay
  3387.     inc    si            ; x = next dot right
  3388.     loop    shal1
  3389.     jmp    short plotex
  3390.  
  3391.     ; steep algorithm, move along y, di=y1, bx=deltay, si=x1, ax=deltax
  3392. steep:    add    ax,ax            ; ax = 2*deltax
  3393.     mov    dx,ax            ; dx holds error
  3394.     sub    dx,bx            ; error = 2*deltax(bx) - deltay (bx)
  3395.     mov    cx,bx            ; cx = number of steps (deltay here)
  3396.     inc    cx            ; loop dec's cx before testing
  3397.     add    bx,bx            ; bx = 2*|deltay|
  3398. stee1:    call    plotptr            ; Plot(x,y) x = ax, y = di
  3399.     cmp    dx,0
  3400.     jle    stee2            ; le  error <= 0
  3401.     inc    si            ; x = next dot right
  3402.     sub    dx,bx            ; error = error - 2*deltay
  3403. stee2:    add    dx,ax            ; error = error + 2*deltax
  3404.     call    pincy            ; increment y
  3405.     loop    stee1
  3406. ;;;    jmp    plotex
  3407.  
  3408. plotex:    pop    dx            ; al has orginal pixel op
  3409.     mov    ccode,dl        ; restore it
  3410.     pop    es
  3411.     pop    di
  3412.     pop    si
  3413.     pop    dx            ; restore the world
  3414.     pop    cx
  3415.     pop    bx
  3416.     pop    ax
  3417.     ret
  3418. LINE    ENDP
  3419.  
  3420. ; Draw a rectangle.
  3421. ;  lower left corner: x = param[0], y = param[2], Tek coordinates
  3422. ;  distance: dx = param[4], dy = param[6], Tek coordinates, all positive
  3423. rectdraw proc    near
  3424.     push    x_coord
  3425.     push    y_coord
  3426.     mov    ax,param[0]        ; lower left corner is start, x part
  3427.     mov    bx,param[2]        ; y part
  3428.     push    ax            ; x0
  3429.     push    bx            ; y0
  3430.     xor    cl,cl            ; moveto
  3431.     call    tekdraw
  3432.     pop    bx
  3433.     pop    ax
  3434.     add    bx,param[6]        ; y0 + dy
  3435.     mov    cl,1            ; draw x0,y0  to  x0,y0+dy
  3436.     push    ax
  3437.     push    bx
  3438.     call    tekdraw
  3439.     pop    bx
  3440.     pop    ax
  3441.     add    ax,param[4]        ; x0+dx
  3442.     mov    cl,1            ; draw x0,y0+dy  to  x0+dx,y0+dy
  3443.     push    ax
  3444.     call    tekdraw
  3445.     pop    ax
  3446.     mov    bx,param[2]        ; y0
  3447.     push    bx
  3448.     mov    cl,1
  3449.     call    tekdraw
  3450.     pop    bx
  3451.     mov    ax,param[0]        ; x0
  3452.     mov    cl,1
  3453.     call    tekdraw            ; complete the box
  3454.     pop    y_coord
  3455.     pop    x_coord
  3456.     ret
  3457. rectdraw endp
  3458.  
  3459. ; Fill a rectangle with a given pattern.
  3460. ;  lower left corner: x = param[0], y = param[2], Tek coordinates
  3461. ;  distance: dx = param[4], dy = param[6], Tek coordinates, all positive
  3462. ;  fill pattern = param[8]
  3463. rectfil    proc    near
  3464.     push    oldx
  3465.     push    oldy            ; save regular point/line old coords
  3466.     mov    ax,param        ; get Tek X coord of lower left corner
  3467.     mov    bx,param[2]        ; get Tek Y coord
  3468.     call    scale            ; convert to PC in ax,bx, scalex/y
  3469.     mov    rectx1,ax        ; lower left corner in PC coords
  3470.     mov    recty1,bx
  3471.     mov    ax,param        ; convert ending points, start Tek X
  3472.     add    ax,param[4]        ; Tek X + DX
  3473.     mov    bx,param[2]        ; start Tek Y
  3474.     add    bx,param[6]        ; Tek Y + DY
  3475.     call    scale
  3476.     pop    oldy
  3477.     pop    oldx
  3478.     mov    rectx2,ax        ; upper right corner PC X coord
  3479.     mov    recty2,bx        ; upper right corner PC Y coord
  3480.     mov    si,rectx1        ; starting x PC coord to si
  3481.     mov    di,recty2        ; starting y PC coord to di
  3482.     mov    cx,recty1        ; plotting from top down on screen
  3483.     sub    cx,bx            ; cx = # scan lines - 1
  3484.     mov    numlines,cx        ; remember here
  3485.     mov    bx,param[8]        ; fill pattern number
  3486.     or    bx,bx            ; zero?
  3487.     jz    rectfi1            ; z = yes, use current pointer
  3488.     cmp    bx,numfil        ; pattern number is too large?
  3489.     ja    rectfi1            ; a = yes, use current pointer
  3490.     dec    bx            ; count internally from 0
  3491.     shl    bx,1            ; make this a word pointer
  3492.     mov    bx,fillist[bx]        ; get pointer to pattern
  3493.     mov    fillptr,bx        ; remember it here
  3494. rectfi1:mov    cx,rectx2        ; ending x coord
  3495.     sub    cx,rectx1        ; number of horizontal pixels - 1
  3496.     inc    cx            ; number of horizontal pixels
  3497.     call    psetup            ; set up dsp and di to screen offset
  3498.             ; di points to whole byte, do bits in byte in gfplot
  3499. rectfi2:push    bx
  3500.      mov    bx,recty1        ; lower screen y (larger value)
  3501.     sub    bx,numlines        ; alignment: global screen sync
  3502.     and    bx,7            ; modulo 8
  3503.     add    bx,fillptr        ; offset of fill pattern start
  3504.     mov    bl,[bx]            ; pattern byte
  3505.     mov    fill,bl            ; save here for gfplot
  3506.     pop    bx
  3507.     call    gfplot            ; line fill routine
  3508.     call    pincy            ; next line
  3509.     dec    numlines
  3510.     jns    rectfi2            ; ns = more to do
  3511.     ret
  3512. rectfil    endp
  3513.  
  3514. ;;;;;;; EGA plot support routines
  3515. psetupe    proc    near            ; EGA setup for plotting
  3516.     push    ax
  3517.     mov    linelen,80        ; for y going down screen by pincy
  3518.     mov    ax,segscn        ; set es to screen memory segment
  3519.     mov    es,ax
  3520.     mov    ax,0205h        ; mode: write mode 2
  3521.     call    ega_gc
  3522.     mov    ax,0003h        ; assume writing bits directly
  3523.     test    ccode,pixfor+pixbak    ; direct foreground/background write?
  3524.     jnz    psete2            ; nz = yes
  3525.     mov    ax,1003h        ; assume OR
  3526.     test    ccode,pixor        ; OR?
  3527.     jnz    psete2            ; nz = yes
  3528.     mov    ax,1803h        ; assume XOR
  3529.     test    ccode,pixxor        ; inverting bits?
  3530.     jnz    psete2            ; nz = yes
  3531.     mov    ax,0803h        ; then use AND
  3532. psete2:    call    ega_gc            ; set controller
  3533.     mov    ax,80            ; compute starting point in regen buff
  3534.     mul    di
  3535.     mov    di,ax            ; di = di * 80
  3536.     pop    ax
  3537.     ret
  3538. psetupe    endp
  3539.  
  3540. pincye    proc    near            ; EGA inc y
  3541.     add    di,linelen        ; includes sign of deltay
  3542.     ret
  3543. pincye    endp
  3544.  
  3545. pltega    proc    near        ; EGA plot(x,y). x is in si, y is in di
  3546.     ror    bp,1            ; rotate line pattern
  3547.     jc    pltega1            ; c = a 1 bit to be plotted
  3548.     cmp    ccode,pixfor+pixbak    ; plot both 1's and 0's?
  3549.     je    pltega1            ; e = yes
  3550.     ret                ; else ignore the 0 bit
  3551. pltega1:push    bx
  3552.     push    si
  3553.     push    di
  3554.     mov    bx,si            ; want si/8 for bytes along line
  3555.     shr    si,1
  3556.     shr    si,1
  3557.     shr    si,1
  3558.     add    di,si            ; starting point in regen buffer
  3559.     and    bx,0007h        ; leave lower 3 bits for bit in byte
  3560.     mov    bh,masktab[bx]        ; 0-7 into bit mask in byte, x pos
  3561.     mov    bl,ccode        ; get line type code
  3562.     call    ega_plt
  3563.     pop    di
  3564.     pop    si
  3565.     pop    bx
  3566.     ret
  3567. pltega    endp
  3568.  
  3569. ; Plot bit pattern in "fill" as 8 horizontal pixels, starting at x,y (si,di)
  3570. ; and continuing across the line for cx pixels. psetupe has been called.
  3571. bpltega    proc    near        ; EGA plot(x,y). x is in si, y is in di
  3572.     push    bx
  3573.     push    cx
  3574.     push    si
  3575.     push    di
  3576.     mov    bx,si            ; want si/8 for bytes along line
  3577.     shr    si,1
  3578.     shr    si,1
  3579.     shr    si,1
  3580.     add    di,si            ; starting byte in regen buffer
  3581.                     ; di = offset in regen buffer
  3582.     and    bl,7            ; get bit in byte (di = byte aligned)
  3583.     jz    bplteg1            ; z = aligned already
  3584.     xchg    bl,cl            ; get shift to cl, low count to bl
  3585.     mov    bh,fill            ; 8-bit fill pattern
  3586.     mov    al,bh            ; get complement of pattern too
  3587.     not    al
  3588.     shl    bh,cl            ; trim cl bits from the left
  3589.     shr    bh,cl
  3590.     shl    al,cl            ; trim them from the right edge
  3591.     shr    al,cl            ; restore pattern
  3592.     xchg    cl,bl            ; put count back in cx
  3593.     add    cl,bl            ; add bits taken care of
  3594.     adc    ch,0
  3595.     jmp    short bplteg2        ; do this partial byte now
  3596.  
  3597. bplteg1:mov    bh,fill            ; fill pattern
  3598.     mov    al,bh            ; make inverted pattern
  3599.     not    al
  3600.     cmp    cx,8            ; do all 8 bits?
  3601.     jae    bplteg2            ; ae = yes
  3602.     push    cx            ; final byte fixup
  3603.     sub    cl,8            ; cl = - (number of bits to omit)
  3604.     neg    cl            ; cl = number of bits to omit
  3605.     mov    al,bh            ; get complement of pattern too
  3606.     not    al
  3607.     shr    bh,cl            ; trim them from the right edge
  3608.     shl    bh,cl            ; restore pattern
  3609.     shr    al,cl            ; trim them from the right edge
  3610.     shl    al,cl            ; restore pattern
  3611.     pop    cx
  3612. bplteg2:push    ax
  3613.     cmp    ccode,pixfor+pixbak    ; do both fore and background?
  3614.     jne    bplteg2a        ; ne = no
  3615.     push    bx
  3616.     mov    bh,al            ; get complemented pattern
  3617.     mov    bl,pixbak        ; write background
  3618.     call    ega_plt
  3619.     pop    bx
  3620. bplteg2a:mov    bl,ccode        ; get line type code
  3621.     call    ega_plt
  3622. bplteg3:pop    ax
  3623.     inc    di            ; next byte right
  3624.     sub    cx,8            ; did these
  3625.     cmp    cx,0            ; anything left to do?
  3626.     jg    bplteg1            ; a = yes, repeat
  3627.     pop    di
  3628.     pop    si
  3629.     pop    cx
  3630.     pop    bx
  3631.     ret
  3632. bpltega    endp
  3633.  
  3634. ;;;;;;;; CGA plot support routines
  3635. ; The CGA graphics memory mapping in mode 6 (640 by 200) is 8 dots per byte,
  3636. ; left most dot in the high bit, 80 bytes per scan line, scan line segments
  3637. ; alternating between 0b800h (even lines 0, 2, ...) and 0ba00h (odd lines).
  3638. psetupc    proc    near            ; CGA setup for plotting
  3639.     push    ax
  3640.     push    cx
  3641.     mov    linelen,80        ; 80 bytes per scan line
  3642.     mov    cx,segscn
  3643.     mov    es,cx
  3644.     mov    cx,di            ; save copy of di, start y line
  3645.                     ; compute starting point in regen buff
  3646.     shr    di,1            ; half the lines in each bank
  3647.     mov    ax,80            ; 80 bytes per line
  3648.     mul    di
  3649.     mov    di,ax            ; di = di * 80 / 2
  3650.     test    cx,1            ; even or odd line
  3651.     jz    psetc1            ; z = even
  3652.     add    di,2000h        ; offset to odd bank (seg 0ba00h)
  3653. psetc1:    and    di,3fffh
  3654.     pop    cx
  3655.     pop    ax
  3656.     ret
  3657. psetupc    endp
  3658.  
  3659. pincyc    proc    near            ; CGA inc y
  3660.     cmp    linelen,0        ; increasing or decreasing y?
  3661.     jl    pinyc2            ; l = decreasing
  3662.     cmp    di,2000h        ; in upper bank now?
  3663.     jb    pinyc1            ; b = no, in lower bank
  3664.     add    di,linelen        ; add a line
  3665. pinyc1:    add    di,2000h        ; switch banks
  3666.     and    di,3fffh        ; roll over address
  3667.     ret
  3668. pinyc2:    cmp    di,2000h        ; in upper bank now?
  3669.     jae    pinyc4            ; ae = yes
  3670.     add    di,linelen        ; subtract a line
  3671. pinyc4:    add    di,2000h        ; switch banks
  3672.     and    di,3fffh        ; roll over address
  3673.     ret
  3674. pincyc    endp
  3675.  
  3676. pltcga    proc    near        ; CGA plot(x,y). x is in si, y is in di
  3677.     push    bx        ; used for HGA and Wyse plots also.
  3678.     push    si
  3679.     push    di
  3680.     ror    bp,1            ; rotate line pattern
  3681.     jc    pltcg6            ; c = 1 bit to be plotted
  3682.     cmp    ccode,pixfor+pixbak    ; plot both 1's and 0's?
  3683.     jne    pltcg3            ; ne = no
  3684.  
  3685. pltcg6:    mov    bx,si            ; want si/8 for bytes along line
  3686.     shr    si,1
  3687.     shr    si,1
  3688.     shr    si,1
  3689.     add    di,si            ; starting point in regen buffer
  3690.     and    bx,0007h        ; leave lower 3 bits for bit in byte
  3691.                     ; di = offset in regen buffer
  3692.     mov    bh,masktab[bx]        ; 0-7 into bit mask in byte. x position
  3693.     mov    bl,ccode        ; get line type code
  3694.     test    bl,pixfor+pixor        ; draw in foreground color or OR?
  3695.     jz    pltcg1            ; z = no
  3696.     test    bl,pixor        ; OR?
  3697.     jnz    pltcg5            ; nz = yes
  3698.     test    gfcol,7            ; is foreground dark?
  3699.     jz    pltcg4            ; z = yes, punch a hole
  3700. pltcg5:    or    es:[di],bh        ; drawn
  3701.     jmp    short pltcg3
  3702. pltcg1:    test    bl,pixbak        ; draw in background (erase)?
  3703.     jz    pltcg2            ; z = no
  3704.     test    gbcol,7            ; is background light?
  3705.     jnz    pltcg5            ; nz = yes
  3706. pltcg4:    not    bh            ; invert the bit
  3707.     and    es:[di],bh        ; erase the dot
  3708.     jmp    short pltcg3
  3709. pltcg2:    xor    es:[di],bh        ; xor in this color
  3710. pltcg3:    pop    di
  3711.     pop    si
  3712.     pop    bx
  3713.     ret
  3714. pltcga    endp
  3715.  
  3716. ; Plot bit pattern in fill as 8 horizontal pixels, starting at x,y (si,di)
  3717. ; and continuing across the line for cx pixels. psetupc has been called.
  3718. bpltcga    proc    near        ; CGA plot(x,y). x is in si, y is in di
  3719.     push    bx        ; used for HGA and Wyse plots also.
  3720.     push    cx
  3721.     push    si
  3722.     push    di
  3723.     mov    bx,si            ; want si/8 for bytes along line
  3724.     shr    si,1
  3725.     shr    si,1
  3726.     shr    si,1
  3727.     add    di,si            ; starting byte in regen buffer
  3728.                     ; di = offset in regen buffer
  3729.     and    bl,7            ; get bit in byte (di = byte aligned)
  3730.     jz    bpltcg5            ; z = aligned already
  3731.     xchg    bl,cl            ; get shift to cl, low count to bl
  3732.     mov    bh,fill            ; 8-bit fill pattern
  3733.     shl    bh,cl            ; trim cl bits from the left
  3734.     shr    bh,cl
  3735.     push    cx
  3736.     mov    al,0ffh            ; 1's are original bits to be saved
  3737.     sub    cl,8            ; max field width is 8 bits
  3738.     neg    cl            ; 8-number of bits trimmed from left
  3739.     shl    al,cl            ; al now holds save-field bit pattern
  3740.     pop    cx
  3741.     xchg    cl,bl            ; put count back in cx
  3742.     add    cl,bl            ; add bits taken care of
  3743.     adc    ch,0
  3744.     jmp    short bpltcg4        ; do this partial byte now
  3745.  
  3746. bpltcg5:mov    bh,fill            ; fill pattern
  3747.     xor    al,al            ; assume saving no bits
  3748.     cmp    cx,8            ; do all 8 bits?
  3749.     jae    bpltcg4            ; ae = yes
  3750.     push    cx            ; final byte fixup
  3751.     mov    al,0ffh            ; 1's are original bits to be saved
  3752.     shl    al,cl
  3753.     shr    al,cl            ; al now holds save-field bit pattern
  3754.     sub    cl,8            ; cl = - (number of bits to omit)
  3755.     neg    cl            ; cl = number of bits to omit
  3756.     shr    bh,cl            ; trim them from the right edge
  3757.     shl    bh,cl            ; restore pattern
  3758.     pop    cx
  3759. bpltcg4:mov    bl,ccode        ; get line type code
  3760.     cmp    bl,pixfor+pixbak    ; set both fore and background?
  3761.     jne    bpltcg9            ; ne = no
  3762.     test    gfcol,7            ; is foreground dark?
  3763.     jnz    bpltcg8            ; nz = no
  3764.     not    bh            ; invert the bit pattern
  3765.     or    bh,al            ; set bits to be saved
  3766.     sub    bh,al            ; trim off saved bits from this field
  3767. bpltcg8:mov    ah,es:[di]        ; get contents of memory cell
  3768.     and    ah,al            ; preserve bit field given by al
  3769.     or    bh,ah            ; mask in saved bits
  3770.     mov    es:[di],bh        ; write the byte
  3771.     jmp    short bpltcg3        ; done
  3772. bpltcg9:test    bl,pixfor+pixor        ; draw in foreground?
  3773.     jz    bpltcg1            ; z = no
  3774.     test    bl,pixor        ; OR?
  3775.     jnz    bpltcg7            ; nz = yes
  3776.     test    gfcol,7            ; is foreground dark?
  3777.     jz    bpltcg6            ; z = yes, punch a hole
  3778. bpltcg7:or    es:[di],bh        ; drawn
  3779.     jmp    short bpltcg3
  3780. bpltcg1:test    bl,pixbak        ; draw as background (erase)?
  3781.     jz    bpltcg2            ; z= do not draw as background (erase)
  3782.     test    gbcol,7            ; is background light?
  3783.     jz    bpltcg6            ; z = no
  3784.     or    es:[di],bh        ; drawn
  3785.     jmp    short bpltcg3
  3786. bpltcg6:not    bh
  3787.     and    es:[di],bh        ; erase the dots
  3788.     jmp    short bpltcg3
  3789. bpltcg2:xor    es:[di],bh        ; xor in this color
  3790. bpltcg3:inc    di            ; next byte right
  3791.     sub    cx,8            ; did these
  3792.     cmp    cx,0            ; anything left to do?
  3793.     jg    bpltcg5            ; a = yes, repeat
  3794.     pop    di
  3795.     pop    si
  3796.     pop    cx
  3797.     pop    bx
  3798.     ret
  3799. bpltcga    endp
  3800.  
  3801. ;;;;;;; Wyse-700 plot support routines
  3802. ; The Wyse graphics memory map in mode 0D3h (1280 by 800) is 8 dots per byte,
  3803. ; left most dot in the high bit, 160 bytes per scan line, scan line segments
  3804. ; sequence as 0a000h even lines, and same for odd lines
  3805. psetupw proc    near            ; Wyse setup for plotting
  3806.     push    ax
  3807.     push    cx
  3808.     push    dx
  3809.     mov    linelen,160        ; for y going down screen by incy
  3810.     mov    ax,segscn        ; base segment of display memory
  3811.     mov    es,ax
  3812.     mov    cx,di            ; save copy of di, start y line
  3813.                     ; compute starting point in regen buff
  3814.     shr    di,1            ; half the lines in each bank
  3815.     mov    ax,160
  3816.     mul    di
  3817.     mov    di,ax            ; di = di * 160 / 2
  3818.     mov    dx,wymode
  3819.     shr    cx,1            ; compute bank from 1 lsb of line num
  3820.     jnc    psetw2            ; nc = it is in bank 0 (0b000h)
  3821.     mov    ax,wybodd        ; select odd bank
  3822.     out    dx,al
  3823.     jmp    short psetw3
  3824. psetw2: mov    ax,wybeven        ; select even bank
  3825.     out    dx,al
  3826. psetw3: mov    bnkchan, al        ; bank has changed
  3827.     pop    dx
  3828.     pop    cx
  3829.     pop    ax
  3830.     ret
  3831. psetupw endp
  3832.  
  3833. ;
  3834. ; Wyse-700 has two banks. Line 0, 2, 4 ... are in bank 0, and 1, 3, 5 ... are
  3835. ; in bank 1. Lines 0 and 1 have same addresses, lines 2 and 3 have same
  3836. ; addresses etc. We have to change bank every time Y changes but we
  3837. ; have to count new address only after two Y-value changes. Variable
  3838. ; bnkchan is a flag for us to know into which bank to write.
  3839. ;
  3840. pincyw    proc    near            ; Wyse inc y, step offset of line
  3841.     push    ax
  3842.     push    dx
  3843.     mov    dx,wymode        ; Wyse conrol register
  3844.     mov    al,wybeven        ;
  3845.     cmp    bnkchan,wybeven        ; was last write into even bank ?
  3846.     jne    pincywe            ; ne = no
  3847.     mov    al,wybodd        ; yes, set ready for odd bank
  3848.     out    dx,al            ;
  3849.     mov    bnkchan,al        ; set to odd
  3850.     jmp    short pincywo
  3851. pincywe:mov    al,wybeven        ; set ready foe even bank
  3852.     out    dx,al            ; select it
  3853.     mov    bnkchan,al        ; set to odd
  3854. pincywo:cmp    linelen,0        ; increasing y?
  3855.     jg    pinyw2            ; g = yes
  3856.     cmp    al,wybeven        ; from high (1) to low (0) bank ?
  3857.     je    pinyw4            ; e = yes
  3858.     add    di,linelen        ; no, add a line
  3859.     jmp    short pinyw4
  3860. pinyw2: cmp    al,wybodd        ; from low (0) to high (1) bank ?
  3861.     je    pinyw4            ; e = yes
  3862.     add    di,linelen        ; no, add a line
  3863. pinyw4: and    di,0ffffh        ; roll over address
  3864.     pop    dx
  3865.     pop    ax
  3866.     ret
  3867. pincyw    endp
  3868.  
  3869. ;;;;;;; HGA plot support routines
  3870. ; The HGA graphics memory mapping in mode 255 (720 by 348) is 8 dots per byte,
  3871. ; left most dot in the high bit, 90 bytes per scan line, scan line segments
  3872. ; sequence as 0b000h, 0b200h, 0b400h, 0b800h for lines 0-3 and repeat 90 bytes
  3873. ; higher for the rest.
  3874. psetuph    proc    near            ; HGA setup for plotting
  3875.     push    ax
  3876.     push    cx
  3877.     mov    linelen,90        ; for y going down screen by incy
  3878.     mov    ax,segscn        ; base segment of display memory
  3879.     mov    es,ax
  3880.     mov    cx,di            ; save copy of di, start y line
  3881.                     ; compute starting point in regen buff
  3882.     shr    di,1            ; quarter the lines in each bank
  3883.     shr    di,1
  3884.     mov    ax,90
  3885.     mul    di
  3886.     mov    di,ax            ; di = di * 90 / 4
  3887.     and    cx,3            ; compute bank from 2 lsb of line num
  3888.     jcxz    pseth2            ; z means it is in bank 0 (0b000h)
  3889. pseth1:    add    di,2000h        ; add offset for each bank
  3890.     loop    pseth1            ; do cx times
  3891. pseth2:    pop    cx
  3892.     pop    ax
  3893.     ret
  3894. psetuph    endp
  3895.  
  3896. pincyh    proc    near            ; HGA inc y, step offset of line
  3897.     cmp    linelen,0        ; increasing y?
  3898.     jg    pinyh2            ; g = yes
  3899.     cmp    di,2000h        ; in lowest for four banks?
  3900.     ja    pinyh1            ; a = no
  3901.     add    di,linelen        ; yes, add a line
  3902. pinyh1:    add    di,6000h        ; move back by adding a lot
  3903.     and    di,7fffh        ; roll over address
  3904.     ret
  3905. pinyh2:    cmp    di,6000h        ; in top most bank?
  3906.     jb    pinyh4            ; b = no
  3907.     add    di,linelen        ; yes, first add a line
  3908. pinyh4:    add    di,2000h        ; switch to next bank
  3909.     and    di,7fffh        ; roll over address
  3910.     ret
  3911. pincyh    endp
  3912.  
  3913. ;;;;;;; AT&T-Olivetti, Toshiba, VAXmate Graphics Adapter plot support routines
  3914. ; The graphics memory mapping in 640 by 400 mode is 8 dots per byte,
  3915. ; left most dot in the high bit, 80 bytes per scan line, scan line segments
  3916. ; sequence as 0b800h, 0ba00h, 0bc00h, 0be00h for lines 0-3 and repeat 80 bytes
  3917. ; higher for the rest. Use Hercules line incrementing (inc y) and CGA dot
  3918. ; writing. This is a monographic display.
  3919. psetupo    proc    near            ; setup for plotting
  3920.     push    ax
  3921.     push    cx
  3922.     mov    linelen,80        ; for y going down screen by incy
  3923.     mov    ax,segscn        ; base segment of display memory
  3924.     mov    es,ax
  3925.     mov    cx,di            ; save copy of di, start y line
  3926.                     ; compute starting point in regen buff
  3927.     shr    di,1            ; quarter the lines in each bank
  3928.     shr    di,1
  3929.     mov    ax,80
  3930.     mul    di
  3931.     mov    di,ax            ; di = di * 80 / 4
  3932.     and    cx,3            ; compute bank from 2 lsb of line num
  3933.     jcxz    pseto2            ; z means it is in bank 0 (0b800h)
  3934. pseto1:    add    di,2000h        ; add offset for each bank
  3935.     loop    pseto1            ; do cx times
  3936. pseto2:    pop    cx
  3937.     pop    ax
  3938.     ret
  3939. psetupo    endp
  3940.  
  3941. ;;;;;;;; Monochrome, simulate dots with text char
  3942. psetupm    proc    near
  3943.     mov    linelen,1        ; 80 characters but one line
  3944.     ret
  3945. psetupm    endp
  3946.  
  3947. pltmon    proc    near            ; Monochrome dot plot
  3948.     mov    x_coord,si        ; put dot at row=di, col=si, PC Coord
  3949.     mov    y_coord,di
  3950.     push    ax
  3951.     mov    al,'+'            ; our dot character
  3952.     call    mputc            ; display text char
  3953.     pop    ax
  3954.     ret
  3955. pltmon    endp
  3956.  
  3957. ; Plot bit pattern in fill as 8 horizontal pixels, starting at x,y (si,di)
  3958. ; and continuing across the line for cx pixels. Destroys CX.
  3959. bpltmon    proc    near        ; Mono plot(x,y). x is in si, y is in di
  3960.     jmp    pltmon        ; a dummy for the present
  3961. bpltmon    endp
  3962.  
  3963. pincym    proc    near            ; Monochrome inc y
  3964.     add    di,linelen        ; includes sign
  3965.     ret
  3966. pincym    endp
  3967.  
  3968. ; GPUTC - a routine to send text characters from font to true graphics boards
  3969. ; such as EGA, Hercules or CGA. Char is in al. Drawing routine ptr is gcplot.
  3970.      
  3971. gputc    proc    near
  3972.     cmp    al,' '            ; control character or space?
  3973.     ja    gputc2            ; a = no, display the char
  3974.     je    gputc1            ; e = space char
  3975.     jmp    putctrl            ; else handle controls at putctrl
  3976. gputc1:    cmp    spcontrol,0        ; non-destructive space?
  3977.     jne    gputc2            ; ne = no, do actual writing
  3978.     cmp    chcontrol,0        ; write transparently?
  3979.     jne    gputc2            ; ne = no, opaque, draw the char
  3980.     call    testfull        ; check on full screen
  3981.     jmp    incx            ; move to next char position
  3982.  
  3983. gputc2:    push    bx            ; first save some registers
  3984.     push    cx
  3985.     push    es
  3986.     push    di
  3987.      mov    bl,al            ; now BL has char to be displayed
  3988.     and    bl,7fh            ; no high bits allowed here
  3989.                     ; set board mode
  3990.     mov    di,y_coord        ; get current y coord (char bottom)
  3991.     sub    di,7            ; start 7 lines higher
  3992.     jnc    gputc3            ; nc = ok
  3993.     xor    di,di            ; move up to first line
  3994.     mov    y_coord,7        ; and reset scan line indicator
  3995. gputc3:    call    psetup    ; enter with di=line number, sets es:di to start of
  3996.             ; line in regen buffer and sets byte-wide plot mode
  3997.     mov    si,x_coord        ; si has x-axis in PC screen coord
  3998.     xor    bh,bh
  3999.     sub    bx,32            ; characters in font start at 32
  4000.     shl    bx,1
  4001.     shl    bx,1            ; 8 bytes per char, hence * 8
  4002.     shl    bx,1
  4003.     mov    cx,8            ; 8 bytes (scan lines) to transfer
  4004.     call    gcplot            ; call character plot routine
  4005.     call    incx            ; move to next char position
  4006.     pop    di
  4007.     pop    es
  4008.     pop    cx
  4009.     pop    bx
  4010.     ret
  4011. gputc    endp
  4012.  
  4013. putctrl    proc    near            ; CONTROL CHARS = cursor movement
  4014.     cmp    al,FF            ; formfeed?
  4015.      jne    putct0            ; ne = no
  4016.     jmp    TEKCLS            ; FF clears the screen
  4017.  
  4018. putct0:    cmp    al,BS            ; BS? sends (logical) cursor back one
  4019.     jne    putct2            ; ne = no, try next
  4020.     sub    x_coord,8        ; delete 8 dots (move left)
  4021.     jnc    putct1            ; nc = ok
  4022.     mov    x_coord,0        ; limit to left margin
  4023. putct1:    cmp    bscontrol,0        ; non-destructive backspace?
  4024.     je    putctx            ; e = yes
  4025.     push    x_coord            ; destructive backspace
  4026.     mov    al,spcontrol        ; save this
  4027.     push    ax
  4028.     mov    spcontrol,1        ; destructive space
  4029.     mov    al,' '            ; a space to be written
  4030.     call    gputc            ; write it
  4031.     pop    ax
  4032.     mov    spcontrol,al        ; restore space control
  4033.     pop    x_coord            ; restore cursor
  4034.     ret
  4035.  
  4036. putct2:    cmp    al,TAB            ; tabs move forward one char position
  4037.     jne    putct4            ; ne = not a tab
  4038. ;;;    OR    X_COORD,7*8
  4039.     jmp    incx            ; let incx move cursor right one col
  4040.  
  4041. putct4:    cmp    al,CR            ; <CR> means go to beginning of line
  4042.     jne    putct5
  4043.     mov    x_coord,0        ; zero the x coordinate
  4044.     ret
  4045.  
  4046. putct5:    cmp    al,LF            ; <LF> means go down 8 pixels (1 line)
  4047.     jne    putct7            ; ne = not LF
  4048.     add    y_coord,8        ; border managed by outscrn and incx
  4049.     ret
  4050.  
  4051. putct7:    cmp    al,VT            ; <VT> move up screen 1 line (8 pixels)
  4052.     jne    putctx
  4053.     sub    y_coord,8        ; subtract one line (8 pixels)
  4054.     jnc    putctx            ; nc = space left
  4055.     mov    y_coord,8        ; else set to top of screen
  4056. putctx:    ret
  4057. putctrl    endp
  4058.  
  4059. mputc    proc    near            ; MONO put char in AL via Bios
  4060.     push    bx            ; updates x_coord,y_coord with
  4061.     push    cx            ; new cursor position
  4062.     push    dx
  4063.     xor    ah,ah            ; marker for cursor setting not needed
  4064.     cmp    al,' '            ; control code?
  4065.     jae    mputc1            ; ae = no, printable
  4066.     call    putctrl            ; do cursor arithmetic
  4067.     mov    ah,1            ; marker to set cursor but no display
  4068.  
  4069. mputc1:    push    ax            ; save char and marker
  4070.     mov    cl,3            ; char cell is 8 x 8 dots
  4071.     mov    ax,x_coord        ; get resulting cursor PC positions
  4072.     shr    ax,cl
  4073.     mov    dl,al            ; column
  4074.     mov    ax,y_coord
  4075.     sub    ax,7            ; minus 7 dots, like other modes
  4076.     jnc    mputc2            ; nc = non-negative
  4077.     mov    ax,7            ; else start at the top
  4078.     mov    y_coord,ax        ; here too
  4079. mputc2:    shr    ax,cl
  4080.     mov    dh,al            ; row
  4081.     mov    ah,2            ; set cursor to x_coord,y_coord
  4082.     xor    bh,bh            ; page 0
  4083.     int    screen
  4084.     pop    ax
  4085.     or    ah,ah            ; write a char in al?
  4086.     jnz    mputcx            ; nz = no
  4087.     mov    ah,09h            ; write char at cursor postion
  4088.     mov    cx,1            ; just one char
  4089.     xor    bh,bh            ; page 0
  4090.     mov    bl,gfcol        ; foreground coloring
  4091.     int    screen
  4092.     inc    dl            ; next column
  4093.     mov    ah,2            ; set real cursor ahead of last char
  4094.     int    screen
  4095.     call    incx            ; move logical cursor
  4096. mputcx:    pop    dx
  4097.     pop    cx
  4098.     pop    bx
  4099.     ret
  4100. mputc    endp
  4101.  
  4102. incx    proc    near            ; move the logical cursor right
  4103.     mov    ax,xmax
  4104.     add    ax,8            ; last column+1
  4105.     cmp    ax,x_coord        ; beyond right most column?
  4106.     jae    incx1            ; ae = no
  4107.     mov    x_coord,ax        ; set up for wrap
  4108.     ret
  4109. incx1:    add    x_coord,8        ; shift the (logical) cursor right
  4110.     ret                ;  one character cell
  4111. incx    endp
  4112.  
  4113. ; Character plot routine. Enter with bx pointing at font array for char
  4114. ; cx = number of bytes in char font, es:di = screen memory. Worker for gputc.
  4115. ; ccode: pixbak=plot in backgrd colors, pixfor=foregrd, pixxor=xor with screen
  4116. gcplot    proc    near
  4117.     mov    al,ccode        ; save original ccode and fill pattern
  4118.     mov    ah,fill
  4119.     push    ax
  4120.     or    bx,bx            ; dealing with "space"?
  4121.     jnz    gcplot1            ; nz = no
  4122.     cmp    spcontrol,0        ; transparent space?
  4123.     jne    gcplot2            ; ne = no, do destructive space
  4124. gcplot1:cmp    chcontrol,0        ; transparent char writing?
  4125.     je    gcplot3            ; e = yes
  4126. gcplot2:mov    ccode,pixfor+pixbak    ; write both fore and back ground
  4127. gcplot3:mov    al,font[bx]        ; EGA byte plot: get bits from font
  4128.     push    bx
  4129.     push    cx
  4130.     mov    cx,si            ; x-axis in PC screen coordinates
  4131.     and    cx,7            ; bit in byte across the screen
  4132.     ror    al,cl            ; rotate pattern for gfplot filling
  4133.     mov    cx,8            ; do 8 bits on the line
  4134.     mov    fill,al            ; use "fill" as fill pattern
  4135.     call    gfplot            ; fill a scan line for cx bits
  4136.     call    pincy            ; next scan line (linelen is preset)
  4137.     pop    cx
  4138.     pop    bx
  4139.     inc    bx            ; next byte of char pattern
  4140.     loop    gcplot1
  4141.     pop    ax
  4142.     mov    ccode,al        ; recover variables
  4143.     mov    fill,ah
  4144.     ret
  4145. gcplot    endp
  4146.  
  4147. ; routines to manipulate ega graphics controller and mode register
  4148. ; command code in al, value in ah - destroys al and dx
  4149.      
  4150. ega_gc    proc    near            ; ega graphics controller
  4151.     mov    dx,3ceh
  4152.     out    dx,al            ; output command code
  4153.     inc    dx            ; dx is now data port
  4154.     mov    al,ah            ; get value to al
  4155.     out    dx,al            ; output value
  4156.     ret
  4157. ega_gc    endp
  4158. ega_md    proc    near            ; ega mode controller
  4159.     mov    dx,3c4h
  4160.     out    dx,al            ; output command code
  4161.     inc    dx            ; dx is now data port
  4162.     mov    al,ah            ; get value to al
  4163.     out    dx,al            ; output value
  4164.     ret
  4165. ega_md endp
  4166.      
  4167. ; Plot eight pixels using an EGA board
  4168. ; Enter with ES:[DI] pointing to screen address of byte,
  4169. ; bh has pattern of bits to be set, bl has attributes:
  4170. ;  pixbak = draw in background color, pixfor = draw in foreground color,
  4171. ;  pixor = OR with foreground color, pixxor = XOR with foreground color.
  4172. ; registers preserved
  4173. ; Note: this function operates on 8 pixels. One bits in bh select pixels to
  4174. ; be changed, bl determines which color planes will be affected for every
  4175. ; selected pixel.
  4176. ega_plt proc    near
  4177.     push    ax
  4178.     push    dx
  4179.     mov    dx,3ceh            ; (ega_gc) unprotect the bit positions
  4180.     mov    al,8            ; command to set bit mask register
  4181.     out    dx,al            ; output command code
  4182.     inc    dx            ; dx is now data port
  4183.     mov    al,bh            ; get pixels to be modified (1's)
  4184.     out    dx,al            ; output value (end of ega_gc)
  4185.     pop    dx
  4186.  
  4187.     mov    ah,gfcol        ; foreground color bit planes
  4188. ega1:    test    bl,pixfor+pixor        ; write foreground or OR?
  4189.     jnz    ega3            ; nz = yes
  4190.     mov    ah,gbcol        ; background color bit planes
  4191.     test    bl,pixbak        ; write in background coloring?
  4192.     jnz    ega3            ; nz = yes
  4193.     mov    ah,0fh            ; xor, touch each bit plane
  4194. ega3:    mov    al,es:[di]        ; latch byte
  4195.     mov    es:[di],ah        ; merge with untouched bits
  4196.     pop    ax
  4197.     ret
  4198. ega_plt endp
  4199.  
  4200. ; Presence test for Wyse-700: info in B000h and B800h are supposed to be equal
  4201. chkwyse    proc    near
  4202.     push    es
  4203.     push    ds
  4204.     mov    ax,0b800h        ; CGA segment
  4205.     mov    es,ax
  4206.     mov    ax,0b000h        ; Mono segment
  4207.     mov    ds,ax
  4208.     mov    ch,byte ptr es:[0]    ; CGA seg
  4209.     mov    cl,byte ptr ds:[0]    ; Mono seg
  4210.     push    cx            ; save original contents
  4211.     mov    byte ptr ds:[0],ch    ; copy CGA to Mono
  4212.     cmp    byte ptr ds:[0],ch    ; if different then not Wyse
  4213.     jne    chkwys1            ; ne = not Wyse
  4214.     not    byte ptr es:[0]        ; change CGA contents
  4215.     not    ch            ; and original pattern
  4216.     cmp    ch,byte ptr ds:[0]    ; if different then not Wyse
  4217.     jne    chkwys1            ; ne = not Wyse
  4218.     pop    cx
  4219.     mov    byte ptr es:[0],ch    ; restore CGA
  4220.     mov    byte ptr ds:[0],cl    ; restore Mono
  4221.     pop    ds
  4222.     pop    es
  4223.     clc
  4224.     ret
  4225.  
  4226. chkwys1:pop    cx
  4227.     mov    byte ptr es:[0],ch    ; restore CGA
  4228.     mov    byte ptr ds:[0],cl    ; restore Mono
  4229.     pop    ds
  4230.     pop    es
  4231.     stc
  4232.     ret
  4233. chkwyse    endp
  4234. ;
  4235. ; routine to set Wyse-700 board to graphics mode - 1280 * 800 & cls
  4236. ;
  4237. WYGRAF    PROC    NEAR
  4238.     push    ax
  4239.     push    bx            ; save used registers
  4240.     push    cx
  4241.     push    dx
  4242.     push    di
  4243.     xor    al,al
  4244.     mov    dx,wystoff        ; map video memory offset to zero
  4245.     out    dx,al            ;
  4246.     mov    dx,wystseg        ; map video memory segment to zero
  4247.     out    dx,al            ;
  4248.     mov    ax,segwyse        ; set es to Wyse start segment
  4249.     mov    es,ax            ;
  4250.     mov    al,wybeven        ; graph mode - even bank
  4251.     mov    dx,wymode        ; Wyse mode control register
  4252.     out    dx,al            ; select even bank
  4253.     cld
  4254.     xor    ax,ax            ; zero ax
  4255.     xor    di,di            ; start from zero
  4256.     mov    cx,0ffffh        ; clear 10000h bytes, whole even bank
  4257.     rep    stosb            ; store blanking char in whole screen
  4258.     mov    al,wybodd        ; graph mode - odd bank
  4259.     mov    dx,wymode        ; select it
  4260.     out    dx,al            ;
  4261.     xor    ax,ax            ; zero ax
  4262.     xor    di,di            ;
  4263.     mov    cx,0ffffh        ; clear 10000h bytes, whole odd bank
  4264.     rep    stosb            ; store blanking char in whole screen
  4265.     mov    bnkchan, 0        ; assume bank 0
  4266.     pop    di            ; restore regs
  4267.     pop    dx
  4268.     pop    cx
  4269.     pop    bx
  4270.     pop    ax
  4271.     ret
  4272. WYGRAF    ENDP
  4273.  
  4274. ; routine to set Hercules card to graphics mode - both pages are enabled
  4275.      
  4276. HGRAF    PROC    NEAR
  4277.     push    ax
  4278.     push    bx            ; save used registers
  4279.     push    cx
  4280.     push    si
  4281.     mov    al,grph            ; graph mode
  4282.     lea    si,gtable        ;  requires graphics table
  4283.     xor    bx,bx
  4284.     mov    cx,4000h        ; clear 4000h words
  4285.     test    gbcol,7            ; any (light) background color bits?
  4286.     jz    hgraf1            ; z = no, we are ok
  4287.     dec    bx            ; light background, set all the bits
  4288. hgraf1:    call    setmd            ; and set the mode
  4289.     pop    si
  4290.     pop    cx
  4291.     pop    bx
  4292.     pop    ax
  4293.     ret
  4294. HGRAF    ENDP
  4295.      
  4296. ; set Hercules card to text mode
  4297.      
  4298. HTEXT    PROC    NEAR
  4299.     push    ax
  4300.     push    bx
  4301.     push    cx
  4302.     push    si
  4303.     mov    al,text            ; text mode
  4304.     lea    si,ttable        ; requires text table
  4305.     mov    bx,0720h        ; blank value (space, white on black)
  4306.     mov    cx,2000            ; whole screen to clear (80*25)
  4307.     call    setmd            ; set the mode
  4308.     pop    si
  4309.     pop    cx
  4310.     pop    bx
  4311.     pop    ax
  4312.     ret
  4313. HTEXT    ENDP
  4314.      
  4315. ; Hercules mode set - called from HTEXT and HGRAF
  4316.      
  4317. SETMD    PROC    NEAR
  4318.     push    dx
  4319.     push    ax
  4320.     mov    dx,config        ; configuration port
  4321.     mov    al,genable        ; allow graphics mode to be set
  4322.     out    dx,al
  4323.     pop    ax
  4324.     push    ax
  4325.     push    cx            ; save count
  4326.     mov    dx,cntrl        ; control port
  4327.     out    dx,al            ; set to text or graphics
  4328.     mov    dx,index        ; send 12 bytes from table to 6845
  4329.     mov    cx,12            ; number of registers to load
  4330.     xor    ah,ah            ; start with register 0 of 6845
  4331.     cld
  4332. setmd1:    jmp    $+2            ; small pause for hardware
  4333.     mov    al,ah            ; ah is counter
  4334.     out    dx,al            ; set register
  4335.     inc    dx            ; point to data port
  4336.     lodsb                ; get next byte in table
  4337.     jmp    $+2            ; small pause for hardware
  4338.     out    dx,al            ; and send to 6845
  4339.     inc    ah            ; next register
  4340.     dec    dx            ; point to register port
  4341.     loop    setmd1            ; and continue 'til cx=0
  4342.     pop    cx            ; recover count
  4343.     cld
  4344.     push    di
  4345.     push    es
  4346.     mov    ax,segscn        ; start of screen
  4347.     mov    es,ax
  4348.     xor    di,di
  4349.     mov    ax,bx            ; get blanking character
  4350.     rep    stosw            ; store blanking char in whole screen
  4351.     pop    es
  4352.     pop    di
  4353.     mov    dx,cntrl        ; now to re-enable screen
  4354.     pop    ax            ; get mode
  4355.     or    al,scrn_on        ; enable screen
  4356.     out    dx,al
  4357.     pop    dx
  4358.     ret
  4359. SETMD    ENDP
  4360.      
  4361. teksave    proc    near        ; saves graphics screen from page 0 to page 1
  4362.     push    si
  4363.     push    di
  4364.     cmp    gpage,0        ; only graphics page 0 on display board?
  4365.     je    teksavx        ; e = yes, no saving possible here
  4366.     mov    si,segscn    ; segment (!) of current screen
  4367.     cmp    graph_mode,ega
  4368.     je    teksav1
  4369.     cmp    graph_mode,monoega
  4370.     je    teksav1
  4371.     cmp    graph_mode,colorega
  4372.     je    teksav1
  4373.     cmp    graph_mode,hercules
  4374.     je    teksav2
  4375.     jmp    short teksavx    ; else nothing
  4376. teksav1:mov    di,segega+800h    ; EGA page 1 screen segment
  4377.     call    egasr        ; call common save/restore code
  4378.     jmp    short teksavx
  4379. teksav2:mov    di,seghga+800h    ; Hercules page 1 screen segment
  4380.     call    hgasr        ; call common save/restore code
  4381. teksavx:pop    di
  4382.     pop    si
  4383.     ret
  4384. teksave    endp
  4385.  
  4386. tekrest    proc    near        ; restores graphics screen in page 1 to page 0
  4387.     push    si
  4388.     push    di
  4389.     cmp    gpage,0        ; only graphics page 0 on display board?
  4390.      jne    tekres0        ; ne = no, more so work to do here
  4391.     call    tekcls1        ;  else clear the screen to color it
  4392.     jmp    short tekresx    ;  and exit
  4393. tekres0:mov    di,segscn    ; segment (!) of new graphics screen
  4394.     cmp    graph_mode,ega
  4395.     je    tekres1
  4396.     cmp    graph_mode,monoega
  4397.     je    tekres1
  4398.     cmp    graph_mode,colorega
  4399.     je    tekres1
  4400.     cmp    graph_mode,hercules
  4401.     je    tekres2
  4402.     jmp    short tekresx    ; else nothing
  4403. tekres1:mov    si,segega+800h    ; segment of EGA page 1
  4404.     call    egasr        ; call common save/restore code
  4405.     jmp    short tekresx
  4406. tekres2:mov    si,seghga+800h    ; segment of Hercules page 1
  4407.     call    hgasr        ; call common save/restore code
  4408. tekresx:pop    di
  4409.     pop    si
  4410.     ret
  4411. tekrest    endp
  4412.  
  4413. egasr    proc    near        ; common code for Tek ega save/restore ops
  4414.     push    ax
  4415.     push    cx
  4416.     push    dx
  4417.     mov    ax,0f00h    ; enable 4 plane set/resets
  4418.     call    ega_gc        ; set controller
  4419.     mov    ax,0f01h    ; enable Set/Reset register
  4420.     call    ega_gc
  4421.     mov    ax,0f02h    ; set color compare register for 4 planes
  4422.     call    ega_gc
  4423.     mov    ax,0905h    ; set mode reg: write latches, read mode
  4424.     call    ega_gc
  4425.     mov    ax,0ff02h    ; enable all planes
  4426.     call    ega_md
  4427.     mov    cx,ybot        ; last scan line
  4428.     inc    cx        ; number of scan lines
  4429.     mov    ax,80        ; bytes per scan line
  4430.     mul    cx
  4431.     mov    cx,ax
  4432.     push    es        ; save es
  4433.     push    ds        ; save ds
  4434.     mov    es,di        ; destination, set es to video memory
  4435.     mov    ds,si        ; source, set ds to video memory
  4436.     xor    si,si        ; clear offset fields
  4437.     xor    di,di
  4438.     cld            ; byte moves for ega adaptor
  4439.     rep    movsb        ; copy from page (ds:si) to page (es:di)
  4440.     pop    ds        ; recover ds
  4441.     pop    es        ; and other registers
  4442.     xor    ax,ax        ; disable 4 plane set/resets
  4443.     call    ega_gc        ; set controller
  4444.     mov    ax,0001h    ; disable Set/Reset register
  4445.     call    ega_gc        ; set controller
  4446.     mov    ax,0002h    ; disable color compare register
  4447.     call    ega_gc
  4448.     mov    ax,1005h    ; set mode reg: write latches, odd/even
  4449.     call    ega_gc
  4450.     pop    dx
  4451.     pop    cx
  4452.     pop    ax
  4453.     ret
  4454. egasr    endp
  4455.  
  4456. hgasr    proc    near        ; Hercules save restore screen
  4457.     push    cx
  4458.     mov    cx,4000h    ; number of words to move
  4459.     push    es        ; save es
  4460.     push    ds        ; save ds
  4461.     mov    es,di        ; destination, set es to video memory
  4462.     mov    ds,si        ; source, set ds to video memory
  4463.     xor    si,si        ; clear offset fields
  4464.     xor    di,di
  4465.     cld
  4466.     rep    movsw        ; copy from page [si] to page [di]
  4467.     pop    ds        ; recover ds
  4468.     pop    es        ; and other registers
  4469.     pop    cx
  4470.     ret
  4471. hgasr    endp
  4472.  
  4473. dump    proc    FAR            ; Write screen as TIFF v5.0 file
  4474.     push    ax
  4475.     push    bx
  4476.     push    cx
  4477.     push    dx
  4478.     push    si
  4479.     push    di
  4480.     call    remcursor        ; remove the cursor from the screen
  4481.     mov    si,offset dumpname    ; name of dump file
  4482.     mov    di,offset tempname    ; destination
  4483.     push    es
  4484.     push    ds
  4485.     pop    es
  4486.     mov    cx,dumplen        ; length of dump name
  4487.     cld
  4488.     repnz    movsb            ; copy it, asciiz
  4489.     pop    es
  4490.     mov    ax,offset tempname    ; address to ax for unique
  4491.     call    tunique            ; get unique name into ax
  4492.     mov    dx,ax            ; ds:dx is asciiz filename
  4493.     xor    cx,cx            ; normal attributes
  4494.     mov    ah,creat2        ; create the file
  4495.     int    dos
  4496.     jc    dmp2            ; c = failure
  4497. dmp1:    mov    dhandle,ax        ; file handle
  4498.     call    dmpdate            ; do time stamp
  4499.     cmp    plotptr,offset pltcga    ; using CGA style graphics?
  4500.     jne    dmp2            ; ne = no
  4501.     call    cgadmp            ; do CGA style dump routine
  4502.     jmp    short dmp3
  4503. dmp2:    call    egadmp
  4504. dmp3:    mov    cursorst,1        ; pretend cursor was on
  4505.     call    remcursor        ; restore the cursor to the screen
  4506.     mov    cursorst,1        ; say it is on
  4507.     pop    di
  4508.     pop    si
  4509.     pop    dx
  4510.     pop    cx
  4511.     pop    bx
  4512.     pop    ax
  4513.     ret
  4514. dump    endp
  4515.  
  4516. ; CGA TIFF 5.0 screen-to-file dump routine
  4517. cgadmp    proc    near
  4518.     push    es            ; do the bookkeeping math first
  4519.     mov    bps.entval,1        ; bits/sample, mono
  4520.     mov    photo.entval,1        ; mono, one bit after the other
  4521.     mov    word ptr cmap.entcnt,0    ; no palette color map entries
  4522.     mov    ax,xmax            ; image width - 8 pixels
  4523.     add    ax,8            ; plus 8, for pixels per line
  4524.     mov    iwidth.entval,ax    ; store in directory
  4525.     mov    xresval,ax        ; x resolution
  4526.     mov    xresval+2,0        ; high order part
  4527.     mov    ax,ybot            ; lines per screen - 1
  4528.     inc    ax            ; lines per screen
  4529.     mov    ilength.entval,ax    ; image length, scan lines
  4530.     mov    yresval,ax        ; y resolution
  4531.     mov    yresval+2,0        ; high order part
  4532.     mov    cx,25            ; try dividing into this many strips
  4533. cgadmp5:xor    dx,dx            ; image pixels
  4534.     mov    ax,yresval        ; number of scan lines
  4535.     div    cx            ; try dividing into 25 strips,ax=quo
  4536.     or    dx,dx            ; did we get null remainder?
  4537.     loopnz    cgadmp5            ; nz = no, try again with fewer strips
  4538.     inc    cx            ; inc for dec by loop, cx = # strips
  4539.     mov    word ptr strip.entcnt,cx ; store number of strips
  4540.     mov    word ptr sbc.entcnt,cx    ; store number of strip byte counts
  4541.     mov    rps.entval,ax        ; rows per strip
  4542.     push    cx
  4543.     mov    cx,iwidth.entval    ; dots per line (row)
  4544.     shr    cx,1            ; get bytes/row
  4545.     shr    cx,1
  4546.     shr    cx,1
  4547.     mul    cx            ; rows/strip * bytes/row = bytes/strip
  4548.     pop    cx
  4549.     push    cx            ; save strip count for loop below
  4550.     push    ds            ; ax = bytes per strip
  4551.     pop    es            ; es:di to our data segment
  4552.     mov    di,offset stripbc    ; where to write strip byte counts
  4553.     cld
  4554.     rep    stosw            ; write ax as bytes/strip, cx times
  4555.     pop    cx            
  4556.     mov    dx,ax            ; bytes/strip = increment, put here
  4557.     mov    di,offset stripoff    ; where we write
  4558.     mov    ax,offset pixdata-offset header ; where first strip starts
  4559. cgadmp4:stosw                ; write strip file offset
  4560.     mov    word ptr [di],0        ; high order part
  4561.     add    di,2            ; next double word
  4562.     add    ax,dx            ; next file strip offset
  4563.     loop    cgadmp4            ; do all strip offsets
  4564.                     ; file i/o starts here
  4565.     mov    bx,dhandle        ; dump's file handle
  4566.     mov    dx,offset header    ; write TIFF header and directory
  4567.     mov    cx,tifflen        ; length of header plus directory
  4568.     mov    ah,write2
  4569.     int    dos
  4570.     jc    cgadmp2            ; c = failure
  4571.     xor    di,di            ; start at y = top
  4572.     call    psetup            ; setup cga and di
  4573.     mov    cx,ybot            ; number of scan lines-1
  4574.     inc    cx            ; number of scan lines
  4575. cgadmp1:push    cx
  4576.     mov    cx,iwidth.entval    ; dots per line (row)
  4577.     shr    cx,1            ; get bytes/row
  4578.     shr    cx,1
  4579.     shr    cx,1            ; line length, bytes
  4580.     mov    dx,di            ; offset in screen buffer
  4581.     mov    bx,dhandle        ; file handle
  4582.     push    ds
  4583.     mov    ax,segscn        ; screen seg
  4584.     mov    ds,ax
  4585.     mov    ah,write2        ; write directly from screen memory
  4586.     int    dos
  4587.     pop    ds
  4588.     jc    cgadmp2            ; c = failure
  4589.     call    pincy            ; next line down, y = y + 1
  4590.     pop    cx
  4591.     loop    cgadmp1            ; do all scan lines
  4592. cgadmp2:mov    ah,close2        ; close the file
  4593.     int    dos
  4594.     mov    dhandle,-1        ; set handle to unused
  4595.     pop    es
  4596.     ret
  4597. cgadmp    endp
  4598.  
  4599. ; EGA TIFF 5.0 screen-to-file dump routine
  4600. egadmp    proc    near
  4601.     push    es            ; do the bookkeeping math first
  4602.     mov    bps.entval,4        ; bits/sample, iRGB
  4603.     mov    photo.entval,3        ; photo interp, palette
  4604.     mov    word ptr cmap.entcnt,3*16 ; palette color map entries
  4605.     mov    ax,xmax            ; image width - 8 pixels
  4606.     add    ax,8            ; plus 8, for pixels per line
  4607.     mov    iwidth.entval,ax    ; store in directory
  4608.     mov    xresval,ax        ; x resolution
  4609.     mov    xresval+2,0        ; high order part
  4610.     mov    ax,ybot            ; lines per screen - 1
  4611.     inc    ax            ; lines per screen
  4612.     mov    ilength.entval,ax    ; image length, scan lines
  4613.     mov    yresval,ax        ; y resolution
  4614.     mov    yresval+2,0        ; high order part
  4615.     mov    cx,25            ; try dividing into this many strips
  4616. egadmp10:xor    dx,dx            ; image pixels
  4617.     mov    ax,yresval        ; number of scan lines
  4618.     div    cx            ; try dividing into 25 strips, ax=quo
  4619.     or    dx,dx            ; did we get null remainder?
  4620.     loopnz    egadmp10        ; nz = no, try again with fewer strips
  4621.     inc    cx            ; inc for dec by loop, cx = # strips
  4622.     mov    word ptr strip.entcnt,cx ; store number of strips
  4623.     mov    word ptr sbc.entcnt,cx    ; store number of strip byte counts
  4624.     mov    rps.entval,ax        ; rows per strip
  4625.     shl    ax,1
  4626.     shl    ax,1            ; times 4 bits / pixel
  4627.     push    cx
  4628.     mov    cx,iwidth.entval    ; dots per line (row)
  4629.     shr    cx,1            ; get bytes/row
  4630.     shr    cx,1
  4631.     shr    cx,1
  4632.     mul    cx            ; rows/strip * bytes/row = bytes/strip
  4633.     pop    cx
  4634.     push    cx            ; save strip count for loop below
  4635.     push    ds            ; ax = bytes per strip
  4636.     pop    es            ; es:di to our data segment
  4637.     mov    di,offset stripbc    ; where to write strip byte counts
  4638.     cld
  4639.     rep    stosw            ; write ax as bytes/strip, cx times
  4640.     pop    cx            
  4641.     mov    dx,ax            ; bytes/strip = increment, put here
  4642.     mov    di,offset stripoff    ; where we write
  4643.     mov    ax,offset pixdata-offset header ; where first strip starts
  4644.     xor    bx,bx
  4645. egadmp11:stosw                ; write strip file offset
  4646.     mov    es:[di],bx        ; high order part
  4647.     add    di,2            ; next double word
  4648.     add    ax,dx            ; next file strip offset
  4649.     adc    bx,0
  4650.     loop    egadmp11        ; do all strip offsets
  4651.                     ; screen to file i/o starts here
  4652.     mov    bx,dhandle        ; dump's file handle
  4653.     mov    dx,offset header    ; write TIFF header and directory
  4654.     mov    cx,tifflen        ; length of header plus directory
  4655.     mov    ah,write2
  4656.     int    dos
  4657.     jnc    egadmp12
  4658.     jmp    egadmp9            ; c = failure
  4659. egadmp12:
  4660.     xor    di,di            ; start at y = top
  4661.     call    psetup            ; setup adapter and es:di
  4662.     xor    di,di
  4663.     mov    bx,offset tempname    ; set buffer address
  4664.     mov    cx,ybot            ; number of scan lines-1
  4665.     inc    cx            ; number of scan lines
  4666. egadmp1:push    cx            ; save scan line counter
  4667.     mov    cx,iwidth.entval    ; dots per line (row)
  4668.     shr    cx,1            ; get bytes/row
  4669.     shr    cx,1
  4670.     shr    cx,1            ; 8*dots across the screen (640)
  4671. egadmp2:push    cx            ; save counter of inner loops
  4672.     mov    cx,4            ; number of planes to do
  4673.     mov    word ptr [bx],0        ; clear the four bytes for this loop
  4674.     mov    word ptr [bx+2],0
  4675. egadmp3:push    cx            ; save plane counter
  4676.     push    bx            ; don't advance buffer pointer here
  4677.     mov    dx,3ceh            ; (ega_gc)
  4678.     mov    al,4            ; command to select read map register
  4679.     out    dx,al            ; output command code
  4680.     inc    dx            ; dx is now data port
  4681.     mov    al,cl            ; do planes 3(I), then 2(R),1(G),0(B)
  4682.     dec    al            ; cx is one higher than plane
  4683.     out    dx,al            ; output value (end of ega_gc)
  4684.     mov    al,es:[di]        ; latch byte
  4685.                     ; got 8 bits from a plane
  4686.     mov    cx,4            ; do this for four output bytes
  4687. egadmp4:mov    ah,[bx]            ; eventually iRGB in each nibble
  4688.     shl    al,1            ; get left most pixel bit in plane
  4689.     jnc    egadmp5
  4690.     or    ah,8            ; set high nibble least sig bit
  4691. egadmp5:shl    al,1            ; odd numbered pixel
  4692.      rcl    ah,1            ; set low nibble least sig bit if c
  4693.     mov    [bx],ah
  4694.     inc    bx            ; next byte
  4695.     loop    egadmp4            ; do all four bytes
  4696.  
  4697.     pop    bx
  4698.     pop    cx            ; restore plane counter
  4699.     loop    egadmp3            ; do all planes
  4700.  
  4701.     inc    di            ; next screen memory address
  4702.     add    bx,4            ; just did four bytes
  4703.     cmp    bx,offset tempname+80    ; at end of 80 bytes?
  4704.     jb    egadmp6            ; b = no
  4705.     call    egadmpw            ; write the buffer
  4706.     mov    bx,offset tempname    ; reset buffer address
  4707.     jnc    egadmp6            ; nc = success
  4708.     pop    cx            ; clean stack
  4709.     pop    cx
  4710.     jmp    egadmp9            ; error
  4711.  
  4712. egadmp6:pop    cx            ; recover bytes per line counter
  4713.     loop    egadmp2            ; next group across scan line
  4714.     pop    cx            ; recover scan line counter
  4715.     loop    egadmp1            ; do next scan line
  4716.     call    egadmpw            ; flush the buffer for last scan line
  4717. egadmp9:mov    ah,close2        ; close the file
  4718.     mov    bx,dhandle
  4719.     int    dos
  4720.     mov    dhandle,-1        ; set handle to unused
  4721.     xor    di,di
  4722.     call    psetup
  4723.     pop    es
  4724.     ret
  4725.                        ; local worker
  4726. egadmpw:push    bx            ; write tempbuf from start to [bx-1]
  4727.     push    cx
  4728.     mov    dx,offset tempname    ; work buffer
  4729.     mov    cx,bx            ; buffer pointer to next free byte
  4730.     sub    cx,dx            ; buffer size to write
  4731.     cmp    cx,0
  4732.     jle    egadmpw1        ; le = nothing to write
  4733.     mov    bx,dhandle        ; file handle
  4734.     mov    ah,write2        ; write cx bytes from tempname
  4735.     int    dos
  4736.     jc    egadmpw2        ; c = error
  4737.     cmp    ax,cx            ; wrote all?
  4738.     jne    egadmpw2        ; ne = no
  4739. egadmpw1:clc                ; clc
  4740.     pop    cx
  4741.     pop    bx
  4742.     ret
  4743. egadmpw2:stc                ; carry set for failure
  4744.     pop    cx
  4745.     pop    bx
  4746.     ret
  4747.  
  4748. egadmp    endp
  4749.  
  4750. ; Worker. Write Kermit version and current date and time in TIFF header
  4751. dmpdate    proc    near
  4752.     mov    di,offset prog+10    ; place for version in prog field
  4753.     mov    ax,version        ; Kermit version
  4754.     call    dec2di            ; write the version
  4755.     mov    ah,getdate        ; DOS date (cx= yyyy, dh= mm, dl= dd)
  4756.     int    dos
  4757.     mov    di,offset dandt        ; where to write
  4758.     mov    ax,cx            ; get yyyy
  4759.     push    dx
  4760.     call    dec2di            ; write to buffer
  4761.     pop    dx
  4762.     mov    byte ptr [di],':'
  4763.     inc    di
  4764.     mov    al,dh            ; mm
  4765.     cmp    al,10            ; leading digit?
  4766.     jae    dmpdat1            ; ae = yes
  4767.     mov    byte ptr [di],'0'    ; make our own
  4768.     inc    di
  4769. dmpdat1:xor    ah,ah
  4770.     push    dx
  4771.     call    dec2di
  4772.     mov    byte ptr [di],':'
  4773.     pop    dx
  4774.     inc    di
  4775.     mov    al,dl            ; dd
  4776.     cmp    al,10            ; leading digit?
  4777.     jae    dmpdat2            ; ae = yes
  4778.     mov    byte ptr [di],'0'    ; make our own
  4779.     inc    di
  4780. dmpdat2:xor    ah,ah
  4781.     call    dec2di
  4782.     mov    byte ptr [di],' '
  4783.     inc    di
  4784.     mov    ah,gettim        ; DOS tod (ch=hh, cl=mm, dh=ss, dl=.s)
  4785.     int    dos
  4786.     push    dx            ; save dx
  4787.     xor    ah,ah
  4788.     mov    al,ch            ; Hours
  4789.     cmp    al,10            ; leading digit?
  4790.     jae    dmpdat3            ; ae = yes
  4791.     mov    byte ptr [di],'0'    ; make our own
  4792.     inc    di
  4793. dmpdat3:push    cx
  4794.     call    dec2di            ; write decimal asciiz to buffer
  4795.     pop    cx
  4796.     mov    byte ptr [di],':'
  4797.     inc    di
  4798.     xor    ah,ah
  4799.     mov    al,cl            ; Minutes
  4800.     cmp    al,10            ; leading digit?
  4801.     jae    dmpdat4            ; ae = yes
  4802.     mov    byte ptr [di],'0'    ; make our own
  4803.     inc    di
  4804. dmpdat4:call    dec2di            ; write decimal asciiz to buffer
  4805.     mov    byte ptr [di],':'
  4806.     inc    di
  4807.     pop    dx
  4808.     xor    ah,ah
  4809.     mov    al,dh            ; Seconds
  4810.     cmp    al,10            ; leading digit?
  4811.     jae    dmpdat5            ; ae = yes
  4812.     mov    byte ptr [di],'0'    ; make our own
  4813.     inc    di
  4814. dmpdat5:call    dec2di            ; write decimal asciiz to buffer
  4815.     inc    di
  4816.     ret
  4817. dmpdate    endp
  4818.  
  4819. ; Dispatch table processor. Enter with BX pointing at table of {char count,
  4820. ; address of action routines, characters}. Jump to matching routine or return.
  4821. ; Enter with AL holding received Final char.
  4822. atdispat proc near
  4823.     mov    cl,[bx]            ; get table length from first byte
  4824.     xor    ch,ch
  4825.     mov    di,bx            ; main table
  4826.     add    di,3            ; point di at first char in table
  4827.     push    es
  4828.     push    ds
  4829.     pop    es            ; use data segment for es:di below
  4830.     cld                ; set direction forward
  4831.     repne    scasb            ; find matching character
  4832.     pop    es
  4833.     je    atdisp2            ; e = found a match, get action addr
  4834.     cmp    al,' '            ; control char?
  4835.     jb    atdisp1            ; b = yes
  4836.     ret                ; ignore escape sequence
  4837. atdisp1:jmp    tekctl            ; process control char
  4838. atdisp2:sub    di,bx            ; distance scanned in table
  4839.     sub    di,4            ; skip count byte, address word, inc
  4840.     shl    di,1            ; convert to word index
  4841.     inc    bx            ; point to address of action routines
  4842.     mov    bx,[bx]            ; get address of action table
  4843.     jmp    word ptr [bx+di]    ; dispatch to the routine
  4844. atdispat endp
  4845.  
  4846. ansich    proc    near            ; insert Pn spaces at and after cursor
  4847.     mov    cx,param        ; get Pn
  4848.     or    cx,cx
  4849.     jnz    ansich1            ; got a value
  4850.     inc    cx            ; zero means one
  4851. ansich1:push    x_coord
  4852.     push    y_coord
  4853.     mov    al,spcontrol        ; preserve space control
  4854.     mov    tempname,al        ; save here
  4855.     mov    spcontrol,1        ; turn on destructive space
  4856.     and    x_coord,not 7        ; modulo 8x8 cells
  4857.     mov    ax,xmax            ; start of last cell
  4858.     sub    ax,x_coord        ; start of current cell
  4859.     shr    ax,1            ; divide by 8 dots per char
  4860.     shr    ax,1
  4861.     shr    ax,1
  4862.     cmp    ax,cx            ; want more spaces than are on line?
  4863.     jae    ansich2            ; ae = no
  4864.     mov    cx,ax            ; clip to right margin
  4865.     jcxz    ansich3            ; z = nothing to do
  4866. ansich2:push    cx
  4867.     mov    al,' '            ; a space
  4868.     call    outscrn            ; write to screen
  4869.     pop    cx
  4870.     loop    ansich2            ; do them
  4871. ansich3:mov    al,tempname        ; space control
  4872.     mov    spcontrol,al        ; restored
  4873.     pop    x_coord
  4874.     pop    y_coord
  4875.     call    remcursor        ; remove text cursor symbol
  4876.     call    setcursor        ; draw cursor at new location
  4877.     ret
  4878. ansich    endp
  4879.                     ; scaled by text screen height
  4880. atcuu    proc    near            ; cursor up Pn lines
  4881.     cmp    param,0            ; empty arg?
  4882.     jne    atcuu1            ; got a value
  4883.     inc    param            ; zero means one
  4884. atcuu1:    mov    ax,y_coord        ; where we are now
  4885.     add    ax,4            ; round up a smidge
  4886.     mov    cl,byte ptr low_rgt+1    ; highest text line
  4887.     xor    ch,ch
  4888.     mul    cx            ; proportion
  4889.     xor    dx,dx
  4890.     mov    cx,ybot            ; highest scan line
  4891.     div    cx            ; end, estimate currren text line
  4892.     sub    ax,param
  4893.     inc    ax            ; count lines from 1 again
  4894.     mov    param,ax        ; new text row
  4895.     jmp    atcva            ; do as absolute
  4896. atcuu    endp
  4897.  
  4898.                     ; scaled by text screen height
  4899. atcud    proc    near            ; cursor down Pn lines
  4900.     cmp    param,0            ; get Pn
  4901.     jne    atcud1            ; ne = got a value
  4902.     inc    param            ; zero means one
  4903. atcud1:    mov    ax,y_coord        ; where we are now
  4904.     add    ax,4            ; round up a smidge
  4905.     mov    cl,byte ptr low_rgt+1    ; highest text line
  4906.     xor    ch,ch
  4907.     mul    cx            ; proportion
  4908.     xor    dx,dx
  4909.     mov    cx,ybot            ; highest scan line
  4910.     div    cx            ; end, estimate currren text line
  4911.     inc    ax            ; count lines from 1 again
  4912.     add    param,ax        ; new text row
  4913.     jmp    atcva            ; do as absolute
  4914. atcud    endp
  4915.  
  4916. atcuf    proc    near            ; cursor forward Pn columns
  4917.     mov    ax,param        ; get Pn
  4918.     or    ax,ax
  4919.     jnz    atcuf1            ; got a value
  4920.     inc    ax            ; zero means one
  4921. atcuf1:    shl    ax,1            ; times 8 dots per char cell
  4922.     shl    ax,1
  4923.     shl    ax,1            ; Tek columns worth
  4924.     and    x_coord,not 7        ; modulo 8x8 cells
  4925.     add    x_coord,ax        ; forward to absolute column
  4926.     mov    ax,xmax
  4927.     cmp    x_coord,ax        ; beyond right most cell?
  4928.     jbe    atcuf2            ; be = no
  4929.     mov    x_coord,ax        ; limit to right
  4930. atcuf2:    call    remcursor        ; remove text cursor symbol
  4931.     call    setcursor        ; draw cursor at new location
  4932.     ret
  4933. atcuf    endp
  4934.  
  4935. atcub    proc    near            ; cursor left/back Pn columns
  4936.     mov    ax,param        ; get Pn
  4937.     or    ax,ax
  4938.     jnz    atcub1            ; got a value
  4939.     inc    ax            ; zero means one
  4940. atcub1:    shl    ax,1
  4941.     shl    ax,1
  4942.     shl    ax,1            ; times 8 dots per cell
  4943.     and    x_coord,not 7        ; modulo 8x8 cells
  4944.     mov    cx,xmax
  4945.     cmp    x_coord,cx        ; beyond last col (wrap pending)?
  4946.     jbe    atcub3            ; be = no
  4947.     mov    x_coord,cx        ; set to last col
  4948. atcub3:    sub    x_coord,ax        ; back up
  4949.     jnc    atcub2            ; nc = ok
  4950.     mov    x_coord,0        ; stop in column zero
  4951. atcub2:    call    remcursor        ; remove text cursor symbol
  4952.     call    setcursor        ; draw cursor at new location
  4953.     ret
  4954. atcub    endp
  4955.  
  4956. atcnl    proc    near            ; do Pn cr/lf's
  4957.     mov    x_coord,0        ; to left margin
  4958.     jmp    atcud            ; do the cursor downs
  4959. atcnl    endp
  4960.  
  4961. atcpl    proc    near            ; do Pn cursor ups
  4962.     jmp    atcuu            ; do the cursor ups
  4963. atcpl    endp
  4964.  
  4965.                     ; scaled by text screen width
  4966. atcha    proc    near            ; cursor to absolute column
  4967.     and    x_coord,not 7        ; modulo 8x8 cells
  4968.     mov    ax,param        ; get Pn
  4969.     or    ax,ax
  4970.     jz    atcha1            ; z = zero already
  4971.     dec    param            ; count columns from 0
  4972.     mov    ax,xmax            ; number of Tek dots/row
  4973.     mul    param            ; times columns they want
  4974.     mov    cl,byte ptr low_rgt    ; number of last text column
  4975.     xor    ch,ch
  4976.     xor    dx,dx
  4977.     div    cx            ; scale to ~80 column screen
  4978.     cmp    ax,xmax            ; too far?
  4979.     jbe    atcha1            ; be = no
  4980.     mov    ax,xmax            ; right most column
  4981. atcha1:    mov    x_coord,ax
  4982.     call    remcursor        ; remove text cursor symbol
  4983.     call    setcursor        ; draw cursor at new location
  4984.     ret
  4985. atcha    endp
  4986.                     ; scaled by text screen height
  4987. atcva    proc    near            ; cursor to absolute row
  4988.     dec    param            ; count from 0
  4989.     mov    ax,param        ; desired text row
  4990.     or    ax,ax            ; zero or now -1?
  4991.     jg    atcva1            ; g = no, further down
  4992.     mov    ax,7            ; bottom of top text cell
  4993.     jmp    short atcva2
  4994. atcva1:    mov    ax,ybot
  4995.     inc    ax            ; number of scan lines on screen
  4996. ;;;;    and    ax,not 7        ; whole 8x8 char cells
  4997.     mul    param            ; times row they want
  4998.     mov    cl,byte ptr low_rgt+1    ; number of last text line (0..23)
  4999.     xor    ch,ch
  5000.     xor    dx,dx
  5001.     div    cx            ; scale to ~24 line screen 
  5002.     mov    cx,ybot
  5003. ;;;;    and    cx,not 7        ; whole 8x8 char cells
  5004.     cmp    ax,cx            ; too far?
  5005.     jbe    atcva2            ; be = no
  5006.     mov    ax,cx
  5007. atcva2:    mov    y_coord,ax        ; go to that line
  5008.     call    remcursor        ; remove text cursor symbol
  5009.     call    setcursor        ; draw cursor at new location
  5010.     ret
  5011. atcva    endp
  5012.     
  5013. atcup    proc    near            ; cursor to absolute row, column
  5014.     call    atcva            ; process param[0] as absolute row
  5015.     push    param[2]        ; column
  5016.     pop    param
  5017.     jmp    atcha            ; process param[2] as absolute column
  5018. atcup    endp
  5019.  
  5020. ated    proc    near            ; erase display
  5021.     mov    al,spcontrol        ; preserve space control
  5022.     mov    tempname,al        ; save here
  5023.     mov    spcontrol,1        ; turn on destructive space
  5024.     push    x_coord
  5025.     push    y_coord            ; save cursor
  5026.     cmp    param,0            ; cursor to end of screen?
  5027.     je    ated1            ; e = yes
  5028.     cmp    param,1            ; start of screen to cursor?
  5029.     je    ated3            ; e = yes
  5030.     cmp    param,2            ; entire screen?
  5031.     je    ated5            ; e = yes
  5032.     ret                ; else ignore
  5033.  
  5034. ated1:    mov    param,0            ; cursor to end of this line
  5035.     call    atel            ; erase cursor to end of line
  5036.     add    y_coord,8        ; look at next line
  5037.     mov    ax,ybot
  5038.     cmp    y_coord,ax        ; are we at the end now?
  5039.     ja    ated6            ; a = yes
  5040.     mov    x_coord,0        ; start of line is here
  5041.     jmp    ated1            ; do through last line
  5042.  
  5043. ated3:    and    y_coord,not 7        ; modulo 8x8 char cells
  5044.     mov    cx,y_coord        ; start of screen to cursor
  5045.     shr    cx,1            ; char lines at 8 dots/char
  5046.     shr    cx,1
  5047.     shr    cx,1
  5048.     dec    cx            ; omit current line= # whole lines
  5049.     or    cx,cx            ; any whole lines?
  5050.     jle    ated3b            ; le = no
  5051.     mov    y_coord,7        ; start at the top line
  5052. ated3a:    push    cx
  5053.     mov    param,2            ; entire line
  5054.     call    atel            ; erase entire line
  5055.     add    y_coord,8        ; next line
  5056.     pop    cx
  5057.     loop    ated3a
  5058. ated3b:    mov    param,1            ; start of line to cursor
  5059.     call    atel            ; erase to cursor on this (last) line
  5060.     jmp    short ated6
  5061.  
  5062. ated5:    call    tekcls            ; erase whole screen
  5063.  
  5064. ated6:    mov    al,tempname        ; spacing control
  5065.     mov    spcontrol,al
  5066.     pop    y_coord
  5067.     pop    x_coord
  5068.     call    remcursor        ; remove last cursor
  5069.     call    setcursor        ; set cursor to original position
  5070.     ret
  5071. ated    endp
  5072.  
  5073. atech    proc    near            ; erase Pn chars from cursor to eol
  5074.     mov    al,spcontrol        ; preserve space control
  5075.     mov    tempname,al        ; save here
  5076.     mov    spcontrol,1        ; turn on destructive space
  5077.     push    x_coord
  5078.     push    y_coord            ; save cursor
  5079.     mov    cx,x_coord
  5080.     and    cx,not 7        ; modulo 8x8 cells
  5081.     mov    ax,xmax
  5082.     sub    ax,cx            ; number of chars remaining on line
  5083.     shr    ax,1
  5084.     shr    ax,1
  5085.     shr    ax,1
  5086.     inc    ax            ; count cursor cell
  5087.     mov    cx,param        ; how many chars to erase
  5088.     or    cx,cx
  5089.     jz    atech1            ; z = zero, use one
  5090.     inc    cx
  5091. atech1:    cmp    ax,cx            ; want more than line length?
  5092.     jae    atech2            ; ae = no
  5093.     mov    cx,ax            ; clip at right margin
  5094.     or    cx,cx
  5095.     jle    atech3            ; le = nothing to do
  5096. atech2:    push    cx
  5097.     mov    al,' '
  5098.     call    outscrn            ; write spaces
  5099.     pop    cx
  5100.     loop    atech2
  5101. atech3:    mov    al,tempname        ; spacing control
  5102.     mov    spcontrol,al
  5103.     pop    y_coord
  5104.     pop    x_coord
  5105.     call    remcursor        ; remove last cursor
  5106.     call    setcursor        ; set cursor to original position
  5107.     ret
  5108. atech    endp
  5109.  
  5110. atel    proc    near            ; erase on this line
  5111.     call    remcursor        ; remove cursor
  5112.     push    x_coord
  5113.     push    y_coord
  5114.     cmp    param,0            ; cursor to end of line?
  5115.     je    atel1            ; e = yes
  5116.     cmp    param,1            ; start of line to cursor?
  5117.     je    atel3            ; e = yes
  5118.     cmp    param,2            ; whole line?
  5119.     jne    atel5            ; ne = no, fail
  5120.     mov    x_coord,0        ; erase entire line
  5121.  
  5122. atel1:    mov    cx,xmax            ; cursor to end of line
  5123.     mov    ax,x_coord
  5124.     and    ax,not 7        ; modulo 8x8 cells
  5125.     sub    cx,ax
  5126.     shr    cx,1
  5127.     shr    cx,1
  5128.     shr    cx,1            ; 8 dots/char
  5129.     inc    cx            ; count the cursor cell
  5130.     or    cx,cx
  5131.     jle    atel5            ; le = do nothing
  5132.     mov    al,spcontrol        ; preserve space control
  5133.     mov    tempname,al        ; save here
  5134.     mov    spcontrol,1        ; turn on destructive space
  5135. atel2:    push    cx            ; start of line to cursor
  5136.     mov    al,' '
  5137.     call    outscrn
  5138.     pop    cx
  5139.     loop    atel2
  5140.     mov    al,tempname        ; space control
  5141.     mov    spcontrol,al        ; restored
  5142. atel5:    pop    y_coord
  5143.     pop    x_coord
  5144.     call    remcursor        ; remove last cursor
  5145.     call    setcursor        ; set cursor to original position
  5146.     ret
  5147. atel3:    mov    cx,x_coord        ; start of line to cursor
  5148.     shr    cx,1
  5149.     shr    cx,1
  5150.     shr    cx,1
  5151.     inc    cx            ; count cursor cell
  5152.     mov    x_coord,0        ; go to start of line
  5153.     jmp    atel2            ; do the loops
  5154. atel    endp
  5155. code2    ends
  5156.     end
  5157.